5:05 PM  13-JAN-95
AUM 95.1 patch 2, SCB updates from 13Jan95 Banyan.
A9AUM2
A9AUM2 ; DSD/GTH - STANDARD TABLE UPDATES, 13JAN95 BANYAN, RPI ; [ 01/13/95  4:24 PM ]
 ;;95.1;TABLE MAINTENANCE;**2**;NOV 1, 1994
 G START^AUM9501

AUM9501
AUM9501 ; DSD/GTH - STANDARD TABLE UPDATES, 13JAN95 BANYAN ; [ 01/13/95  3:28 PM ]
 ;;95.1;TABLE MAINTENANCE;**2**;NOV 1, 1994
 ;
 I '$G(DUZ) W !,"DUZ UNDEFINED OR ZERO.",! Q
 D HOME^%ZIS,DT^DICRW,INTRO
 S (DIR(0),DIR("B"))="Y"
 S DIR("A")="Do you want to queue the utility to TaskMan"
 S DIR("??")="^D Q2^AUM9501"
 D ^DIR G Q2:$D(DIRUT),START:'Y
QUE ;
 S %DT="AERSX",%DT("A")="Requested Start Time: ",%DT("B")="T@2015",%DT(0)="NOW" D ^%DT
 I Y<1 W !,"QUEUE INFORMATION MISSING - NOT QUEUED",!!,"Okay...",! D Q2 Q
 S X=+Y D H^%DTC S ZTDTH=%H_","_%T
 S ZTRTN="START^AUM9501",ZTIO="",ZTDESC=$P($P($T(+1),";",2)," ",4,99)
 D ^%ZTLOAD,HOME^%ZIS
 I $D(ZTSK) W !!,"QUEUED TO TASK ",ZTSK,!!,"A mail message with the results will be sent to your MailMan 'IN' basket.",!
 E  W !!,*7,"QUEUE UNSUCCESSFUL.  RESTART UTILITY."
 Q
START ;EP - From Taskman
 ;
 NEW XMSUB,XMDUZ,XMTEXT,XMY
 K ^TMP($J)
 D START^AUM95011
 S (XMSUB,XMDUZ)=$P($P($T(+1),";",2)," ",4,99),XMTEXT="^TMP($J,""RSLT"",",XMY(1)="",XMY(DUZ)="" D ^XMD
 K ^TMP($J)
 I $D(ZTQUEUED) S ZTREQ="@"
 E  W !!,"The results are in your MailMan 'IN' basket.",!
 Q
 ;
INTRO ;
 W ! F %=2:1:5 W ?5,$P($T(INTRO+%),";;",2),!
 ;;This patch updates standard tables according to the changes
 ;;specified in the Banyan message time stamped 13Jan95@11:35:25 MST,
 ;;Please consult that message, and the mail message produced by this
 ;;utility.
 Q
Q2 ;EP - From DIR
 W ! F %=2:1:7 W ?5,$P($T(Q2+%),";;",2),!
 ;;Answer "Y" if you want to queue this standard table update to TaskMan.
 ;;Answer "N" if you want to run this update interactively.
 ;;
 ;;If you run interactively, results will be displayed on your screen,
 ;;as well as in the mail message sent to you and user 1.  If you queue
 ;;to TaskMan, please read the mail message for results of this patch.
 Q

AUM95011
AUM95011 ; DSD/GTH - STANDARD TABLE UPDATES (1), 13JAN95 BANYAN ; [ 01/13/95  4:27 PM ]
 ;;95.1;TABLE MAINTENANCE;**2**;NOV 1, 1994
 Q
 ;
START ;EP
 NEW A,C,DIC,DIE,DLAYGO,DR,E,L,N,O,P,R,S,T
 S E(0)="ERROR : ",E(1)="NOT ADDED : "
 D COMMNEW,RESNEW,RESMOD,TRIBNEW,TRIBMOD
 Q
 ;
ADDOK D RSLT(E_", Added : "_L) Q
ADDFAIL D RSLT(E(0)_E_" : ADD FAILED => "_L) Q
DIE NEW A,C,E,L,N,O,P,R,S,T
 LOCK +(@(DIE_DA_")")):10 E  D RSLT(E(0)_"Entry '"_DIE_DA_"' IS LOCKED.  NOTIFY PROGRAMMER.") S Y=1 Q
 D ^DIE LOCK -(@(DIE_DA_")")) K DA,DIE,DR Q
