11:36 AM  6-JUL-95
AUM v 95.1, patch 6, SCB updates, 05Jul95 Banyan.
A9AUM6
A9AUM6 ; IHS/ADC/GTH - STANDARD TABLE UPDATES, 05JUL95 BANYAN, RPI ; [ 07/06/95  11:35 AM ]
 ;;95.1;TABLE MAINTENANCE;**6**;NOV 1, 1994
 ;
 D START^AUM9507
 ;
 Q:'$L($G(^%ZOSF("DEL")))
 NEW X
 F %=1:1 S X=$P($T(DEL+%),";",3) Q:X=""  X ^%ZOSF("DEL")
 Q
DEL ;     
 ;;A9AUM5
 ;;AUM9507
 ;;AUM95071
 ;;AUM95072
 ;;AUM9507A
 ;;AUM9507M

AUM9507
AUM9507 ; IHS/ADC/GTH - STANDARD TABLE UPDATES, 05JUL95 BANYAN ; [ 07/05/95   4:50 PM ]
 ;;95.1;TABLE MAINTENANCE;**6**;NOV 1, 1994
 ;
 I '$G(DUZ) W !,"DUZ UNDEFINED OR ZERO.",! Q
 D HOME^%ZIS,DT^DICRW,INTRO
 S (DIR(0),DIR("B"))="Y"
 S DIR("A")="Do you want to queue the utility to TaskMan"
 S DIR("??")="^D Q2^AUM9507"
 D ^DIR G Q2:$D(DIRUT),START:'Y
QUE ;
 S %DT="AERSX",%DT("A")="Requested Start Time: ",%DT("B")="T@2015",%DT(0)="NOW" D ^%DT
 I Y<1 W !,"QUEUE INFORMATION MISSING - NOT QUEUED",!!,"Okay...",! D Q2 Q
 S X=+Y D H^%DTC S ZTDTH=%H_","_%T
 S ZTRTN="START^AUM9507",ZTIO="",ZTDESC=$P($P($T(+1),";",2)," ",4,99)
 D ^%ZTLOAD,HOME^%ZIS
 I $D(ZTSK) W !!,"QUEUED TO TASK ",ZTSK,!!,"A mail message with the results will be sent to your MailMan 'IN' basket.",!
 E  W !!,*7,"QUEUE UNSUCCESSFUL.  RESTART UTILITY."
 Q
START ;EP - From Taskman
 ;
 NEW XMSUB,XMDUZ,XMTEXT,XMY
 K ^TMP("AUM SCB",$J)
 D START^AUM95071,START^AUM95072
 S (XMSUB,XMDUZ)=$P($P($T(+1),";",2)," ",4,99),XMTEXT="^TMP(""AUM SCB"",$J,",XMY(1)="",XMY(DUZ)="" D ^XMD
 K ^TMP("AUM SCB",$J)
 I $D(ZTQUEUED) S ZTREQ="@"
 E  W !!,"The results are in your MailMan 'IN' basket.",!
 Q
 ;
INTRO ;
 W ! F %=2:1:5 W ?5,$P($T(INTRO+%),";;",2),!
 ;;This patch updates standard tables according to the changes
 ;;specified in the Banyan message time stamped 05Jul95@09:33:03 MDT,
 ;;Please consult that message, and the mail message produced by this
 ;;utility.
 Q
Q2 ;EP - From DIR
 W ! F %=2:1:7 W ?5,$P($T(Q2+%),";;",2),!
 ;;Answer "Y" if you want to queue this standard table update to TaskMan.
 ;;Answer "N" if you want to run this update interactively.
 ;;
 ;;If you run interactively, results will be displayed on your screen,
 ;;as well as in the mail message sent to you and user 1.  If you queue
 ;;to TaskMan, please read the mail message for results of this patch.
 Q

