2:26 PM  3-MAR-95
AUM v 95.1 patch 3, KETCHIKAN mod.
A9AUM3
A9AUM3 ; DSD/GTH - STANDARD TABLE UPDATES, KETCHIKAN, RPI ; [ 03/03/95  2:25 PM ]
 ;;95.1;TABLE MAINTENANCE;**3**;NOV 1, 1994
 ;
 D START^AUM9502
 ;
 Q:'$L($G(^%ZOSF("DEL")))
 NEW X
 F %=1:1 S X=$P($T(DEL+%),";",3) Q:X=""  X ^%ZOSF("DEL")
 Q
DEL ;     
 ;;AUM9502
 ;;AUM95021
 ;;AUM9502A
 ;;AUM9502M

AUM9502
AUM9502 ; DSD/GTH - STANDARD TABLE UPDATES, KETCHIKAN ; [ 03/03/95  2:12 PM ]
 ;;95.1;TABLE MAINTENANCE;**3**;NOV 1, 1994
 ;
 I '$G(DUZ) W !,"DUZ UNDEFINED OR ZERO.",! Q
 D HOME^%ZIS,DT^DICRW,INTRO
 S (DIR(0),DIR("B"))="Y"
 S DIR("A")="Do you want to queue the utility to TaskMan"
 S DIR("??")="^D Q2^AUM9502"
 D ^DIR G Q2:$D(DIRUT),START:'Y
QUE ;
 S %DT="AERSX",%DT("A")="Requested Start Time: ",%DT("B")="T@2015",%DT(0)="NOW" D ^%DT
 I Y<1 W !,"QUEUE INFORMATION MISSING - NOT QUEUED",!!,"Okay...",! D Q2 Q
 S X=+Y D H^%DTC S ZTDTH=%H_","_%T
 S ZTRTN="START^AUM9502",ZTIO="",ZTDESC=$P($P($T(+1),";",2)," ",4,99)
 D ^%ZTLOAD,HOME^%ZIS
 I $D(ZTSK) W !!,"QUEUED TO TASK ",ZTSK,!!,"A mail message with the results will be sent to your MailMan 'IN' basket.",!
 E  W !!,*7,"QUEUE UNSUCCESSFUL.  RESTART UTILITY."
 Q
START ;EP - From Taskman
 ;
 NEW XMSUB,XMDUZ,XMTEXT,XMY
 K ^TMP($J,"RSLT")
 D START^AUM95021
 S (XMSUB,XMDUZ)=$P($P($T(+1),";",2)," ",4,99),XMTEXT="^TMP($J,""RSLT"",",XMY(1)="",XMY(DUZ)="" D ^XMD
 K ^TMP($J,"RSLT")
 I $D(ZTQUEUED) S ZTREQ="@"
 E  W !!,"The results are in your MailMan 'IN' basket.",!
 Q
 ;
INTRO ;
 W ! F %=2:1:8 W ?5,$P($T(INTRO+%),";;",2),!
 ;;  ***  This is not a change to the Standard Code Book.  ***
 ;;For operational considerations, the RPMS LOCATION file will be
 ;;edited to reflect Ketchikan, Alaska, as an IHS facility.  Editing
 ;;of Ketchikan from an IHS facility to a Non-IHS facility (Area code
 ;;from 30 to 35) was done with patch 7 to AUM 94.1, distributed in
 ;;August 1994.
 ;;    This patch is at the request of the Alaska Area ISC.
 Q
Q2 ;EP - From DIR
 W ! F %=2:1:7 W ?5,$P($T(Q2+%),";;",2),!
 ;;Answer "Y" if you want to queue this standard table update to TaskMan.
 ;;Answer "N" if you want to run this update interactively.
 ;;
 ;;If you run interactively, results will be displayed on your screen,
 ;;as well as in the mail message sent to you and user 1.  If you queue
 ;;to TaskMan, please read the mail message for results of this patch.
 Q

AUM95021
AUM95021 ; DSD/GTH - STANDARD TABLE UPDATES (1), KETCHIKAN ; [ 03/03/95  2:13 PM ]
 ;;95.1;TABLE MAINTENANCE;**3**;NOV 1, 1994
 Q
 ;
START ;EP
 NEW A,C,DIC,DIE,DLAYGO,DR,E,L,N,O,P,R,S,T
 S E(0)="ERROR : ",E(1)="NOT ADDED : "
 D LOCMOD
 D RSLT(" ")
 F A=2:1:8 D RSLT($P($T(INTRO+A^AUM9502),";",3))
 D RSLT(" "),RSLT(" - It is suggested that you print the mail message for future"),RSLT(" - reference to this situation.")
 Q
 ;
