5:24 PM  01-FEB-2001
AUM v 01.1, Patch 1, EXAM/PT ED/STATES.
A9AUM1
A9AUM1 ; IHS/RPMSDBA/GTH - STANDARD TABLE UPDATES, AUM*1.1*1, RPI ; [ 02/01/2001   5:23 PM ]
 ;;01.1;TABLE MAINTENANCE;**1**;DEC 6,2000
 ;
 D START^AUM1101
DEL ;EP - Delete routines.
 Q:'$L($G(^%ZOSF("DEL")))
 NEW X
 I $$RSEL^ZIBRSEL("AUM1101*") D D
 I $$RSEL^ZIBRSEL("A9AUM*")
 KILL ^TMP("ZIBRSEL",$J,"A9AUM1") ; Don't delete the current routine.
 D D
 Q
 ;
D ;
 S X=""
 F  S X=$O(^TMP("ZIBRSEL",$J,X)) Q:X=""  X ^%ZOSF("DEL") I '$D(ZTQUEUED) W !,X,$E("...........",1,11-$L(X)),"<poof'd>"
 KILL ^TMP("ZIBRSEL",$J)
 Q
 ;

AUM1101
AUM1101 ; IHS/RPMSDBA/GTH - STANDARD TABLE UPDATES, AUM*1.1*1 ; [ 02/01/2001   5:23 PM ]
 ;;01.1;TABLE MAINTENANCE;**1**;DEC 6,2000
 ;
 I '$G(DUZ) W !,"DUZ UNDEFINED OR ZERO.",! Q
 D HOME^%ZIS,DT^DICRW,VP,HELP("INTRO")
 S (DIR(0),DIR("B"))="Y"
 S DIR("A")="Do you want to queue the update to TaskMan"
 S DIR("??")="^D HELP^AUM1101(""Q2"")"
 D ^DIR
 KILL DIR
 I $D(DIRUT) D HELP("Q2") Q
 G START:'Y
QUE ;
 S %DT="AERSX",%DT("A")="Requested Start Time: ",%DT("B")="T@2015",%DT(0)="NOW"
 D ^%DT
 I Y<1 W !,"QUEUE INFORMATION MISSING - NOT QUEUED" D HELP("Q2") G AUM1101
 S X=+Y
 D H^%DTC
 S ZTDTH=%H_","_%T,ZTRTN="START^AUM1101",ZTIO="",ZTDESC=$P($P($T(+1),";",2)," ",4,99)
 D ^%ZTLOAD,HOME^%ZIS
 I $D(ZTSK) W !!,"QUEUED TO TASK ",ZTSK,!!,"A mail message with the results will be sent to your MailMan 'IN' basket.",!
 E  W !!,*7,"QUEUE UNSUCCESSFUL.  RESTART UTILITY."
 Q
 ;
START ;EP - From Taskman
 ;
 NEW XMSUB,XMDUZ,XMTEXT,XMY
 KILL ^TMP("AUM1101",$J)
 D START^AUM11011
 S XMSUB=$P($P($T(+1),";",2)," ",4,99),XMDUZ=$G(DUZ,.5),XMTEXT="^TMP(""AUM1101"",$J,",XMY(DUZ)=""
 F %="XUPROGMODE","AG TM MENU","ABMDZ TABLE MAINTENANCE","APCCZMGR" D SINGLE(%)
 D ^XMD
 KILL ^TMP("AUM1101",$J)
 I $D(ZTQUEUED) S ZTREQ="@" G DEL^A9AUM1
 W !!,"The results are in your MailMan 'IN' basket.",!
 I $L($T(DIR^XBDIR)),$$DIR^XBDIR("Y","Want me to delete the routines in this patch","Y") G DEL^A9AUM1
 Q
 ;
INTRO ;EP - To write to mail message, too.
 ;;This patch makes the following add/edits to standard tables:
 ;;  
 ;;(1)  Corrects the abbreviation for the state of Nebraska in the STATE
 ;;     file from "NB" to "NE".  You might already have caught this.
 ;;(2)  Adds Canadian Provinces to the STATE file, in response to a
 ;;     field request.
 ;;(3)  Adds a new EXAM, in response to a field request.
 ;;(4)  Corrects three typographical errors in the Education Topics,
 ;;     Administrative functions, which were distributed in AUM 99.1,
 ;;     Patch 16.  The Names of Administrative Functions begin with AF,
 ;;     not AD.  The mnemonics were distributed correctly.
 ;;  
 ;;###;NOTE:  This line indicates the end of the message.
 ;
