11:09 AM  6-NOV-95
AUM v 95.1, Patch 10, SCB changes from 02Nov95 Banyan.  5 routines.  Restore routines and DO ^AUM9511.
A9AUM10
A9AUM10 ; IHS/ADC/GTH - STANDARD TABLE UPDATES, 02NOV95 BANYAN, RPI ; [ 11/06/95  11:07 AM ]
 ;;95.1;TABLE MAINTENANCE;**10**;NOV 1, 1994
 ;
 D START^AUM9511
 ;
 Q:'$L($G(^%ZOSF("DEL")))
 NEW X
 F %=1:1 S X=$P($T(DEL+%),";",3) Q:X=""  X ^%ZOSF("DEL")
 Q
DEL ;     
 ;;A9AUM9
 ;;AUM9511
 ;;AUM95111
 ;;AUM9511A
 ;;AUM9511M

AUM9511
AUM9511 ; IHS/ADC/GTH - STANDARD TABLE UPDATES, 02NOV95 BANYAN ; [ 11/06/95  11:01 AM ]
 ;;95.1;TABLE MAINTENANCE;**10**;NOV 1, 1994
 ;
 I '$G(DUZ) W !,"DUZ UNDEFINED OR ZERO.",! Q
 D HOME^%ZIS,DT^DICRW,HELP("INTRO")
 S (DIR(0),DIR("B"))="Y"
 S DIR("A")="Do you want to queue the update to TaskMan"
 S DIR("??")="^D HELP^AUM9511(""Q2"")"
 D ^DIR
 I $D(DIRUT) D HELP("Q2") Q
 G START:'Y
QUE ;
 S %DT="AERSX",%DT("A")="Requested Start Time: ",%DT("B")="T@2015",%DT(0)="NOW"
 D ^%DT
 I Y<1 W !,"QUEUE INFORMATION MISSING - NOT QUEUED" D Q2 G AUM9511
 S X=+Y
 D H^%DTC
 S ZTDTH=%H_","_%T
 S ZTRTN="START^AUM9511",ZTIO="",ZTDESC=$P($P($T(+1),";",2)," ",4,99)
 D ^%ZTLOAD,HOME^%ZIS
 I $D(ZTSK) W !!,"QUEUED TO TASK ",ZTSK,!!,"A mail message with the results will be sent to your MailMan 'IN' basket.",!
 E  W !!,*7,"QUEUE UNSUCCESSFUL.  RESTART UTILITY."
 Q
 ;
START ;EP - From Taskman
 ;
 NEW XMSUB,XMDUZ,XMTEXT,XMY
 K ^TMP("AUM SCB",$J)
 D START^AUM95111
 S XMSUB=$P($P($T(+1),";",2)," ",4,99),XMDUZ=$S($G(DUZ):DUZ,1:.5),XMTEXT="^TMP(""AUM SCB"",$J,",XMY(1)="",XMY(DUZ)=""
 D ^XMD
 K ^TMP("AUM SCB",$J)
 I $D(ZTQUEUED) S ZTREQ="@"
 E  W !!,"The results are in your MailMan 'IN' basket.",!
 Q
 ;
INTRO ;
 ;;This updates standard tables according to the changes specified in
 ;;the Banyan message time stamped 02Nov95@14:44:07 MST. Please consult
 ;;that message, and the mail message produced by this update.
 ;;
 ;;###
 ;
Q2 ;
 ;;Answer "Y" if you want to queue this standard table update to TaskMan.
 ;;Answer "N" if you want to run this update interactively.
 ;;
 ;;If you run interactively, results will be displayed on your screen,
 ;;as well as in the mail message sent to you and user 1.  If you queue
 ;;to TaskMan, please read the mail message for results of this update.
 ;;###
 ;
HELP(L) ;EP - Display text at label L.
 W !
 F %=1:1 W !?4,$P($T(@L+%),";",3) Q:$P($T(@L+%+1),";",3)="###"
 Q
 ;

AUM95111
AUM95111 ; IHS/ADC/GTH - STANDARD TABLE UPDATES, 02NOV95 BANYAN ; [ 11/06/95  10:54 AM ]
 ;;95.1;TABLE MAINTENANCE;**10**;NOV 1, 1994
 Q
 ;