ADDOK D RSLT(E_", Added : "_L) Q
ADDFAIL D RSLT(E(0)_E_" : ADD FAILED => "_L) Q
DIE NEW A,C,E,L,N,O,P,R,S,T
 LOCK +(@(DIE_DA_")")):10 E  D RSLT(E(0)_"Entry '"_DIE_DA_"' IS LOCKED.  NOTIFY PROGRAMMER.") S Y=1 Q
 D ^DIE LOCK -(@(DIE_DA_")")) K DA,DIE,DR Q
IEN(X,%,Y) ;EP
 S Y=$O(@(X_"""C"",%,0)"))
 I 'Y S Y=$T(@%^AUM9502M) I Y NEW Z S Z=E D  S:Y<0 Y="" S E=Z
 . NEW A,C,L,N,O,P,R,S,V,%
 . S L=Y
 . I X["AREA" NEW X S E=E_" (Add Area) " D ADDAREA Q
 . I X["SU" NEW X S E=E_" (Add SU) " D ADDSU Q
 . I X["CTY" NEW X S E=E_" (Add County) " D ADDCNTY Q
 .Q
 D:'Y RSLT(E(0)_E_" : "_$P(@(X_"0)"),U)_" DOES NOT EXIST => "_%)
 Q +Y
FILE NEW A,C,E,L,N,O,P,R,S,T K DD,DO S DIC(0)="L" D FILE^DICN K DIC Q
MODOK D RSLT(E_", Changed : "_L) Q
RSLT(%) S ^(0)=$G(^TMP($J,"RSLT",0))+1,^(^(0))=% W:'$D(ZTQUEUED) !,% Q
 ;
AREANEW ;
 S E="New Area Codes"
 F T=1:1 S L=$T(AREANEW+T^AUM9502A) Q:$P(L,";",3)="END"  D ADDAREA
 Q
 ;
ADDAREA ;
 S L=$P(L,";;",2),A=$P(L,U),N=$P(L,U,2),R=$P(L,U,3),C=$P(L,U,4),L=A_"  "_N_"  "_R_"  "_C
 I $D(^AUTTAREA("B",N)) D RSLT(E(1)_E_" : NAME EXISTS => "_N) Q
 I $D(^AUTTAREA("C",A)) D RSLT(E(1)_E_" : CODE EXISTS => "_A) Q
 S DLAYGO=9999999.21,DIC="^AUTTAREA(",X=N,DIC("DR")=".02///"_A_";.03///"_R_";.04///"_C D FILE
 D ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
SUNEW ;
 S E="New Service Unit Codes"
 F T=1:1 S L=$T(SUNEW+T^AUM9502A) Q:$P(L,";",3)="END"  D ADDSU
 Q
 ;
ADDSU ;
 S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),N=$P(L,U,3),L=A_"  "_S_"  "_N
 I $D(^AUTTSU("C",A_S)) D RSLT(E(1)_E_" : ASU EXISTS => "_A_S) Q
 S P=$$IEN("^AUTTAREA(",A) Q:'P
 S DLAYGO=9999999.22,DIC="^AUTTSU(",X=N,DIC("DR")=".02////"_P_";.03///"_S D FILE
 D ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
LOCNEW ;
 S E="New Location Codes"
 F T=1:1 S L=$T(LOCNEW+T^AUM9502A) Q:$P(L,";",3)="END"  D ADDLOC
 Q
 ;
ADDLOC ;
 S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3),N=$P(L,U,4),P=$P(L,U,5)
 S L=A_"  "_S_"  "_F_"  "_N_"  "_P
 S %=A_S_F,%=$O(^AUTTLOC("C",%,0))
 I % D RSLT(E(1)_E_" : ASUFAC EXISTS => "_A_S_F) D  Q
 .I $P($G(^AUTTLOC(%,0)),U,21) S DIE="^AUTTLOC(",DA=%,DR=".27///@" D DIE D:$D(Y) RSLT(E(1)_E_" : DELETE INACTIVE DATE FAILED => "_L) D:'$D(Y) RSLT(E_" : INACTIVE DATE DELETED => "_L)
 .S %=$O(^AUTTLOC("C",A_S_F,0)),%=$P(^AUTTLOC(%,0),U)
 .I %,$D(^DIC(4,%,0)),N'=$P(^DIC(4,%,0),U) S DIE="^DIC(4,",DA=%,DR=".01///"_N D DIE D:$D(Y) RSLT(E(0)_E_" : EDIT INSTITUTION FAILED => "_L) D:'$D(Y) RSLT(E_" : INSTITUTION NAME UPDATED => "_L)
 .S %=$O(^AUTTLOC("C",A_S_F,0))
 .I P'=$P($G(^AUTTLOC(%,1)),U,2) S DIE="^AUTTLOC(",DA=%,DR=".31///"_P D DIE D:$D(Y) RSLT(E(0)_E_" : EDIT PSEUDO PREFIX FAILED => "_L) D:'$D(Y) RSLT(E_" : PSEUDO PREFIX UPDATED => "_L)
 .Q
 S P("A")=$$IEN("^AUTTAREA(",A) Q:'P("A")
 S P("S")=$$IEN("^AUTTSU(",A_S) Q:'P("S")
 F DINUM=+$P(^DIC(4,0),U,3):1 Q:'$D(^DIC(4,DINUM))&('$D(^AUTTLOC(DINUM)))  I DINUM>99999 D RSLT(E(0)_"DINUM FOR LOC/INSTITUTION TOO BIG. NOTIFY ISC.") Q
 Q:DINUM>99999
 S DLAYGO=4,DIC="^DIC(4,",X=N D FILE
 I Y<0 D RSLT(E(0)_E_" : ^DIC(4 ADD FAILED => "_L) Q
 S DINUM=+Y,DLAYGO=9999999.06,DIC="^AUTTLOC(",X=DINUM,DIC("DR")=".04////"_P("A")_";.05////"_P("S")_";.07///"_F_";.31///"_P D FILE
 D ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
LOCMOD ;
 S E="Location Code Changes"
 F T=1:2 S L=$T(LOCMOD+T^AUM9502A) Q:$P(L,";",3)="END"  S L("TO")=$T(LOCMOD+T+1^AUM9502A) D
 .S L=$P(L,U,2,99),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3)
 .S P=$O(^AUTTLOC("C",A_S_F,0))
 .S L=$P(L("TO"),U,2,99),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3),N=$P(L,U,4)
 .I 'P S P=$O(^AUTTLOC("C",A_S_F,0)) I 'P S L=";;"_L D ADDLOC Q
 .S L=A_"  "_S_"  "_F_"  "_N_"  "_$P(L("TO"),U,6)
 .S P("A")=$$IEN("^AUTTAREA(",A) Q:'P("A")
 .S P("S")=$$IEN("^AUTTSU(",A_S) Q:'P("S")
 .S DIE="^AUTTLOC(",DA=P,DR=".04////"_P("A")_";.05////"_P("S")_";.07///"_F_";.31///"_$P(L("TO"),U,6) D DIE
 .I $D(Y) D RSLT(E(0)_E_" : EDIT LOCATION FAILED => "_L) Q
 .S DIE="^DIC(4,",DA=$P(^AUTTLOC(P,0),U),DR=".01///"_N D DIE
 .I $D(Y) D RSLT(E(0)_E_" : EDIT INSTITUTION FAILED => "_L) Q
 .D MODOK
 .Q
 Q
 ;

AUM9502A
AUM9502A ; DSD/GTH - STANDARD TABLE UPDATES DATA A, KETCHIKAN ; [ 03/03/95  1:58 PM ]
 ;;95.1;TABLE MAINTENANCE;**3**;NOV 1, 1994
 ;
 ;  This is not a change to the Standard Code Book.  The RPMS Standard
 ;  tables will be edited to reflect Ketchikan as an IHS facility for
 ;  operational considerations.  Editing of Ketchikan from an IHS
 ;  facility to a Non-IHS facility (Area code from 30 to 35) was done
 ;  with patch 7 to AUM 94.1, distributed in August 1994.  This patch
 ;  is at the request of the Alaska Area ISC.
 ;
LOCMOD ;;    ^AREA^S.U.^FAC.^NAME^PSEUDO^Y
 ;;FROM^35^36^11^SEARHC HC - KETCHIKAN^ABU
 ;;  TO^30^36^11^SEARHC HC - KETCHIKAN^ABU
 ;;END

AUM9502M
AUM9502M ; DSD/GTH - BACKGROUND VALUES FOR STANDARD TABLE UPDATES, KETCHIKAN ; [ 03/03/95  1:51 PM ]
 ;;95.1;TABLE MAINTENANCE;**3**;NOV 1, 1994
 ;
AREA ; CODE^NAME^PREFIX/REGION^CAN PREFIX
30 ;;30^ALASKA^A^J59
 ;;
SU ; AREA^SU^NAME
3036 ;;30^36^MT.EDGECUMBE
 ;;
COUNTY ; STATE^COUNTY^NAME
 ;;