Q2 ;
 ;;Answer "Y" if you want to queue this standard table update to TaskMan.
 ;;Answer "N" if you want to run this update interactively.
 ;;
 ;;If you run interactively, results will be displayed on your screen,
 ;;as well as in the mail message sent to you and user 1.  If you queue
 ;;to TaskMan, please read the mail message for results of this update.
 ;;###;NOTE:  This line indicates the end of the message.
 ;
HELP(L) ;EP - Display text at label L.
 W !
 F %=1:1 W !?4,$P($T(@L+%),";",3) Q:$P($T(@L+%+1),";",3)="###"
 Q
 ;
SINGLE(K) ; Get holders of a single key K.
 NEW Y
 S Y=0
 Q:'$D(^XUSEC(K))
 F  S Y=$O(^XUSEC(K,Y)) Q:'Y  S XMY(Y)=""
 Q
 ;
VP ;
 W !?4,"****    AUM Version ",$P($T(+2),";",3)," Patch ",$P($P($T(+2),";",5),"*",3),?65,"****"
 W !?4,"****   ",$P($P($T(+1),";",2),"-",2),?65,"****"
 Q
 ;
GREET ;;EP - To add to mail message.
 ;;  
 ;;Greetings.
 ;;  
 ;;Standard tables on your RPMS system have been updated.
 ;;  
 ;;You are receiving this message because of the particular RPMS
 ;;security keys that you hold.  This is for your information, only.
 ;;You need do nothing in response to this message.
 ;;  
 ;;Requests for modifications or additions to RPMS standard tables,
 ;;whether they are or are not reflected in the IHS Standard Code
 ;;Book (SCB), can be submitted to your Area Information System
 ;;Coordinator (ISC).
 ;;  
 ;;Current SCB sections can be retrieved from the INTRAnet at:
 ;;  http://dpsntweb1.hqw.ihs.gov/ciweb/main.html
 ;;  
 ;;Questions about this patch, which is a product of the RPMS DBA,
 ;;can be directed to the DIR/RPMS Support Center, at
 ;;505-248-4371, or via e-mail to "hqwhd@mail.ihs.gov".  Please
 ;;refer to patch "AUM*1.1*1".
 ;;  
 ;;###;NOTE: This line indicates the end of text in this message.
 ;

AUM11011
AUM11011 ; IHS/RPMSDBA/GTH - STANDARD TABLE UPDATES, AUM*1.1*1 ; [ 02/01/2001   5:23 PM ]
 ;;01.1;TABLE MAINTENANCE;**1**;DEC 6,2000
 ;
 Q
 ;
START ;EP
 ;
 NEW A,C,DIC,DIE,DINUM,DLAYGO,DR,E,L,M,N,O,P,R,S,T
 ;
 S E(0)="ERROR : ",E(1)="NOT ADDED : "
 D RSLT($J("",5)_$P($T(UPDATE^AUM1101A),";",3))
 F %=1:1 D RSLT($P($T(GREET+%^AUM1101),";",3)) Q:$P($T(GREET+%+1^AUM1101),";",3)="###"
 F %=1:1 D RSLT($P($T(INTRO+%^AUM1101),";",3)) Q:$P($T(INTRO+%+1^AUM1101),";",3)="###"
 D DASH,STATEMOD,DASH,STATENEW,DASH,EXAMNEW,DASH,EDTMOD,DASH
 Q
 ;
 ; -----------------------------------------------------
 ;
ADDOK D RSLT($J("",5)_"Added : "_L) Q
ADDFAIL D RSLT($J("",5)_E(0)_"ADD FAILED => "_L) Q
DASH D RSLT(""),RSLT($$REPEAT^XLFSTR("-",$S($G(IOM):IOM-10,1:70))),RSLT("") Q
DIE NEW A,C,E,L,M,N,O,P,R,S,T
 LOCK +(@(DIE_DA_")")):10 E  D RSLT($J("",5)_E(0)_"Entry '"_DIE_DA_"' IS LOCKED.  NOTIFY PROGRAMMER.") S Y=1 Q
 D ^DIE LOCK -(@(DIE_DA_")")) KILL DA,DIE,DR Q