START ;EP
 ;
 NEW A,C,DIC,DIE,DLAYGO,DR,E,L,N,O,P,R,S,T
 ;
 S E(0)="ERROR : ",E(1)="NOT ADDED : "
 D LOCNEW,LOCMOD,LOCINACT,CNTYMOD,COMMNEW,COMMMOD,RESMOD
 ;
 Q
 ;
ADDOK D RSLT(E_", Added : "_L) Q
ADDFAIL D RSLT(E(0)_E_" : ADD FAILED => "_L) Q
DIE NEW A,C,E,L,N,O,P,R,S,T
 LOCK +(@(DIE_DA_")")):10 E  D RSLT(E(0)_"Entry '"_DIE_DA_"' IS LOCKED.  NOTIFY PROGRAMMER.") S Y=1 Q
 D ^DIE LOCK -(@(DIE_DA_")")) K DA,DIE,DR Q
IEN(X,%,Y) ;
 S Y=$O(@(X_"""C"",%,0)"))
 I 'Y S Y=$T(@%^AUM9511M) I Y NEW Z S Z=E D  S:Y<0 Y="" S E=Z
 . NEW A,C,L,N,O,P,R,S,V,%
 . S L=Y
 . I X["AREA" NEW X S E=E_" (Add Area) " D ADDAREA Q
 . I X["SU" NEW X S E=E_" (Add SU) " D ADDSU Q
 . I X["CTY" NEW X S E=E_" (Add County) " D ADDCNTY Q
 .Q
 D:'Y RSLT(E(0)_E_" : "_$P(@(X_"0)"),U)_" DOES NOT EXIST => "_%)
 Q +Y
FILE NEW A,C,E,L,N,O,P,R,S,T K DD,DO S DIC(0)="L" D FILE^DICN K DIC Q
MODOK D RSLT(E_", Changed : "_L) Q
RSLT(%) S ^(0)=$G(^TMP("AUM SCB",$J,0))+1,^(^(0))=% W:'$D(ZTQUEUED) !,% Q
 ;
AREANEW ;
 S E="New Area Codes"
 F T=1:1 S L=$T(AREANEW+T^AUM9511A) Q:$P(L,";",3)="END"  D ADDAREA
 Q
 ;
ADDAREA ;
 S L=$P(L,";;",2),A=$P(L,U),N=$P(L,U,2),R=$P(L,U,3),C=$P(L,U,4),L=A_"  "_N_"  "_R_"  "_C
 I $D(^AUTTAREA("B",N)) D RSLT(E(1)_E_" : NAME EXISTS => "_N) Q
 I $D(^AUTTAREA("C",A)) D RSLT(E(1)_E_" : CODE EXISTS => "_A) Q
 S DLAYGO=9999999.21,DIC="^AUTTAREA(",X=N,DIC("DR")=".02///"_A_";.03///"_R_";.04///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
SUNEW ;
 S E="New Service Unit Codes"
 F T=1:1 S L=$T(SUNEW+T^AUM9511A) Q:$P(L,";",3)="END"  D ADDSU
 Q
 ;
ADDSU ;
 S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),N=$P(L,U,3),L=A_"  "_S_"  "_N
 I $D(^AUTTSU("C",A_S)) D RSLT(E(1)_E_" : ASU EXISTS => "_A_S) Q
 S P=$$IEN("^AUTTAREA(",A)
 Q:'P
 S DLAYGO=9999999.22,DIC="^AUTTSU(",X=N,DIC("DR")=".02////"_P_";.03///"_S
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
LOCNEW ;
 S E="New Location Codes"
 F T=1:1 S L=$T(LOCNEW+T^AUM9511A) Q:$P(L,";",3)="END"  D ADDLOC
 Q
 ;
ADDLOC ;
 S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3),N=$P(L,U,4),P=$P(L,U,5)
 S L=A_"  "_S_"  "_F_"  "_N_"  "_P
 S %=A_S_F,%=$O(^AUTTLOC("C",%,0))
 I % D RSLT(E(1)_E_" : ASUFAC EXISTS => "_A_S_F) D  Q
 . I $P($G(^AUTTLOC(%,0)),U,21) S DIE="^AUTTLOC(",DA=%,DR=".27///@" D DIE D:$D(Y) RSLT(E(1)_E_" : DELETE INACTIVE DATE FAILED => "_L) D:'$D(Y) RSLT(E_" : INACTIVE DATE DELETED => "_L)
 . S %=$O(^AUTTLOC("C",A_S_F,0)),%=$P(^AUTTLOC(%,0),U)
 . I %,$D(^DIC(4,%,0)),N'=$P(^DIC(4,%,0),U) S DIE="^DIC(4,",DA=%,DR=".01///"_N D DIE D:$D(Y) RSLT(E(0)_E_" : EDIT INSTITUTION FAILED => "_L) D:'$D(Y) RSLT(E_" : INSTITUTION NAME UPDATED => "_L)
 . S %=$O(^AUTTLOC("C",A_S_F,0))
 . I P'=$P($G(^AUTTLOC(%,1)),U,2) S DIE="^AUTTLOC(",DA=%,DR=".31///"_P D DIE D:$D(Y) RSLT(E(0)_E_" : EDIT PSEUDO PREFIX FAILED => "_L) D:'$D(Y) RSLT(E_" : PSEUDO PREFIX UPDATED => "_L)
 .Q
 S P("A")=$$IEN("^AUTTAREA(",A)
 Q:'P("A")
 S P("S")=$$IEN("^AUTTSU(",A_S)
 Q:'P("S")
 F DINUM=+$P(^DIC(4,0),U,3):1 Q:'$D(^DIC(4,DINUM))&('$D(^AUTTLOC(DINUM)))  I DINUM>99999 D RSLT(E(0)_"DINUM FOR LOC/INSTITUTION TOO BIG. NOTIFY ISC.") Q
 Q:DINUM>99999
 S DLAYGO=4,DIC="^DIC(4,",X=N
 D FILE
 I Y<0 D RSLT(E(0)_E_" : ^DIC(4 ADD FAILED => "_L) Q
 S DINUM=+Y,DLAYGO=9999999.06,DIC="^AUTTLOC(",X=DINUM,DIC("DR")=".04////"_P("A")_";.05////"_P("S")_";.07///"_F_";.31///"_P
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
LOCMOD ;
 S E="Location Code Changes"
 F T=1:2 S L=$T(LOCMOD+T^AUM9511A) Q:$P(L,";",3)="END"  S L("TO")=$T(LOCMOD+T+1^AUM9511A) D
 . S L=$P(L,U,2,99),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3)
 . S P=$O(^AUTTLOC("C",A_S_F,0))
 . S L=$P(L("TO"),U,2,99),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3),N=$P(L,U,4)
 . I 'P S P=$O(^AUTTLOC("C",A_S_F,0)) I 'P S L=";;"_L D ADDLOC Q
 . S L=A_"  "_S_"  "_F_"  "_N_"  "_$P(L("TO"),U,6)
 . S P("A")=$$IEN("^AUTTAREA(",A)
 . Q:'P("A")
 . S P("S")=$$IEN("^AUTTSU(",A_S)
 . Q:'P("S")
 . S DIE="^AUTTLOC(",DA=P,DR=".04////"_P("A")_";.05////"_P("S")_";.07///"_F_";.31///"_$P(L("TO"),U,6)
 . D DIE
 . I $D(Y) D RSLT(E(0)_E_" : EDIT LOCATION FAILED => "_L) Q
 . S DIE="^DIC(4,",DA=$P(^AUTTLOC(P,0),U),DR=".01///"_N
 . D DIE
 . I $D(Y) D RSLT(E(0)_E_" : EDIT INSTITUTION FAILED => "_L) Q
 . D MODOK
 .Q
 ; D RSLT($$LOCMOD^AUMXPORT("AUM9511A")_" patients marked for export because of the Location Code changes.") ; There were only name changes in NOV 02 Banyan.  No need to export.
 ;
 Q
 ;
LOCINACT ;
 S E="Inactivated Location Codes"
 F T=1:1 S L=$T(LOCINACT+T^AUM9511A) Q:$P(L,";",3)="END"  D
 . S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3),N=$P(L,U,4),P=$P(L,U,5)
 . S L=A_"  "_S_"  "_F_"  "_N_"  "_P
 . S %=A_S_F,%=$O(^AUTTLOC("C",%,0))
 . I '% D RSLT(E_" : ASUFAC "_A_S_F_" not found (OK).") Q
 . S DIE="^AUTTLOC(",DA=%,DR=".27////"_DT
 . D DIE
 . I $D(Y) D RSLT(E(1)_E_" : EDIT INACTIVE DATE FAILED => "_L) I 1
 . E  D RSLT(E_" : INACTIVATED => "_L)
 .Q
 Q
 ;
CNTYNEW ;
 S E="New County Codes"
 F T=1:1 S L=$T(CNTYNEW+T^AUM9511A) Q:$P(L,";",3)="END"  D ADDCNTY
 Q
 ;
ADDCNTY ;
 S L=$P(L,";;",2),S=$P(L,U),C=$P(L,U,2),N=$P(L,U,3),L=S_"  "_C_"  "_N
 I $D(^AUTTCTY("C",S_C)) D RSLT(E(1)_E_" : CODE EXISTS => "_S_C) Q
 S P("S")=$$IEN("^DIC(5,",S)
 Q:'P("S")
 S DIC="^AUTTCTY(",X=N,DIC("DR")=".02////"_P("S")_";.03///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
CNTYMOD ;
 S E="County Code Changes"
 F T=1:2 S L=$T(CNTYMOD+T^AUM9511A) Q:$P(L,";",3)="END"  S L("TO")=$T(CNTYMOD+T+1^AUM9511A) D
 . S L=$P(L,U,2,99),S=$P(L,U),C=$P(L,U,2)
 . S P=$O(^AUTTCTY("C",S_C,0))
 . S L=$P(L("TO"),U,2,99),S=$P(L,U),C=$P(L,U,2),N=$P(L,U,3)
 . I 'P S P=$O(^AUTTCTY("C",S_C,0)) I 'P S L=";;"_L D ADDCNTY Q
 . S L=S_"  "_C_"  "_N
 . S P("S")=$$IEN("^DIC(5,",S)
 . Q:'P("S")
 . S DIE="^AUTTCTY(",DA=P,DR=".01///"_N_";.02////"_P("S")_";.03///"_C
 . D DIE
 . I $D(Y) D RSLT(E(0)_E_" : EDIT COUNTY FAILED => "_L) Q
 . D MODOK
 .Q
 Q
 ;
COMMNEW ;
 S E="New Community Codes"
 F T=1:1 S L=$T(COMMNEW+T^AUM9511A) Q:$P(L,";",3)="END"  D ADDCOMM
 Q
 ;
ADDCOMM ;
 S L=$P(L,";;",2),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3),N=$P(L,U,4),A=$P(L,U,5),V=$P(L,U,6),L=S_" "_O_" "_C_" "_N_" "_A_" "_V
 I $D(^AUTTCOM("C",S_O_C)) D RSLT(E(1)_E_" : STCTYCOM CODE EXISTS => "_S_O_C) Q
 S P("O")=$$IEN^AUM95111("^AUTTCTY(",S_O)
 Q:'P("O")
 S P("A")=$$IEN^AUM95111("^AUTTAREA(",A)
 Q:'P("A")
 S P("V")=$$IEN^AUM95111("^AUTTSU(",A_V)
 Q:'P("V")
 S DLAYGO=9999999.05,DIC="^AUTTCOM(",X=N,DIC("DR")=".02////"_P("O")_";.05////"_P("V")_";.06////"_P("A")_";.07///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
COMMMOD ;
 S E="Community Code Changes"
 F T=1:2 S L=$T(COMMMOD+T^AUM9511A) Q:$P(L,";",3)="END"  S L("TO")=$T(COMMMOD+T+1^AUM9511A) D
 . S L=$P(L,U,2,99),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3)
 . S P=$O(^AUTTCOM("C",S_O_C,0))
 . S L=$P(L("TO"),U,2,99),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3),N=$P(L,U,4),A=$P(L,U,5),V=$P(L,U,6)
 . I 'P S P=$O(^AUTTCOM("C",S_O_C,0)) I 'P S L=";;"_L D ADDCOMM Q
 . S L=S_" "_O_" "_C_" "_N_" "_A_" "_V
 . S P("O")=$$IEN^AUM95111("^AUTTCTY(",S_O)
 . Q:'P("O")
 . S P("A")=$$IEN^AUM95111("^AUTTAREA(",A)
 . Q:'P("A")
 . S P("V")=$$IEN^AUM95111("^AUTTSU(",A_V)
 . Q:'P("V")
 . S DIE="^AUTTCOM(",DA=P,DR=".01///"_N_";.02////"_P("O")_";.05////"_P("V")_";.06////"_P("A")_";.07///"_C
 . D DIE
 . I $D(Y) D RSLT(E(0)_E_" : CHANGE FAILED => "_L) Q
 . D MODOK
 .Q
 ; D RSLT($$COMMMOD^AUMXPORT("AUM9511A")_" patients marked for export because of the Community Code changes.") ; There were only name changes in NOV 02 Banyan.  No need to export.
 Q
 ;
RESNEW ;
 S E="New Reservation Codes"
 F T=1:1 S L=$T(RESNEW+T^AUM9511A) Q:$P(L,";",3)="END"  D ADDRES
 Q
 ;
ADDRES ;
 S L=$P(L,";;",2),C=$P(L,U),N=$P(L,U,2),A=$P(L,U,3),O=$P(L,U,4),S=$P(L,U,5),L=C_" "_N_" "_A_" "_O_" "_S
 I $D(^AUTTRES("C",C)) D RSLT(E(1)_E_" : RESERVATION CODE EXISTS => "_C) Q
 S P("A1")=$$IEN("^AUTTAREA(",A)
 Q:'P("A1")
 I O S P("A2")=$$IEN("^AUTTAREA(",O) Q:'P("A2")
 S P("S")=$$IEN("^DIC(5,",S)
 Q:'P("S")
 S DLAYGO=9999999.47,DIC="^AUTTRES(",X=N,DIC("DR")=".02///"_C_";.03////"_P("S")_";.04////"_P("A1")
 I O,$G(P("A2")) S DIC("DR")=DIC("DR")_";.05////"_P("A2")
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
RESMOD ;
 S E="Reservation Code Changes"
 F T=1:2 S L=$T(RESMOD+T^AUM9511A) Q:$P(L,";",3)="END"  S L("TO")=$T(RESMOD+T+1^AUM9511A) D
 . S L=$P(L,U,2,99),C=$P(L,U)
 . S P=$O(^AUTTRES("C",C,0))
 . S L=$P(L("TO"),U,2,99),C=$P(L,U),N=$P(L,U,2),A=$P(L,U,3),O=$P(L,U,4),S=$P(L,U,5)
 . I 'P S L=";;"_L D ADDRES Q
 . S L=C_"  "_N_"  "_A_"  "_O_"  "_S
 . S P("A1")=$$IEN("^AUTTAREA(",A)
 . Q:'P("A1")
 . I O S P("A2")=$$IEN("^AUTTAREA(",O) Q:'P("A2")
 . S P("S")=$$IEN("^DIC(5,",S)
 . Q:'P("S")
 . S DIE="^AUTTRES(",DA=P,DR=".01///"_N_";.03////"_P("S")_";.04////"_P("A1")
 . I O,$G(P("A2")) S DR=DR_";.05////"_P("A2")
 . D DIE
 . I $D(Y) D RSLT(E(0)_E_" : EDIT RESERVATION FAILED => "_L) Q
 . D MODOK
 .Q
 Q
 ;

AUM9511A
AUM9511A ; IHS/ADC/GTH - STANDARD TABLE UPDATES DATA A, 02NOV95 BANYAN ; [ 11/06/95  10:11 AM ]
 ;;95.1;TABLE MAINTENANCE;**10**;NOV 1, 1994
 ;
 ;  If you do not want new entries made in your area, remove the line.
 ;
 ;  If you don't want the modifications performed in your area, remove
 ;    BOTH the FROM line and the TO line.
 ;
 ;
 ;
LOCNEW ; A.  NEW LOCATION CODES (SECTION VIII-C): AREA^S.U.^FAC.^NAME^PSEUDO
 ;;45^43^32^ARLEE HEALTH STATION^BAN
 ;;45^43^81^PABLO DENTAL CLINIC^BAO
 ;;55^58^13^LITTLE AXE HEALTH CENTER^OAE
 ;;55^60^20^JONES ACADEMY SCHOOL HC^OAD
 ;;65^66^30^GILA CROSSING TRIBAL^XCY
 ;;75^78^31^QUEETS HEALTH STATION^PAR
 ;;END
 ;
LOCMOD ; B.  LOCATION CODE CHANGES (SECTION VIII-C): AREA^S.U.^FAC.^NAME^PSEUDO
 ;;FROM^55^52^13^OKMULGEE DENTAL CLINIC^OPD
 ;;  TO^55^52^13^OKMULGEE HEALTH CENTER^OPD
 ;;FROM^70^76^10^YAKAMA HEALTH CENTER^PFB
 ;;  TO^70^76^10^YAKIMA HEALTH CENTER^PFB
 ;;FROM^75^76^10^YAKAMA HEALTH CENTER^PQA
 ;;  TO^75^76^10^YAKIMA HEALTH CENTER^PQA
 ;;FROM^79^76^10^YAKAMA HEALTH CENTER^PTL
 ;;  TO^79^76^10^YAKIMA HEALTH CENTER^PTL
 ;;END
 ;
LOCINACT ; C.  INACTIVE LOCATION CODES (SECTION VIII-C): AREA^S.U.^FAC.^NAME
 ;;60^66^30^GILA CROSSING
 ;;65^66^21^GILA CROSSING TRIBAL
 ;;70^78^31^QUEETS HS
 ;;END
 ;
CNTYMOD ; D.  COUNTY CODE CHANGES (SECTION V-B): STATE^CNTY^NAME
 ;;FROM^53^39^YAKAMA
 ;;  TO^53^39^YAKIMA
 ;;END
 ;
COMMNEW ; E.  NEW COMMUNITY CODES (SECTION V-C): STATE^CNTY^COMM^NAME^AREA^S.U.
 ;;02^06^120^TWO RIVERS^30^37
 ;;02^13^100^MEADOW LAKE^30^31
 ;;02^13^101^BUTTE^30^31
 ;;02^13^102^LAZY MOUNTAIN^30^31
 ;;02^14^100^NORTON SOUND^30^39
 ;;04^04^070^GISELA^60^66
 ;;04^04^071^STAR VALLEY^60^66
 ;;END
 ;
COMMMOD ; F.  COMMUNITY CODE CHANGES (SECTION V-C): STATE^CNTY^COMM^NAME^AREA^S.U.
 ;;FROM^02^09^285^ENGLISH BAY^30^31
 ;;  TO^02^09^285^NANWALEK^30^31
 ;;FROM^53^39^861^YAKAMA CITY^70^76
 ;;  TO^53^39^861^YAKIMA CITY^70^76
 ;;FROM^53^39^867^YAKAMA RURAL^70^76
 ;;  TO^53^39^867^YAKIMA RURAL^70^76
 ;;END
 ;
RESMOD ; G.  RESERVATION CODE CHANGES (SECTION XIV): CODE^NAME^AREA1^AREA2^STATE
 ;;FROM^211^YAKAMA^70^^53
 ;;  TO^211^YAKIMA^70^^53
 ;;END
 ;

AUM9511M
AUM9511M ; IHS/ADC/GTH - BACKGROUND VALUES FOR STANDARD TABLE UPDATES, 02NOV95 BANYAN ; [ 11/06/95  10:49 AM ]
 ;;95.1;TABLE MAINTENANCE;**10**;NOV 1, 1994
 ;
AREA ; CODE^NAME^PREFIX/REGION^CAN PREFIX
30 ;;30^ALASKA^A^J59
45 ;;45^BILLINGS TRIBE/638^B^J47
55 ;;55^OKLAHOMA TRIBE/638^O^J50
60 ;;60^PHOENIX^X^J40
65 ;;65^PHOENIX TRIBE/638^X^J40
70 ;;70^PORTLAND^P^J64
75 ;;75^PORTLAND TRIBE/638^P^J64
79 ;;79^PORTLAND NON-IHS^P^J64
 ;
SU ; AREA^SU^NAME
3031 ;;30^31^ANCHORAGE
3037 ;;30^37^INTER ALASKA
3039 ;;30^39^NORTON SOUND
4543 ;;45^43^FLATHEAD
5552 ;;55^52^CLAREMORE
5558 ;;55^58^SHAWNEE
5560 ;;55^60^TALIHINA
6066 ;;60^66^PHOENIX
6566 ;;65^66^PHOENIX
7076 ;;70^76^YAKIMA
7078 ;;70^78^TAHOLAH
7576 ;;75^76^YAKIMA
7578 ;;75^78^TAHOLAH
7976 ;;79^76^YAKIMA
 ;
COUNTY ; STATE^COUNTY^NAME
0206 ;;02^06^FAIRBANKS NORTH STAR
0209 ;;02^09^KENAI PENINSULA BOROUGH
0213 ;;02^13^MATANUSKA-SUSITNA BOROUGH
0214 ;;02^14^NOME
0404 ;;04^04^GILA
5339 ;;53^39^YAKIMA
 ;