IEN(X,%,Y) ;EP
 S Y=$O(@(X_"""C"",%,0)"))
 I 'Y S Y=$T(@%^AUM9501M) I Y NEW Z S Z=E D  S:Y<0 Y="" S E=Z
 . NEW A,C,L,N,O,P,R,S,V,%
 . S L=Y
 . I X["AREA" NEW X S E=E_" (Add Area) " D ADDAREA Q
 . I X["SU" NEW X S E=E_" (Add SU) " D ADDSU Q
 . I X["CTY" NEW X S E=E_" (Add County) " D ADDCNTY Q
 .Q
 D:'Y RSLT(E(0)_E_" : "_$P(@(X_"0)"),U)_" DOES NOT EXIST => "_%)
 Q +Y
FILE NEW A,C,E,L,N,O,P,R,S,T K DD,DO S DIC(0)="L" D FILE^DICN K DIC Q
MODOK D RSLT(E_", Changed : "_L) Q
RSLT(%) S ^(0)=$G(^TMP($J,"RSLT",0))+1,^(^(0))=% W:'$D(ZTQUEUED) !,% Q
 ;
COMMNEW ;
 S E="New Community Codes"
 F T=1:1 S L=$T(COMMNEW+T^AUM9501A) Q:$P(L,";",3)="END"  D ADDCOMM
 Q
 ;
ADDCOMM ;
 S L=$P(L,";;",2),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3),N=$P(L,U,4),A=$P(L,U,5),V=$P(L,U,6),L=S_" "_O_" "_C_" "_N_" "_A_" "_V
 I $D(^AUTTCOM("C",S_O_C)) D RSLT(E(1)_E_" : STCTYCOM CODE EXISTS => "_S_O_C) Q
 S P("O")=$$IEN("^AUTTCTY(",S_O) Q:'P("O")
 S P("A")=$$IEN("^AUTTAREA(",A) Q:'P("A")
 S P("V")=$$IEN("^AUTTSU(",A_V) Q:'P("V")
 S DLAYGO=9999999.05,DIC="^AUTTCOM(",X=N,DIC("DR")=".02////"_P("O")_";.05////"_P("V")_";.06////"_P("A")_";.07///"_C D FILE
 D ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
RESNEW ;
 S E="New Reservation Codes"
 F T=1:1 S L=$T(RESNEW+T^AUM9501A) Q:$P(L,";",3)="END"  D ADDRES
 Q
 ;
ADDRES ;
 S L=$P(L,";;",2),C=$P(L,U),N=$P(L,U,2),A=$P(L,U,3),O=$P(L,U,4),S=$P(L,U,5),L=C_" "_N_" "_A_" "_O_" "_S
 I $D(^AUTTRES("C",C)) D RSLT(E(1)_E_" : RESERVATION CODE EXISTS => "_C) Q
 S P("A1")=$$IEN("^AUTTAREA(",A) Q:'P("A1")
 I O S P("A2")=$$IEN("^AUTTAREA(",O) Q:'P("A2")
 S P("S")=$$IEN("^DIC(5,",S) Q:'P("S")
 S DLAYGO=9999999.47,DIC="^AUTTRES(",X=N,DIC("DR")=".02///"_C_";.03////"_P("S")_";.04////"_P("A1")
 I O,$G(P("A2")) S DIC=DIC_";.05////"_P("A2")
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
RESMOD ;
 S E="Reservation Code Changes"
 F T=1:2 S L=$T(RESMOD+T^AUM9501A) Q:$P(L,";",3)="END"  S L("TO")=$T(RESMOD+T+1^AUM9501A) D
 . S L=$P(L,U,2,99),C=$P(L,U)
 . S P=$O(^AUTTRES("C",C,0))
 . S L=$P(L("TO"),U,2,99),C=$P(L,U),N=$P(L,U,2),A=$P(L,U,3),O=$P(L,U,4),S=$P(L,U,5)
 . I 'P S L=";;"_L D ADDRES Q
 . S L=C_"  "_N_"  "_A_"  "_O_"  "_S
 . S P("A1")=$$IEN("^AUTTAREA(",A) Q:'P("A1")
 . I O S P("A2")=$$IEN("^AUTTAREA(",O) Q:'P("A2")
 . S P("S")=$$IEN("^DIC(5,",S) Q:'P("S")
 . S DIE="^AUTTRES(",DA=P,DR=".01///"_N_";.03////"_P("S")_";.04////"_P("A1")
 . I O,$G(P("A2")) S DIE=DIE_";.05////"_P("A2")
 . D DIE
 . I $D(Y) D RSLT(E(0)_E_" : EDIT RESERVATION FAILED => "_L) Q
 . D MODOK
 .Q
 Q
 ;
TRIBNEW ;
 S E="New Tribe Codes"
 F T=1:1 S L=$T(TRIBNEW+T^AUM9501A) Q:$P(L,";",3)="END"  D ADDTRIB
 Q
 ;
ADDTRIB ;
 S L=$P(L,";;",2),C=$P(L,U),N=$P(L,U,2),L=C_"  "_N
 I $D(^AUTTTRI("C",C)) D RSLT(E(1)_E_" : TRIBE CODE EXISTS => "_C) Q
 S DLAYGO=9999999.03,DIC="^AUTTTRI(",X=N,DIC("DR")=".02///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
TRIBMOD ;
 S E="Tribe Code Changes"
 F T=1:2 S L=$T(TRIBMOD+T^AUM9501A) Q:$P(L,";",3)="END"  S L("TO")=$T(TRIBMOD+T+1^AUM9501A) D
 . S L=$P(L,U,2,99),C=$P(L,U)
 . S P=$O(^AUTTTRI("C",C,0))
 . S L=$P(L("TO"),U,2,99),C=$P(L,U),N=$P(L,U,2)
 . I 'P S L=";;"_L D ADDTRIB Q
 . S L=C_"  "_N
 . S DIE="^AUTTTRI(",DA=P,DR=".01///"_N
 . D DIE
 . I $D(Y) D RSLT(E(0)_E_" : EDIT TRIBE FAILED => "_L) Q
 . D MODOK
 .Q
 Q
 ;
ADDAREA ;
 S L=$P(L,";;",2),A=$P(L,U),N=$P(L,U,2),R=$P(L,U,3),C=$P(L,U,4),L=A_"  "_N_"  "_R_"  "_C
 I $D(^AUTTAREA("B",N)) D RSLT(E(1)_E_" : NAME EXISTS => "_N) Q
 I $D(^AUTTAREA("C",A)) D RSLT(E(1)_E_" : CODE EXISTS => "_A) Q
 S DLAYGO=9999999.21,DIC="^AUTTAREA(",X=N,DIC("DR")=".02///"_A_";.03///"_R_";.04///"_C D FILE
 D ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
ADDSU ;
 S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),N=$P(L,U,3),L=A_"  "_S_"  "_N
 I $D(^AUTTSU("C",A_S)) D RSLT(E(1)_E_" : ASU EXISTS => "_A_S) Q
 S P=$$IEN("^AUTTAREA(",A) Q:'P
 S DLAYGO=9999999.22,DIC="^AUTTSU(",X=N,DIC("DR")=".02////"_P_";.03///"_S D FILE
 D ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
ADDCNTY ;
 S L=$P(L,";;",2),S=$P(L,U),C=$P(L,U,2),N=$P(L,U,3),L=S_"  "_C_"  "_N
 I $D(^AUTTCTY("C",S_C)) D RSLT(E(1)_E_" : CODE EXISTS => "_S_C) Q
 S P("S")=$$IEN("^DIC(5,",S) Q:'P("S")
 S DIC="^AUTTCTY(",X=N,DIC("DR")=".02////"_P("S")_";.03///"_C D FILE
 D ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;

AUM9501A
AUM9501A ; DSD/GTH - STANDARD TABLE UPDATES DATA A, 13JAN95 BANYAN ; [ 01/13/95  4:43 PM ]
 ;;95.1;TABLE MAINTENANCE;**2**;NOV 1, 1994
 ;
 ;  If you do not want new entries made in your area, remove the line.
 ;
 ;  If you don't want the modifications performed in your area, remove
 ;    BOTH the FROM line and the TO line.
 ;
COMMNEW ;;A.  NEW COMMUNITY CODES (SECTION V-C): STATE^CNTY^COMM^NAME^AREA^S.U.
 ;;26^09^207^KAWKAWLIN^11^00
 ;;26^09^208^LINWOOD^11^00
 ;;26^11^209^COLOMA^11^00
 ;;26^12^210^COLDWATER^11^00
 ;;26^19^211^DEWITT^11^00
 ;;26^19^212^ST. JOHNS^11^00
 ;;26^23^213^GRAND LEDGE^11^00
 ;;26^25^214^DAVISON^11^00
 ;;26^25^215^GRAND BLANC^11^00
 ;;26^26^216^GLADWIN^11^00
 ;;26^29^217^ASHLEY^11^00
 ;;26^29^218^BRECKENRIDGE^11^00
 ;;26^29^219^ELM HALL^11^00
 ;;26^29^220^ELWELL^11^00
 ;;26^29^221^NORTH STAR^11^00
 ;;26^32^222^BAY PORT^11^00
 ;;26^33^223^EAST LANSING^11^00
 ;;26^33^224^WILLIAMSTON^11^00
 ;;26^34^225^BELDING^11^00
 ;;26^34^226^HUBBARDSTON^11^00
 ;;26^37^097^MILLBROOK^18^23
 ;;26^37^098^WINN^18^23
 ;;26^39^227^CLIMAX^11^00
 ;;26^39^228^OSTHEMO^11^00
 ;;26^39^229^PORTAGE^11^00
 ;;26^50^230^CENTERLINE^11^00
 ;;26^50^231^EASTPOINTE^11^00
 ;;26^53^232^SCOTTVILLE^11^00
 ;;26^54^233^BARRYTON^11^00
 ;;26^56^099^HOPE^18^23
 ;;26^59^234^CRYSTAL^11^00
 ;;26^59^235^EDMORE^11^00
 ;;26^59^236^SIDNEY^11^00
 ;;26^62^237^BITELY^11^00
 ;;26^62^238^HESPERIA^11^00
 ;;26^62^239^NEWAYGO^11^00
 ;;26^63^240^PONTIAC^11^00
 ;;26^64^241^MEARS^11^00
 ;;26^67^242^EVART^11^00
 ;;26^67^243^SEARS^11^00
 ;;26^68^244^FAIRVIEW^11^00
 ;;26^70^245^GRAND HAVEN^11^00
 ;;26^70^246^SPRING LAKE^11^00
 ;;26^72^247^HOUGHTON LAKE^11^00
 ;;26^72^248^PRUDENVILLE^11^00
 ;;26^72^249^ST. HELEN^11^00
 ;;26^73^250^CHESANING^11^00
 ;;26^73^251^FREELAND^11^00
 ;;26^78^252^OWOSSO^11^00
 ;;26^78^253^PERRY^11^00
 ;;26^79^254^FAIRGROVE^11^00
 ;;26^79^255^REESE^11^00
 ;;26^79^256^VASSAR^11^00
 ;;26^82^257^RIVERVIEW^11^00
 ;;26^82^258^TAYLOR^11^00
 ;;26^83^259^CADILLAC^11^00
 ;;26^83^262^MESICK^11^00
 ;;27^02^263^ANOKA^11^00
 ;;27^02^264^BLAINE^11^00
 ;;27^02^265^CIRCLE PINES^11^00
 ;;27^02^266^COON RAPIDS^11^00
 ;;27^04^004^HINES^11^32
 ;;27^04^005^KELLIHER^11^32
 ;;27^04^006^PINEWOOD^11^32
 ;;27^04^007^WILTON^11^32
 ;;27^05^267^SAUK RAPIDS^11^00
 ;;27^07^268^MANKATO^11^00
 ;;27^09^001^BARNUM^18^24
 ;;27^10^269^CHASKA^11^00
 ;;27^15^008^LEONARD^11^32
 ;;27^19^270^APPLE VALLEY^11^00
 ;;27^19^271^BURNSVILLE^11^00
 ;;27^23^272^HARMONY^11^00
 ;;27^27^273^BLOOMINGTON^11^00
 ;;27^27^274^CHAMPLIN^11^00
 ;;27^27^275^COLUMBIA HEIGHTS^11^00
 ;;27^27^276^CRYSTAL^11^00
 ;;27^27^277^EDEN PRAIRIE^11^00
 ;;27^27^278^HOPKINS^11^00
 ;;27^27^279^RICHFIELD^11^00
 ;;27^27^280^ROBBINSDALE^11^00
 ;;27^31^011^BOVEY^11^26
 ;;27^31^012^KEEWATIN^11^26
 ;;27^36^004^GEMMELL^18^31
 ;;27^39^009^WILLIAMS^11^32
 ;;27^42^281^COTTONWOOD^11^00
 ;;27^45^010^NEWFOLDEN^11^32
 ;;27^54^014^HALSTAD^11^35
 ;;27^57^011^ST. HILARE^11^32
 ;;27^62^282^MOUNDSVIEW^11^00
 ;;27^62^283^NEW BRIGHTON^11^00
 ;;27^68^012^WANNASKA^11^32
 ;;27^71^284^BIG LAKE^11^00
 ;;27^73^285^ST. JOSEPH^11^00
 ;;27^77^286^STAPLES^11^00
 ;;27^84^287^BRECKENRIDGE^11^00
 ;;END
RESNEW ;;B.  NEW RESERVATION CODES (SECTION XIV): CODE^NAME^AREA 1^AREA 2^STATE
 ;;316^LITTLE TRAVERSE BAY BAND OF ODAWA INDIANS^18^^26
 ;;317^LITTLE RIVER BAND OF OTTAWA INDIANS^18^^26
 ;;318^POKAGON BAND OF POTAWATOMI INDIANS (IN)^18^^18
 ;;319^POKAGON BAND OF POTAWATOMI INDIANS (MI)^18^^26
 ;;END
RESMOD ;;C.  RESERVATION CODE CHANGES (SECTION XIV): CODE^NAME^AREA 1^AREA 2^STATE
 ;;FROM^209^WISCONSIN WINNEBAGO^18^^55
 ;;  TO^209^HO-CHUNK NATION^18^^55
 ;;END
TRIBNEW ;;D.  NEW TRIBE CODES (SECTION XVIII): CODE^NAME
 ;;453^LITTLE TRAVERSE BAY BAND OF ODAWA INDIANS
 ;;454^LITTLE RIVER BAND OF OTTAWA INDIANS
 ;;455^POKAGON BAND OF POTAWATOMI INDIANS (IN AND MI)
 ;;END
TRIBMOD ;;E.  TRIBE CODE CHANGES (SECTION XVIII): CODE^NAME
 ;;FROM^295^WISCONSIN WINNEBAGO INDIAN TRIBE OF WISCONSIN
 ;;  TO^295^HO-CHUNK NATION
 ;;END

AUM9501M
AUM9501M ; DSD/GTH - BACKGROUND VALUES FOR STANDARD TABLE UPDATES, 13JAN95 BANYAN ; [ 01/13/95  4:41 PM ]
 ;;95.1;TABLE MAINTENANCE;**2**;NOV 1, 1994
 ;
AREA ; CODE^NAME^PREFIX/REGION^CAN PREFIX
11 ;;11^BEMIDJI^D^J46
18 ;;18^BEMIDJI NON-IHS^D^J46
 ;;
SU ; AREA^SU^NAME
1100 ;;11^00^NON SERVICE UNIT
1126 ;;11^26^GREATER LEECH LAKE
1132 ;;11^32^RED LAKE
1135 ;;11^35^WHITE EARTH
1823 ;;18^23^EASTERN MICHIGAN
1824 ;;18^24^FOND DU LAC
1831 ;;18^31^NETT LAKE
 ;;
COUNTY ; STATE^COUNTY^NAME
2609 ;;26^09^BAY
2611 ;;26^11^BERRIEN
2612 ;;26^12^BRANCH
2619 ;;26^19^CLINTON
2623 ;;26^23^EATON
2625 ;;26^25^GENESEE
2626 ;;26^26^GLADWIN
2629 ;;26^29^GRATIOT
2632 ;;26^32^HURON
2633 ;;26^33^INGHAM
2634 ;;26^34^IONIA
2637 ;;26^37^ISABELLA
2639 ;;26^39^KALAMAZOO
2650 ;;26^50^MACOMB
2653 ;;26^53^MASON
2654 ;;26^54^MECOSTA
2656 ;;26^56^MIDLAND
2659 ;;26^59^MONTCALM
2662 ;;26^62^NEWAYGO
2663 ;;26^63^OAKLAND
2664 ;;26^64^OCEANA
2667 ;;26^67^OSCEOLA
2668 ;;26^68^OSCODA
2670 ;;26^70^OTTAWA
2672 ;;26^72^ROSCOMMON
2673 ;;26^73^SAGINAW
2678 ;;26^78^SHIAWASSEE
2679 ;;26^79^TUSCOLA
2682 ;;26^82^WAYNE
2683 ;;26^83^WEXFORD
2702 ;;27^02^ANOKA
2704 ;;27^04^BELTRAMI
2705 ;;27^05^BENTON
2707 ;;27^07^BLUE EARTH
2709 ;;27^09^CARLTON
2710 ;;27^10^CARVER
2715 ;;27^15^CLEARWATER
2719 ;;27^19^DAKOTA
2723 ;;27^23^FILLMORE
2727 ;;27^27^HENNEPIN
2731 ;;27^31^ITASCA
2736 ;;27^36^KOOCHICHING
2739 ;;27^39^LAKE OF THE WOODS
2742 ;;27^42^LYON
2745 ;;27^45^MARSHALL
2754 ;;27^54^NORMAN
2757 ;;27^57^PENNINGTON
2762 ;;27^62^RAMSEY
2768 ;;27^68^ROSEAU
2771 ;;27^71^SHERBURNE
2773 ;;27^73^STEARNS
2777 ;;27^77^TODD
2784 ;;27^84^WILKIN
 ;;