AUM95071
AUM95071 ; IHS/ADC/GTH - STANDARD TABLE UPDATES (1), 05JUL95 BANYAN ; [ 07/06/95  10:10 AM ]
 ;;95.1;TABLE MAINTENANCE;**6**;NOV 1, 1994
 Q
 ;
START ;EP
 ;
 NEW A,C,DIC,DIE,DLAYGO,DR,E,L,N,O,P,R,S,T
 ;
 S E(0)="ERROR : ",E(1)="NOT ADDED : "
 D LOCNEW,LOCMOD
 ;
 Q
 ;
ADDOK D RSLT(E_", Added : "_L) Q
ADDFAIL D RSLT(E(0)_E_" : ADD FAILED => "_L) Q
DIE NEW A,C,E,L,N,O,P,R,S,T
 LOCK +(@(DIE_DA_")")):10 E  D RSLT(E(0)_"Entry '"_DIE_DA_"' IS LOCKED.  NOTIFY PROGRAMMER.") S Y=1 Q
 D ^DIE LOCK -(@(DIE_DA_")")) K DA,DIE,DR Q
IEN(X,%,Y) ;EP
 S Y=$O(@(X_"""C"",%,0)"))
 I 'Y S Y=$T(@%^AUM9507M) I Y NEW Z S Z=E D  S:Y<0 Y="" S E=Z
 . NEW A,C,L,N,O,P,R,S,V,%
 . S L=Y
 . I X["AREA" NEW X S E=E_" (Add Area) " D ADDAREA Q
 . I X["SU" NEW X S E=E_" (Add SU) " D ADDSU Q
 . I X["CTY" NEW X S E=E_" (Add County) " D ADDCNTY Q
 .Q
 D:'Y RSLT(E(0)_E_" : "_$P(@(X_"0)"),U)_" DOES NOT EXIST => "_%)
 Q +Y
FILE NEW A,C,E,L,N,O,P,R,S,T K DD,DO S DIC(0)="L" D FILE^DICN K DIC Q
MODOK D RSLT(E_", Changed : "_L) Q
RSLT(%) S ^(0)=$G(^TMP("AUM SCB",$J,0))+1,^(^(0))=% W:'$D(ZTQUEUED) !,% Q
 ;
AREANEW ;
 S E="New Area Codes"
 F T=1:1 S L=$T(AREANEW+T^AUM9507A) Q:$P(L,";",3)="END"  D ADDAREA
 Q
 ;
ADDAREA ;
 S L=$P(L,";;",2),A=$P(L,U),N=$P(L,U,2),R=$P(L,U,3),C=$P(L,U,4),L=A_"  "_N_"  "_R_"  "_C
 I $D(^AUTTAREA("B",N)) D RSLT(E(1)_E_" : NAME EXISTS => "_N) Q
 I $D(^AUTTAREA("C",A)) D RSLT(E(1)_E_" : CODE EXISTS => "_A) Q
 S DLAYGO=9999999.21,DIC="^AUTTAREA(",X=N,DIC("DR")=".02///"_A_";.03///"_R_";.04///"_C D FILE
 D ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
SUNEW ;
 S E="New Service Unit Codes"
 F T=1:1 S L=$T(SUNEW+T^AUM9507A) Q:$P(L,";",3)="END"  D ADDSU
 Q
 ;
ADDSU ;
 S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),N=$P(L,U,3),L=A_"  "_S_"  "_N
 I $D(^AUTTSU("C",A_S)) D RSLT(E(1)_E_" : ASU EXISTS => "_A_S) Q
 S P=$$IEN("^AUTTAREA(",A) Q:'P
 S DLAYGO=9999999.22,DIC="^AUTTSU(",X=N,DIC("DR")=".02////"_P_";.03///"_S D FILE
 D ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
LOCNEW ;
 S E="New Location Codes"
 F T=1:1 S L=$T(LOCNEW+T^AUM9507A) Q:$P(L,";",3)="END"  D ADDLOC
 Q
 ;
ADDLOC ;
 S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3),N=$P(L,U,4),P=$P(L,U,5)
 S L=A_"  "_S_"  "_F_"  "_N_"  "_P
 S %=A_S_F,%=$O(^AUTTLOC("C",%,0))
 I % D RSLT(E(1)_E_" : ASUFAC EXISTS => "_A_S_F) D  Q
 .I $P($G(^AUTTLOC(%,0)),U,21) S DIE="^AUTTLOC(",DA=%,DR=".27///@" D DIE D:$D(Y) RSLT(E(1)_E_" : DELETE INACTIVE DATE FAILED => "_L) D:'$D(Y) RSLT(E_" : INACTIVE DATE DELETED => "_L)
 .S %=$O(^AUTTLOC("C",A_S_F,0)),%=$P(^AUTTLOC(%,0),U)
 .I %,$D(^DIC(4,%,0)),N'=$P(^DIC(4,%,0),U) S DIE="^DIC(4,",DA=%,DR=".01///"_N D DIE D:$D(Y) RSLT(E(0)_E_" : EDIT INSTITUTION FAILED => "_L) D:'$D(Y) RSLT(E_" : INSTITUTION NAME UPDATED => "_L)
 .S %=$O(^AUTTLOC("C",A_S_F,0))
 .I P'=$P($G(^AUTTLOC(%,1)),U,2) S DIE="^AUTTLOC(",DA=%,DR=".31///"_P D DIE D:$D(Y) RSLT(E(0)_E_" : EDIT PSEUDO PREFIX FAILED => "_L) D:'$D(Y) RSLT(E_" : PSEUDO PREFIX UPDATED => "_L)
 .Q
 S P("A")=$$IEN("^AUTTAREA(",A) Q:'P("A")
 S P("S")=$$IEN("^AUTTSU(",A_S) Q:'P("S")
 F DINUM=+$P(^DIC(4,0),U,3):1 Q:'$D(^DIC(4,DINUM))&('$D(^AUTTLOC(DINUM)))  I DINUM>99999 D RSLT(E(0)_"DINUM FOR LOC/INSTITUTION TOO BIG. NOTIFY ISC.") Q
 Q:DINUM>99999
 S DLAYGO=4,DIC="^DIC(4,",X=N D FILE
 I Y<0 D RSLT(E(0)_E_" : ^DIC(4 ADD FAILED => "_L) Q
 S DINUM=+Y,DLAYGO=9999999.06,DIC="^AUTTLOC(",X=DINUM,DIC("DR")=".04////"_P("A")_";.05////"_P("S")_";.07///"_F_";.31///"_P D FILE
 D ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
LOCMOD ;
 S E="Location Code Changes"
 F T=1:2 S L=$T(LOCMOD+T^AUM9507A) Q:$P(L,";",3)="END"  S L("TO")=$T(LOCMOD+T+1^AUM9507A) D
 .S L=$P(L,U,2,99),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3)
 .S P=$O(^AUTTLOC("C",A_S_F,0))
 .S L=$P(L("TO"),U,2,99),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3),N=$P(L,U,4)
 .I 'P S P=$O(^AUTTLOC("C",A_S_F,0)) I 'P S L=";;"_L D ADDLOC Q
 .S L=A_"  "_S_"  "_F_"  "_N_"  "_$P(L("TO"),U,6)
 .S P("A")=$$IEN("^AUTTAREA(",A) Q:'P("A")
 .S P("S")=$$IEN("^AUTTSU(",A_S) Q:'P("S")
 .S DIE="^AUTTLOC(",DA=P,DR=".04////"_P("A")_";.05////"_P("S")_";.07///"_F_";.31///"_$P(L("TO"),U,6) D DIE
 .I $D(Y) D RSLT(E(0)_E_" : EDIT LOCATION FAILED => "_L) Q
 .S DIE="^DIC(4,",DA=$P(^AUTTLOC(P,0),U),DR=".01///"_N D DIE
 .I $D(Y) D RSLT(E(0)_E_" : EDIT INSTITUTION FAILED => "_L) Q
 .D MODOK
 .Q
 D RSLT($$LOCMOD^AUMXPORT("AUM9507A")_" patients marked for export because of the Location Code changes.")
 ;
 Q
 ;
ADDCNTY ;
 S L=$P(L,";;",2),S=$P(L,U),C=$P(L,U,2),N=$P(L,U,3),L=S_"  "_C_"  "_N
 I $D(^AUTTCTY("C",S_C)) D RSLT(E(1)_E_" : CODE EXISTS => "_S_C) Q
 S P("S")=$$IEN("^DIC(5,",S) Q:'P("S")
 S DIC="^AUTTCTY(",X=N,DIC("DR")=".02////"_P("S")_";.03///"_C D FILE
 D ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;

AUM95072
AUM95072 ; IHS/ADC/GTH - STANDARD TABLE UPDATES (2), 05JUL95 BANYAN ; [ 07/06/95  10:16 AM ]
 ;;95.1;TABLE MAINTENANCE;**6**;NOV 1, 1994
 ;
 Q
 ;
START ;EP
 ;
 NEW A,C,DIC,DIE,DLAYGO,DR,E,L,N,O,P,R,S,T
 ;
 S E(0)="ERROR : ",E(1)="NOT ADDED : "
 D COMMNEW,COMMMOD
 Q
 ; ===   utility sub-routines   ====
 ;
ADDOK D RSLT(E_", Added : "_L) Q
ADDFAIL D RSLT(E(0)_E_" : ADD FAILED => "_L) Q
DIE NEW A,C,E,L,N,O,P,R,S,T
 LOCK +(@(DIE_DA_")")):10 E  D RSLT(E(0)_"Entry '"_DIE_DA_"' IS LOCKED.  NOTIFY PROGRAMMER.") S Y=1 Q
 D ^DIE LOCK -(@(DIE_DA_")")) K DA,DIE,DR Q
FILE NEW A,C,E,L,N,O,P,R,S,T K DD,DO S DIC(0)="L" D FILE^DICN K DIC Q
MODOK D RSLT(E_", Changed : "_L) Q
RSLT(%) S ^(0)=$G(^TMP("AUM SCB",$J,0))+1,^(^(0))=% W:'$D(ZTQUEUED) !,% Q
 ;
 ; =================================
 ;
COMMNEW ;
 S E="New Community Codes"
 F T=1:1 S L=$T(COMMNEW+T^AUM9507A) Q:$P(L,";",3)="END"  D ADDCOMM
 Q
 ;
ADDCOMM ;
 S L=$P(L,";;",2),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3),N=$P(L,U,4),A=$P(L,U,5),V=$P(L,U,6),L=S_" "_O_" "_C_" "_N_" "_A_" "_V
 I $D(^AUTTCOM("C",S_O_C)) D RSLT(E(1)_E_" : STCTYCOM CODE EXISTS => "_S_O_C) Q
 S P("O")=$$IEN^AUM95071("^AUTTCTY(",S_O) Q:'P("O")
 S P("A")=$$IEN^AUM95071("^AUTTAREA(",A) Q:'P("A")
 S P("V")=$$IEN^AUM95071("^AUTTSU(",A_V) Q:'P("V")
 S DLAYGO=9999999.05,DIC="^AUTTCOM(",X=N,DIC("DR")=".02////"_P("O")_";.05////"_P("V")_";.06////"_P("A")_";.07///"_C
 D FILE
 D ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
COMMMOD ;
 S E="Community Code Changes"
 F T=1:2 S L=$T(COMMMOD+T^AUM9507A) Q:$P(L,";",3)="END"  S L("TO")=$T(COMMMOD+T+1^AUM9507A) D
 . S L=$P(L,U,2,99),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3)
 . S P=$O(^AUTTCOM("C",S_O_C,0))
 . S L=$P(L("TO"),U,2,99),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3),N=$P(L,U,4),A=$P(L,U,5),V=$P(L,U,6)
 . I 'P S P=$O(^AUTTCOM("C",S_O_C,0)) I 'P S L=";;"_L D ADDCOMM Q
 . S L=S_" "_O_" "_C_" "_N_" "_A_" "_V
 . S P("O")=$$IEN^AUM95071("^AUTTCTY(",S_O) Q:'P("O")
 . S P("A")=$$IEN^AUM95071("^AUTTAREA(",A) Q:'P("A")
 . S P("V")=$$IEN^AUM95071("^AUTTSU(",A_V) Q:'P("V")
 . S DIE="^AUTTCOM(",DA=P,DR=".01///"_N_";.02////"_P("O")_";.05////"_P("V")_";.06////"_P("A")_";.07///"_C
 . D DIE
 . I $D(Y) D RSLT(E(0)_E_" : CHANGE FAILED => "_L) Q
 . D MODOK
 .Q
 D RSLT($$COMMMOD^AUMXPORT("AUM9507A")_" patients marked for export because of the Community Code changes.")
 Q
 ;

AUM9507A
AUM9507A ; IHS/ADC/GTH - STANDARD TABLE UPDATES DATA A, 05JUL95 BANYAN ; [ 07/06/95  11:34 AM ]
 ;;95.1;TABLE MAINTENANCE;**6**;NOV 1, 1994
 ;
 ;  If you do not want new entries made in your area, remove the line.
 ;
 ;  If you don't want the modifications performed in your area, remove
 ;    BOTH the FROM line and the TO line.
 ;
LOCNEW ;;A. NEW LOCATION CODES (SECTION VIII-C): AREA^S.U.^FAC.^NAME^PSEUDO
 ;;15^37^82^NIOBRARA^CCA
 ;;END
 ;;
LOCMOD ;;B. LOCATION CODE CHANGES (SECTION VIII-C): AREA^S.U.^FAC.^NAME^PSEUDO
 ;;FROM^66^10^30^EL DORADO^LAB
 ;;  TO^66^34^30^EL DORADO^LAZ
 ;;FROM^80^86^01^SHIPROCK HOSP^NFA
 ;;  TO^80^86^01^NORTHERN NAVAJO MEDICAL CTR^NFA
 ;;END
 ;;
 ;;
COMMNEW ;;C.  NEW COMMUNITY CODES (SECTION V-C): STATE^CNTY^COMM^NAME^AREA^S.U.
 ;;27^16^125^COLVILLE^18^25
 ;;27^27^288^MAPLE GROVE^11^00
 ;;27^60^100^NIELSVILLE^11^35
 ;;27^73^289^SAUK CENTRE^11^00
 ;;30^45^528^NOXON^45^43
 ;;30^45^529^HERON^45^43
 ;;30^45^530^TROUT CREEK^45^43
 ;;46^05^020^BROOKINGS^10^00
 ;;46^50^100^EGAN^15^11
 ;;46^50^101^TRENT^15^11
 ;;END
COMMMOD ;;D. COMMUNITY CODE CHANGES (SECTION V-C): STATE^CNTY^COMM^NAME^AREA^S.U.
 ;;FROM^06^09^100^RESCUE^66^10
 ;;  TO^06^09^100^RESCUE^66^34
 ;;FROM^06^09^101^SOMERSET^66^10
 ;;  TO^06^09^101^SOMERSET^66^34
 ;;FROM^06^09^102^GREENWOOD^66^10
 ;;  TO^06^09^102^GREENWOOD^66^34
 ;;FROM^06^09^103^GEORGETOWN^66^10
 ;;  TO^06^09^103^GEORGETOWN^66^34
 ;;FROM^06^09^104^CAMINO^66^10
 ;;  TO^06^09^104^CAMINO^66^34
 ;;FROM^06^09^105^KELSEY^66^10
 ;;  TO^06^09^105^KELSEY^66^34
 ;;FROM^06^09^106^CAMERON PARK^66^10
 ;;  TO^06^09^106^CAMERON PARK^66^34
 ;;FROM^06^09^107^GARDEN VALLEY^66^10
 ;;  TO^06^09^107^GARDEN VALLEY^66^34
 ;;FROM^06^09^108^LOTUS^66^10
 ;;  TO^06^09^108^LOTUS^66^34
 ;;FROM^06^09^109^COLOMA^66^10
 ;;  TO^06^09^109^COLOMA^66^34
 ;;FROM^06^09^110^PILOT HILL^66^10
 ;;  TO^06^09^110^PILOT HILL^66^34
 ;;FROM^06^09^111^WEIMAR^66^10
 ;;  TO^06^09^111^WEIMAR^66^34
 ;;FROM^06^09^305^PLACERVILLE^66^10
 ;;  TO^06^09^305^PLACERVILLE^66^34
 ;;FROM^06^09^336^SHINGLE SPRING RANCH^66^10
 ;;  TO^06^09^336^SHINGLE SPRING RANCH^66^34
 ;;FROM^06^09^345^EL DORADO COUNTY WIDE^66^10
 ;;  TO^06^09^345^EL DORADO COUNTY WIDE^66^34
 ;;FROM^06^09^488^POLLACK PINES^66^10
 ;;  TO^06^09^488^POLLOCK PINES^66^34
 ;;FROM^06^09^806^DIAMOND SPRG^66^10
 ;;  TO^06^09^806^DIAMOND SPRG^66^34
 ;;FROM^06^09^807^SO. LAKE TAHOE^66^10
 ;;  TO^06^09^807^SO. LAKE TAHOE^66^34
 ;;FROM^06^55^113^TWIN HARTE^66^25
 ;;  TO^06^55^113^TWAIN HARTE^66^25
 ;;FROM^06^58^137^CAPAY^66^15
 ;;  TO^06^11^137^CAPAY^66^15
 ;;FROM^30^32^382^FRANCHTON^45^43
 ;;  TO^30^32^382^FRENCHTOWN^45^43
 ;;END
 ;

AUM9507M
AUM9507M ; IHS/ADC/GTH - BACKGROUND VALUES FOR STANDARD TABLE UPDATES, 05JUL95 BANYAN ; [ 07/05/95  4:37 PM ]
 ;;95.1;TABLE MAINTENANCE;**6**;NOV 1, 1994
 ;
AREA ; CODE^NAME^PREFIX/REGION^CAN PREFIX
10 ;;10^ABERDEEN^C^J45
11 ;;11^BEMIDJI^D^J46
15 ;;15^ABERDEEN TRIBE/638^C^J45
18 ;;18^BEMIDJI NON-IHS^D^J46
45 ;;45^BILLINGS TRIBE/638^B^J47
66 ;;66^CALIFORNIA TRIBE/638^L^J41
80 ;;80^NAVAJO^N^J54
 ;;
SU ; AREA^SU^NAME
1000 ;;10^00^NON SERVICE UNIT
1100 ;;11^00^NON SERVICE UNIT
1135 ;;11^35^WHITE EARTH
1511 ;;15^11^FLANDREAU
1537 ;;15^37^NORTHERN PONCA
1825 ;;18^25^GRAND PORTAGE
4543 ;;45^43^FLATHEAD
6615 ;;66^15^NORTH VALLEY
6625 ;;66^25^TUOLUMNE
6634 ;;66^34^SHINGLE SPRINGS TRIB HLTH PROG
8086 ;;80^86^SHIPROCK
 ;;
COUNTY ; STATE^COUNTY^NAME
0609 ;;06^09^EL DORADO
0611 ;;06^11^GLENN
0655 ;;06^55^TUOLUMNE
2716 ;;27^16^COOK
2727 ;;27^27^HENNEPIN
2760 ;;27^60^POLK
2773 ;;27^73^STEARNS
3032 ;;30^32^MISSOULA
3045 ;;30^45^SANDERS
4605 ;;46^05^BROOKINGS
4650 ;;46^50^MOODY
 ;;

AUMXPORT
AUMXPORT ; IHS/ADC/GTH - MARK PT'S FOR REG EXPORT ; [ 07/05/95  4:45 PM ]
 ;;95.1;TABLE MAINTENANCE;**6**;NOV 1, 1994
 ;
 Q
 ;
 ; ----------------------------------------------------------------
 ;
SETUP ;
 D NOW^%DTC
 S N=%
 S W="W:'$D(ZTQUEUED) ""."""
 Q
 ;
 ; ----------------------------------------------------------------
 ;
 ;
COMMMOD(AUMRTN) ;EP - SET ^AGPATCH for Community Code Changes.
 ;
 ;  SET ^AGPATCH(NOW,DUZ(2),DFN)="" for a changed community.
 ;  The above was confirmed and agreed upon with the owner of
 ;  ^AGPATCH (Registration).
 ;
 NEW D,DFN,L,N,T,W
 ;
 ; D = Site DUZ(2).
 ; L = "TO" string, then the name of the community being changed.
 ; N = NOW
 ; T = Counter
 ; W = Write dot if not q'd.
 ;
 D SETUP
 ;
 F T=1:2 S L=$T(COMMMOD+T^@AUMRTN) Q:$P(L,";",3)="END"  X W S L=$P($T(COMMMOD+T+1^@AUMRTN),U,5),DFN=0 F  S DFN=$O(^AUPNPAT("AC",L,DFN)) Q:'DFN  X W S D=$O(^AUPNPAT(DFN,41,0)) X W I D S ^AGPATCH(N,D,DFN)=""
 G COUNT
 ; ----------------------------------------------------------------
 ;
LOCMOD(AUMRTN) ;EP - SET ^AGPATCH for Location Code Changes.
 ;
 NEW D,DFN,L,N,T,W
 ;
 D SETUP
 ;
 K ^TMP("AUMXPORT",$J)
 ;
 F T=1:2 S L=$T(LOCMOD+T^@AUMRTN) Q:$P(L,";",3)="END"  X W S L=$P($T(LOCMOD+T+1^@AUMRTN),U,2,4),L=$TR(L,"^",""),D=$O(^AUTTLOC("C",L,0)),DFN=0 I D S ^TMP("AUMXPORT",$J,D)=""
 ;
 S %="^AUPNPAT(""D"",0,0,0)"
 F  S %=$Q(@%) Q:'$L(%)  X:'((+$P(%,",",3))#1000) W I $D(^TMP("AUMXPORT",$J,+$P(%,",",4))) S ^AGPATCH(N,+$P(%,",",4),+$P(%,",",3))=""
 ;
 K ^TMP("AUMXPORT",$J)
 ;
 G COUNT
 ; ----------------------------------------------------------------
 ;
 ;
CLINMOD(AUMRTN) D SETUP G COUNT
 ; ----------------------------------------------------------------
CNTYMOD(AUMRTN) D SETUP G COUNT
 ; ----------------------------------------------------------------
RESMOD(AUMRTN) D SETUP G COUNT
 ; ----------------------------------------------------------------
TRIBMOD(AUMRTN) D SETUP G COUNT
 ; ----------------------------------------------------------------
 ;
COUNT ; Return the number of patients marked for export because of change.
 S (D,T)=0
 F  S D=$O(^AGPATCH(N,D)) Q:'D  X W S DFN=0 F  S DFN=$O(^AGPATCH(N,D,DFN)) Q:'DFN  X W S T=T+1
 Q T
 ;