E(L) Q $P($P($T(@L^AUM1101A),";",3),":",1)
IEN(X,%,Y) ;
 S Y=$O(@(X_"""C"",%,0)"))
 I 'Y S Y=$$VAL^AUM1101M(X,%) I Y NEW Z S Z=E D  S:Y<0 Y="" S E=Z
 . NEW A,C,L,M,N,O,P,R,S,V,%
 . S L=Y
 . I X["AREA" NEW X D RSLT("(Add Missing Area)") D ADDAREA D RSLT("(END Add Missing Area)") Q
 . I X["SU" NEW X D RSLT("(Add Missing SU)") D ADDSU D RSLT("(END Add Missing SU)") Q
 . I X["CTY" NEW X D RSLT("(Add Missing County)") D ADDCNTY D RSLT("(END Add Missing County)") Q
 .Q
 D:'Y RSLT($J("",5)_E(0)_$P(@(X_"0)"),U)_" DOES NOT EXIST => "_%)
 Q +Y
DIK NEW A,C,E,L,M,N,O,P,R,S,T D ^DIK KILL DIK Q
FILE NEW A,C,E,L,M,N,O,P,R,S,T K DD,DO S DIC(0)="L" D FILE^DICN KILL DIC Q
MODOK D RSLT($J("",3)_"Changed : "_L) Q
RSLT(%) S ^(0)=$G(^TMP("AUM1101",$J,0))+1,^(^(0))=% W:'$D(ZTQUEUED) !,% Q
ZEROTH(A,B,C,D,E,F,G,H,I,J,K) ; Return 0th node.  A is file #, rest fields.
 I '$G(A) Q -1
 I '$G(B) Q -1
 F %=67:1:75 Q:'$G(@($C(%)))  S A=+$P(^DD(A,B,0),U,2),B=@($C(%))
 I 'A!('B) Q -1
 I '$D(^DD(A,B,0)) Q -1
 Q U_$P(^DD(A,B,0),U,2)
 ;
 ; -----------------------------------------------------
 ;
ADDAREA ; PROGRAMMER NOTE:  This s/r is required for every patch.
 S L=$P(L,";;",2),A=$P(L,U),N=$P(L,U,2),R=$P(L,U,3),C=$P(L,U,4),L=A_" "_N_" "_R_" "_C
 I $D(^AUTTAREA("B",N)) D RSLT($J("",5)_E(1)_"NAME EXISTS => "_N) Q
 I $D(^AUTTAREA("C",A)) D RSLT($J("",5)_E(1)_"CODE EXISTS => "_A) Q
 S DLAYGO=9999999.21,DIC="^AUTTAREA(",X=N,DIC("DR")=".02///"_A_";.03///"_R_";.04///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DLAYGO
 Q
 ;
 ; -----------------------------------------------------
 ;
ADDCNTY ; PROGRAMMER NOTE:  This s/r is required for every patch.
 S L=$P(L,";;",2),S=$P(L,U),C=$P(L,U,2),N=$P(L,U,3),L=S_" "_C_" "_N
 I $D(^AUTTCTY("C",S_C)) D RSLT($J("",5)_E(1)_"CODE EXISTS => "_S_C) Q
 S P("S")=$$IEN("^DIC(5,",S)
 Q:'P("S")
 S DIC="^AUTTCTY(",X=N,DIC("DR")=".02////"_P("S")_";.03///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
 ; -----------------------------------------------------
 ;
ADDSU ; PROGRAMMER NOTE:  This s/r is required for every patch.
 S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),N=$P(L,U,3),L=A_" "_S_" "_N
 I $D(^AUTTSU("C",A_S)) D RSLT($J("",5)_E(1)_"ASU EXISTS => "_A_S) Q
 S P=$$IEN("^AUTTAREA(",A)
 Q:'P
 S DLAYGO=9999999.22,DIC="^AUTTSU(",X=N,DIC("DR")=".02////"_P_";.03///"_S
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DLAYGO
 Q
 ;
 ; -----------------------------------------------------
LOCNEW ;
 D RSLT($$E("LOCNEW"))
 D RSLT($J("",13)_"AA SU FA NAME"_$J("",28)_"PSEUDO")
 D RSLT($J("",13)_"-- -- -- ----"_$J("",28)_"------")
 F T=1:1 S L=$T(LOCNEW+T^AUM1101A) Q:$P(L,";",3)="END"  D ADDLOC
 Q
 ;
ADDLOC ;
 S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3),N=$P(L,U,4),P=$P(L,U,5)
 S L=A_" "_S_" "_F_" "_N_$J("",32-$L(N))_P
 S %=A_S_F,%=$O(^AUTTLOC("C",%,0))
 I % D RSLT($J("",5)_E(1)_"ASUFAC EXISTS => "_A_S_F) D  Q
 . I $P($G(^AUTTLOC(%,0)),U,21) S DIE="^AUTTLOC(",DA=%,DR=".27///@;.28////"_DT D DIE D:$D(Y) RSLT($J("",5)_E(0)_"DELETE INACTIVE DATE FAILED => "_L) D:'$D(Y) RSLT($J("",5)_"INACTIVE DATE DELETED => "_L)
 . S %=$O(^AUTTLOC("C",A_S_F,0)),%=$P(^AUTTLOC(%,0),U)
 . I %,$D(^DIC(4,%,0)),N'=$P(^DIC(4,%,0),U) S DIE="^DIC(4,",DA=%,DR=".01///"_N D DIE D:$D(Y) RSLT($J("",5)_E(0)_"EDIT INSTITUTION FAILED => "_L) D:'$D(Y) RSLT($J("",5)_"INSTITUTION NAME UPDATED => "_L)
 . S %=$O(^AUTTLOC("C",A_S_F,0))
 . I P'=$P($G(^AUTTLOC(%,1)),U,2) S DIE="^AUTTLOC(",DA=%,DR=".28////"_DT_";.31///"_P D DIE D:$D(Y) RSLT($J("",5)_E(0)_"EDIT PSEUDO PREFIX FAILED => "_L) D:'$D(Y) RSLT($J("",5)_"PSEUDO PREFIX UPDATED => "_L)
 .Q
 S P("A")=$$IEN("^AUTTAREA(",A)
 Q:'P("A")
 S P("S")=$$IEN("^AUTTSU(",A_S)
 Q:'P("S")
 F DINUM=+$P(^DIC(4,0),U,3):1 Q:'$D(^DIC(4,DINUM))&('$D(^AUTTLOC(DINUM)))  I DINUM>99999 D RSLT($J("",5)_E(0)_"DINUM FOR LOC/INSTITUTION TOO BIG. NOTIFY ISC.") Q
 Q:DINUM>99999
 S DLAYGO=4,DIC="^DIC(4,",X=N
 D FILE
 KILL DINUM,DLAYGO
 I Y<0 D RSLT($J("",5)_E(0)_"^DIC(4 ADD FAILED => "_L) Q
 S DINUM=+Y,DLAYGO=9999999.06,DIC="^AUTTLOC(",X=DINUM,DIC("DR")=".04////"_P("A")_";.05////"_P("S")_";.07///"_F_";.28////"_DT_";.31///"_P
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DINUM,DLAYGO
 Q
 ;
 ; -----------------------------------------------------
 ;
LOCMOD ;
 D RSLT($$E("LOCMOD"))
 D RSLT($J("",15)_"AA SU FA NAME"_$J("",28)_"PSEUDO")
 D RSLT($J("",15)_"-- -- -- ----"_$J("",28)_"------")
 F T=1:2 S L=$T(LOCMOD+T^AUM1101A) Q:$P(L,";",3)="END"  S L("TO")=$T(LOCMOD+T+1^AUM1101A) D
 . S L=$P(L,U,2,99),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3)
 . S P=$O(^AUTTLOC("C",A_S_F,0))
 . S L=$P(L("TO"),U,2,99),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3),N=$P(L,U,4)
 . I 'P S P=$O(^AUTTLOC("C",A_S_F,0)) I 'P S L=";;"_L D ADDLOC Q
 . S L=A_" "_S_" "_F_" "_N_$J("",32-$L(N))_$P(L("TO"),U,6)
 . S P("A")=$$IEN("^AUTTAREA(",A)
 . Q:'P("A")
 . S P("S")=$$IEN("^AUTTSU(",A_S)
 . Q:'P("S")
 . S DIE="^AUTTLOC(",DA=P,DR=".04////"_P("A")_";.05////"_P("S")_";.07///"_F_";.28////"_DT_";.31///"_$P(L("TO"),U,6)
 . D DIE
 . I $D(Y) D RSLT($J("",5)_E(0)_"EDIT LOCATION FAILED => "_L) Q
 . S DIE="^DIC(4,",DA=$P(^AUTTLOC(P,0),U),DR=".01///"_N
 . D DIE
 . I $D(Y) D RSLT($J("",5)_E(0)_"EDIT INSTITUTION FAILED => "_L) Q
 . D MODOK
 .Q
 ;
 D DASH
 D RSLT("Checking Location Code changes to determine export status.")
 D RSLT("Patient data is not exported if the only change is to the Location NAME.")
 D RSLT("Location Code changes must be rolled up into the national data repository...")
 D DASH,RSLT($$LOCMOD^AUMXPORT("AUM1101A")_" patients marked for export because of the Location Code changes.")
 Q
 ;
 ; -----------------------------------------------------
 ;
COMMNEW ;
 D RSLT($$E("COMMNEW"))
 D RSLT($J("",13)_"ST CT COM NAME"_$J("",28)_"AA SU")
 D RSLT($J("",13)_"-- -- --- ----"_$J("",28)_"-- --")
 F T=1:1 S L=$T(COMMNEW+T^AUM1101A) Q:$P(L,";",3)="END"  D ADDCOMM
 Q
 ;
ADDCOMM ;
 S L=$P(L,";;",2),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3),N=$P(L,U,4),A=$P(L,U,5),V=$P(L,U,6),L=S_" "_O_" "_C_" "_N_$J("",32-$L(N))_A_" "_V
 I $D(^AUTTCOM("C",S_O_C)) D RSLT($J("",5)_E(1)_"STCTYCOM CODE EXISTS => "_S_O_C) Q
 S P("O")=$$IEN("^AUTTCTY(",S_O)
 Q:'P("O")
 S P("A")=$$IEN("^AUTTAREA(",A)
 Q:'P("A")
 S P("V")=$$IEN("^AUTTSU(",A_V)
 Q:'P("V")
 S DLAYGO=9999999.05,DIC="^AUTTCOM(",X=N,DIC("DR")=".02////"_P("O")_";.05////"_P("V")_";.06////"_P("A")_";.07///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DLAYGO
 Q
 ;
 ; -----------------------------------------------------
 ;
COMMMOD ;
 D RSLT($$E("COMMMOD"))
 D RSLT($J("",15)_"ST CT COM NAME"_$J("",28)_"AA SU")
 D RSLT($J("",15)_"-- -- --- ----"_$J("",28)_"-- --")
 F T=1:2 S L=$T(COMMMOD+T^AUM1101A) Q:$P(L,";",3)="END"  S L("TO")=$T(COMMMOD+T+1^AUM1101A) D
 . S L=$P(L,U,2,99),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3)
 . S P=$O(^AUTTCOM("C",S_O_C,0))
 . S L=$P(L("TO"),U,2,99),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3),N=$P(L,U,4),A=$P(L,U,5),V=$P(L,U,6)
 . I 'P S P=$O(^AUTTCOM("C",S_O_C,0)) I 'P S L=";;"_L D ADDCOMM Q
 . S L=S_" "_O_" "_C_" "_N_$J("",32-$L(N))_A_" "_V
 . S P("O")=$$IEN("^AUTTCTY(",S_O)
 . Q:'P("O")
 . S P("A")=$$IEN("^AUTTAREA(",A)
 . Q:'P("A")
 . S P("V")=$$IEN("^AUTTSU(",A_V)
 . Q:'P("V")
 . S DIE="^AUTTCOM(",DA=P,DR=".01///"_N_";.02////"_P("O")_";.05////"_P("V")_";.06////"_P("A")_";.07///"_C
 . D DIE
 . I $D(Y) D RSLT($J("",5)_E(0)_"CHANGE FAILED => "_L) Q
 . D MODOK
 .Q
 ;
 D DASH
 D RSLT("Checking Community Code changes to determine export status.")
 D RSLT("Patient data is not exported if the only change is to the Commnuity NAME.")
 D RSLT("Commnity Code changes must be rolled up into the national data repository...")
 D DASH,RSLT($$COMMMOD^AUMXPORT("AUM1101A")_" patients marked for export because of the Community Code changes.")
 Q
 ;
 ; -----------------------------------------------------
 ;
STATENEW ;
 D RSLT($$E("STATENEW"))
 D RSLT($J("",13)_"CC NAME"_$J("",26)_"AB CAPITAL")
 D RSLT($J("",13)_"-- ----"_$J("",26)_"-- -------")
 F T=1:1 S L=$T(STATENEW+T^AUM1101A) Q:$P(L,";",3)="END"  D ADDSTATE
 Q
 ;
ADDSTATE ;
 S L=$P(L,";;",2),C=$P(L,U),N=$P(L,U,2),A=$P(L,U,3),O=$P(L,U,4),L=C_" "_$E(N_$J("",30),1,29)_" "_A_" "_O
 I $D(^DIC(5,"C",C)) D RSLT($J("",5)_E(1)_"STATE CODE EXISTS => "_C) Q
 S DLAYGO=5,DIC="^DIC(5,",X=N,DIC("DR")="1///"_A_";2///"_C_";5///"_O
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DLAYGO
 Q
 ;
 ; -----------------------------------------------------
 ;
STATEMOD ;
 D RSLT($$E("STATEMOD"))
 D RSLT($J("",13)_"CC NAME"_$J("",26)_"AB CAPITAL")
 D RSLT($J("",13)_"-- ----"_$J("",26)_"-- -------")
 F T=1:2 S L=$T(STATEMOD+T^AUM1101A) Q:$P(L,";",3)="END"  S L("TO")=$T(STATEMOD+T+1^AUM1101A) D
 . S C=$P(L,U,2)
 . I '$D(^DIC(5,"C",C)) S L=";;"_$P(L("TO"),U,2,99) D ADDSTATE Q
 . S DA=$O(^DIC(5,"C",C,0))
 . S L=L("TO"),C=$P(L,U,2),N=$P(L,U,3),A=$P(L,U,4),O=$P(L,U,5),L=C_" "_$E(N_$J("",30),1,29)_" "_A_" "_O
 . S DIE="^DIC(5,",DR=".01///"_N_";1///"_A_";2///"_C_";5///"_O
 . D DIE
 . I $D(Y) D RSLT($J("",5)_E(0)_"EDIT STATE FAILED => "_L) Q
 . D MODOK
 .Q
 Q
 ;
 ; -----------------------------------------------------
 ;
EXAMNEW ;
 D RSLT($$E("EXAMNEW"))
 D RSLT($J("",13)_"CC NAME"_$J("",26)_"CPT CODE")
 D RSLT($J("",13)_"-- ----"_$J("",26)_"--------")
 F T=1:1 S L=$T(EXAMNEW+T^AUM1101A) Q:$P(L,";",3)="END"  D ADDEXAM
 Q
 ;
ADDEXAM ;
 S L=$P(L,";;",2),C=$P(L,U),N=$P(L,U,2),O=$P(L,U,3),L=C_" "_$E(N_$J("",30),1,29)_" "_O
 I $D(^AUTTEXAM("C",C)) D RSLT($J("",5)_E(1)_"EXAM CODE EXISTS => "_C) Q
 S DLAYGO=9999999.15,DIC="^AUTTEXAM(",X=N,DIC("DR")=".02///"_C_";.11///"_O
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
 ; -----------------------------------------------------
 ;
ADDEDT ;
 S L=$P(L,";;",2),N=$P(L,U),O=$P(L,U,2),L=$E(N_$J("",30),1,30)_"  "_O
 I $D(^AUTTEDT("B",N)) D RSLT(E(1)_"TOPIC EXISTS => "_N) Q
 I $D(^AUTTEDT("C",O)) D RSLT(E(1)_"MNEMONIC EXISTS => "_O_" for "_N) Q
 S DLAYGO=9999999.09,DIC="^AUTTEDT(",X=N,DIC("DR")="1///"_O
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
 ; -----------------------------------------------------
 ;
EDTMOD ;
 D RSLT($$E("EDTMOD"))
 D RSLT($J("",13)_"NAME"_$J("",28)_"MNEMONIC")
 D RSLT($J("",13)_"----"_$J("",28)_"--------")
 F T=1:2 S L=$T(EDTMOD+T^AUM1101A) Q:$P(L,";",3)="END"  S L("TO")=$T(EDTMOD+T+1^AUM1101A) D
 . S N=$P(L,U,2)
 . I '$D(^AUTTEDT("B",N)) S L=";;"_$P(L("TO"),U,2,99) D ADDEDT Q
 . S DA=$O(^AUTTEDT("B",N,0))
 . S L=L("TO"),N=$P(L,U,2),O=$P(L,U,3),L=$E(N,1,25)_$J("",30-$L(N))_"  "_$E(O,1,25)
 . S DIE="^AUTTEDT(",DR=".01///"_N_";1///"_O
 . D DIE
 . I $D(Y) D RSLT($J("",5)_E(0)_"EDIT EDUCATION TOPICS FAILED => "_L) Q
 . D MODOK
 .Q
 KILL DLAYGO
 Q
 ;
 ; -----------------------------------------------------
 ;

AUM1101A
AUM1101A ; IHS/RPMSDBA/GTH - STANDARD TABLE UPDATES, AUM*1.1*1 ; [ 02/01/2001   5:23 PM ]
 ;;01.1;TABLE MAINTENANCE;**1**;DEC 6,2000
 ;
UPDATE ;;  STANDARD TABLE UPDATES
 ;
 ;
STATEMOD ;;(1)  MODIFY STATE : CODE^NAME^ABBREVIATION^CAPITAL
 ;;FROM^31^NEBRASKA^NB^LINCOLN
 ;;TO  ^31^NEBRASKA^NE^LINCOLN
 ;;END
 ;
STATENEW ;;(2)  NEW STATE CODE (SECTION V-A): CODE^NAME^ABBREVIATION^CAPITAL
 ;;75^ALBERTA^AB^EDMONTON
 ;;77^BRITISH COLUMBIA^BC^VICTORIA
 ;;80^MANITOBA^MB^WINNIPEG
 ;;82^NEW BRUNSWICK^NB^FREDERICTON
 ;;83^NEWFOUNDLAND^NF^ST. JOHN'S
 ;;85^NORTHWEST TERRITORIES^NT^YELLOWKNIFE
 ;;87^NOVA SCOTIA^NS^HALIFAX
 ;;88^NUNAVUT^NU^IQALUIT
 ;;90^ONTARIO^ON^TORONTO
 ;;91^PRINCE EDWARD ISLAND^PE^CHARLOTTETOWN
 ;;92^QUEBEC^PQ^QUEBEC CITY
 ;;93^SASKATCHEWAN^SK^REGINA
 ;;94^YUKON TERRITORY^YT^WHITEHORSE
 ;;END
 ;
EXAMNEW ;;(3)  EXAM FILE (FIELD REQUEST): CODE^NAME^CPT CODE
 ;;31^AUDITORY EVOKED POTENTIAL^92585
 ;;END
 ;
EDTMOD ;;(4)  EDUCATION TOPICS, CORRECT TYPOS IN PATCH 16: NAME^MNEMONIC
 ;;FROM^AD-BENEFITS^AF-B
 ;;TO  ^AF-BENEFITS^AF-B
 ;;FROM^AD-FOLLOW-UP^AF-FU
 ;;TO  ^AF-FOLLOW-UP^AF-FU
 ;;FROM^AD-REFERRAL PROCESS^AF-REF
 ;;TO  ^AF-REFERRAL PROCESS^AF-REF
 ;;END
 ;

AUM1101M
AUM1101M ; IHS/RPMSDBA/GTH -  BACKGROUND VALUES FOR STANDARD TABLE UPDATES, AUM*1.1*1 ; [ 02/01/2001   5:23 PM ]
 ;;01.1;TABLE MAINTENANCE;**1**;DEC 6,2000
 ;
VAL(X,%,Y) ;EP - return background info.
 I X["AREA" Q $T(@%)
 S Y=0
 I X["SU" D  Q Y
 . NEW C,T
 . F C=1:1 S T=$P($T(SU+C),";",3) Q:T="END"  I $P(T,U,1,2)=($E(%,1,2)_U_$E(%,3,4)) S Y=1_";;"_T Q
 .Q
 I '(X["CTY") Q 0
 NEW C,T
 F C=1:1 S T=$P($T(COUNTY+C),";",3) Q:T="END"  I $P(T,U,1,2)=($E(%,1,2)_U_$E(%,3,4)) S Y=1_";;"_T Q
 Q Y
 ;
AREA ; CODE^NAME^PREFIX/REGION^CAN PREFIX
 ;;END
 ;
SU ; AREA^SU^NAME
 ;;END
 ;
COUNTY ; STATE^COUNTY^NAME
 ;;END
 ;