4:18 PM  11-SEP-95
AUM v 95.1, Patch 8, SCB Changes via 11Sep95 BAnyan.  Restore 5 routines and DO ^AUM9509.
A9AUM8
A9AUM8 ; IHS/ADC/GTH - STANDARD TABLE UPDATES, 11SEP95 BANYAN, RPI ; [ 09/11/95  3:47 PM ]
 ;;95.1;TABLE MAINTENANCE;**8**;NOV 1, 1994
 ;
 D START^AUM9509
 ;
 Q:'$L($G(^%ZOSF("DEL")))
 NEW X
 F %=1:1 S X=$P($T(DEL+%),";",3) Q:X=""  X ^%ZOSF("DEL")
 Q
DEL ;     
 ;;A9AUM7
 ;;AUM9509
 ;;AUM95091
 ;;AUM9509A
 ;;AUM9509M

AUM9509
AUM9509 ; IHS/ADC/GTH - STANDARD TABLE UPDATES, 11SEP95 BANYAN ; [ 09/11/95   3:12 PM ]
 ;;95.1;TABLE MAINTENANCE;**8**;NOV 1, 1994
 ;
 I '$G(DUZ) W !,"DUZ UNDEFINED OR ZERO.",! Q
 D HOME^%ZIS,DT^DICRW,HELP("INTRO")
 S (DIR(0),DIR("B"))="Y"
 S DIR("A")="Do you want to queue the utility to TaskMan"
 S DIR("??")="^D HELP^AUM9509(""Q2"")"
 D ^DIR
 I $D(DIRUT) D HELP("Q2") Q
 G START:'Y
QUE ;
 S %DT="AERSX",%DT("A")="Requested Start Time: ",%DT("B")="T@2015",%DT(0)="NOW"
 D ^%DT
 I Y<1 W !,"QUEUE INFORMATION MISSING - NOT QUEUED" D Q2 G AUM9509
 S X=+Y
 D H^%DTC
 S ZTDTH=%H_","_%T
 S ZTRTN="START^AUM9509",ZTIO="",ZTDESC=$P($P($T(+1),";",2)," ",4,99)
 D ^%ZTLOAD,HOME^%ZIS
 I $D(ZTSK) W !!,"QUEUED TO TASK ",ZTSK,!!,"A mail message with the results will be sent to your MailMan 'IN' basket.",!
 E  W !!,*7,"QUEUE UNSUCCESSFUL.  RESTART UTILITY."
 Q
 ;
START ;EP - From Taskman
 ;
 NEW XMSUB,XMDUZ,XMTEXT,XMY
 K ^TMP("AUM SCB",$J)
 D START^AUM95091
 S (XMSUB,XMDUZ)=$P($P($T(+1),";",2)," ",4,99),XMTEXT="^TMP(""AUM SCB"",$J,",XMY(1)="",XMY(DUZ)="" D ^XMD
 K ^TMP("AUM SCB",$J)
 I $D(ZTQUEUED) S ZTREQ="@"
 E  W !!,"The results are in your MailMan 'IN' basket.",!
 Q
 ;
INTRO ;
 ;;This patch updates standard tables according to the changes
 ;;specified in the Banyan message time stamped 11Sep95@15:11:05 MDT,
 ;;Please consult that message, and the mail message produced by this
 ;;utility.
 ;;###
 ;
Q2 ;
 ;;Answer "Y" if you want to queue this standard table update to TaskMan.
 ;;Answer "N" if you want to run this update interactively.
 ;;
 ;;If you run interactively, results will be displayed on your screen,
 ;;as well as in the mail message sent to you and user 1.  If you queue
 ;;to TaskMan, please read the mail message for results of this patch.
 ;;###
 ;
HELP(L) ;EP - Display text at label L.
 W !
 F %=1:1 W !?4,$P($T(@L+%),";",3) Q:$P($T(@L+%+1),";",3)="###"
 Q
 ;

AUM95091
AUM95091 ; IHS/ADC/GTH - STANDARD TABLE UPDATES (1), 11SEP95 BANYAN ; [ 09/11/95  3:49 PM ]
 ;;95.1;TABLE MAINTENANCE;**8**;NOV 1, 1994
 Q
 ;
START ;EP
 ;
 NEW A,C,DIC,DIE,DLAYGO,DR,E,L,N,O,P,R,S,T
 ;
 S E(0)="ERROR : ",E(1)="NOT ADDED : "
 D SUNEW,LOCNEW,LOCINACT,COMMNEW
 ;
 Q
 ;
ADDOK D RSLT(E_", Added : "_L) Q
ADDFAIL D RSLT(E(0)_E_" : ADD FAILED => "_L) Q
DIE NEW A,C,E,L,N,O,P,R,S,T
 LOCK +(@(DIE_DA_")")):10 E  D RSLT(E(0)_"Entry '"_DIE_DA_"' IS LOCKED.  NOTIFY PROGRAMMER.") S Y=1 Q
 D ^DIE LOCK -(@(DIE_DA_")")) K DA,DIE,DR Q
IEN(X,%,Y) ;EP
 S Y=$O(@(X_"""C"",%,0)"))
 I 'Y S Y=$T(@%^AUM9509M) I Y NEW Z S Z=E D  S:Y<0 Y="" S E=Z
 . NEW A,C,L,N,O,P,R,S,V,%
 . S L=Y
 . I X["AREA" NEW X S E=E_" (Add Area) " D ADDAREA Q
 . I X["SU" NEW X S E=E_" (Add SU) " D ADDSU Q
 . I X["CTY" NEW X S E=E_" (Add County) " D ADDCNTY Q
 .Q
 D:'Y RSLT(E(0)_E_" : "_$P(@(X_"0)"),U)_" DOES NOT EXIST => "_%)
 Q +Y
FILE NEW A,C,E,L,N,O,P,R,S,T K DD,DO S DIC(0)="L" D FILE^DICN K DIC Q
MODOK D RSLT(E_", Changed : "_L) Q
RSLT(%) S ^(0)=$G(^TMP("AUM SCB",$J,0))+1,^(^(0))=% W:'$D(ZTQUEUED) !,% Q
 ;
AREANEW ;
 S E="New Area Codes"
 F T=1:1 S L=$T(AREANEW+T^AUM9509A) Q:$P(L,";",3)="END"  D ADDAREA
 Q
 ;
ADDAREA ;
 S L=$P(L,";;",2),A=$P(L,U),N=$P(L,U,2),R=$P(L,U,3),C=$P(L,U,4),L=A_"  "_N_"  "_R_"  "_C
 I $D(^AUTTAREA("B",N)) D RSLT(E(1)_E_" : NAME EXISTS => "_N) Q
 I $D(^AUTTAREA("C",A)) D RSLT(E(1)_E_" : CODE EXISTS => "_A) Q
 S DLAYGO=9999999.21,DIC="^AUTTAREA(",X=N,DIC("DR")=".02///"_A_";.03///"_R_";.04///"_C D FILE
 D ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
SUNEW ;
 S E="New Service Unit Codes"
 F T=1:1 S L=$T(SUNEW+T^AUM9509A) Q:$P(L,";",3)="END"  D ADDSU
 Q
 ;
ADDSU ;
 S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),N=$P(L,U,3),L=A_"  "_S_"  "_N
 I $D(^AUTTSU("C",A_S)) D RSLT(E(1)_E_" : ASU EXISTS => "_A_S) Q
 S P=$$IEN("^AUTTAREA(",A) Q:'P
 S DLAYGO=9999999.22,DIC="^AUTTSU(",X=N,DIC("DR")=".02////"_P_";.03///"_S D FILE
 D ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
LOCNEW ;
 S E="New Location Codes"
 F T=1:1 S L=$T(LOCNEW+T^AUM9509A) Q:$P(L,";",3)="END"  D ADDLOC
 Q
 ;
ADDLOC ;
 S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3),N=$P(L,U,4),P=$P(L,U,5)
 S L=A_"  "_S_"  "_F_"  "_N_"  "_P
 S %=A_S_F,%=$O(^AUTTLOC("C",%,0))
 I % D RSLT(E(1)_E_" : ASUFAC EXISTS => "_A_S_F) D  Q
 .I $P($G(^AUTTLOC(%,0)),U,21) S DIE="^AUTTLOC(",DA=%,DR=".27///@" D DIE D:$D(Y) RSLT(E(1)_E_" : DELETE INACTIVE DATE FAILED => "_L) D:'$D(Y) RSLT(E_" : INACTIVE DATE DELETED => "_L)
 .S %=$O(^AUTTLOC("C",A_S_F,0)),%=$P(^AUTTLOC(%,0),U)
 .I %,$D(^DIC(4,%,0)),N'=$P(^DIC(4,%,0),U) S DIE="^DIC(4,",DA=%,DR=".01///"_N D DIE D:$D(Y) RSLT(E(0)_E_" : EDIT INSTITUTION FAILED => "_L) D:'$D(Y) RSLT(E_" : INSTITUTION NAME UPDATED => "_L)
 .S %=$O(^AUTTLOC("C",A_S_F,0))
 .I P'=$P($G(^AUTTLOC(%,1)),U,2) S DIE="^AUTTLOC(",DA=%,DR=".31///"_P D DIE D:$D(Y) RSLT(E(0)_E_" : EDIT PSEUDO PREFIX FAILED => "_L) D:'$D(Y) RSLT(E_" : PSEUDO PREFIX UPDATED => "_L)
 .Q
 S P("A")=$$IEN("^AUTTAREA(",A) Q:'P("A")
 S P("S")=$$IEN("^AUTTSU(",A_S) Q:'P("S")
 F DINUM=+$P(^DIC(4,0),U,3):1 Q:'$D(^DIC(4,DINUM))&('$D(^AUTTLOC(DINUM)))  I DINUM>99999 D RSLT(E(0)_"DINUM FOR LOC/INSTITUTION TOO BIG. NOTIFY ISC.") Q
 Q:DINUM>99999
 S DLAYGO=4,DIC="^DIC(4,",X=N D FILE
 I Y<0 D RSLT(E(0)_E_" : ^DIC(4 ADD FAILED => "_L) Q
 S DINUM=+Y,DLAYGO=9999999.06,DIC="^AUTTLOC(",X=DINUM,DIC("DR")=".04////"_P("A")_";.05////"_P("S")_";.07///"_F_";.31///"_P D FILE
 D ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
LOCINACT ;
 S E="Inactivated Location Codes"
 F T=1:1 S L=$T(LOCINACT+T^AUM9509A) Q:$P(L,";",3)="END"  D
 . S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3),N=$P(L,U,4),P=$P(L,U,5)
 . S L=A_"  "_S_"  "_F_"  "_N_"  "_P
 . S %=A_S_F,%=$O(^AUTTLOC("C",%,0))
 . I '% D RSLT(E_" : ASUFAC "_A_S_F_" not found (OK).") Q
 . S DIE="^AUTTLOC(",DA=%,DR=".27////"_DT
 . D DIE
 . I $D(Y) D RSLT(E(1)_E_" : EDIT INACTIVE DATE FAILED => "_L) I 1
 . E  D RSLT(E_" : INACTIVATED => "_L)
 .Q
 Q
 ;
CNTYNEW ;
 S E="New County Codes"
 F T=1:1 S L=$T(CNTYNEW+T^AUM9509A) Q:$P(L,";",3)="END"  D ADDCNTY
 Q
 ;
ADDCNTY ;
 S L=$P(L,";;",2),S=$P(L,U),C=$P(L,U,2),N=$P(L,U,3),L=S_"  "_C_"  "_N
 I $D(^AUTTCTY("C",S_C)) D RSLT(E(1)_E_" : CODE EXISTS => "_S_C) Q
 S P("S")=$$IEN("^DIC(5,",S) Q:'P("S")
 S DIC="^AUTTCTY(",X=N,DIC("DR")=".02////"_P("S")_";.03///"_C D FILE
 D ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
COMMNEW ;
 S E="New Community Codes"
 F T=1:1 S L=$T(COMMNEW+T^AUM9509A) Q:$P(L,";",3)="END"  D ADDCOMM
 Q
 ;
ADDCOMM ;
 S L=$P(L,";;",2),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3),N=$P(L,U,4),A=$P(L,U,5),V=$P(L,U,6),L=S_" "_O_" "_C_" "_N_" "_A_" "_V
 I $D(^AUTTCOM("C",S_O_C)) D RSLT(E(1)_E_" : STCTYCOM CODE EXISTS => "_S_O_C) Q
 S P("O")=$$IEN^AUM95091("^AUTTCTY(",S_O) Q:'P("O")
 S P("A")=$$IEN^AUM95091("^AUTTAREA(",A) Q:'P("A")
 S P("V")=$$IEN^AUM95091("^AUTTSU(",A_V) Q:'P("V")
 S DLAYGO=9999999.05,DIC="^AUTTCOM(",X=N,DIC("DR")=".02////"_P("O")_";.05////"_P("V")_";.06////"_P("A")_";.07///"_C
 D FILE
 D ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;

AUM9509A
AUM9509A ; IHS/ADC/GTH - STANDARD TABLE UPDATES DATA A, 11SEP95 BANYAN ; [ 09/11/95  3:45 PM ]
 ;;95.1;TABLE MAINTENANCE;**8**;NOV 1, 1994
 ;
 ;  If you do not want new entries made in your area, remove the line.
 ;
 ;  If you don't want the modifications performed in your area, remove
 ;    BOTH the FROM line and the TO line.
 ;
SUNEW ;;A. NEW SERVICE UNIT CODES (SECTION VIII-B): AREA^S.U.^NAME
 ;;15^09^RAPID CITY
 ;;END
 ;
LOCNEW ; B. NEW LOCATION CODES (SECTION VIII-C): AREA^S.U.^FAC.^NAME^PSEUDO
 ;;15^09^11^ALL NATIONS CLINIC^CZZ
 ;;66^20^32^MANCHESTER/POINT ARENA^LIZ
 ;;END
 ;
LOCINACT ;;C. INACTIVE LOCATION CODES (SECTION VIII-C): AREA^S.U.^FAC.^NAME
 ;;66^22^31^POINT ARENA
 ;;66^22^55^MANCHESTER/POINT ARENA
 ;;END
 ;
COMMNEW ;;D.  NEW COMMUNITY CODES (SECTION V-C): STATE^CNTY^COMM^NAME^AREA^S.U.
 ;;06^04^200^BERRY CREEK^66^15
 ;;27^09^100^CROMWELL^18^24
 ;;27^09^101^HOLYOKE^18^24
 ;;27^69^102^ADOLPH^18^24
 ;;27^69^103^ALBORN^18^24
 ;;27^69^104^CANYON^18^24
 ;;27^69^105^COTTON^18^24
 ;;27^69^106^CULVER^18^24
 ;;27^69^107^FLOODWOOD^18^24
 ;;27^69^108^SAGINAW^18^24
 ;;27^69^109^TWIG^18^24
 ;;27^69^200^BABBITT^18^31
 ;;27^69^201^BIWABIK^18^31
 ;;27^69^202^BRIMSON^18^31
 ;;27^69^203^BRITT^18^31
 ;;27^69^204^BUHL^18^31
 ;;27^69^205^EMBARRASS^18^31
 ;;27^69^206^FORBES^18^31
 ;;27^69^207^IRON^18^31
 ;;27^69^208^KINNEY^18^31
 ;;27^69^209^MAKINEN^18^31
 ;;27^69^210^MELRUDE^18^31
 ;;27^69^211^TOIVOLA^18^31
 ;;27^69^212^WINTON^18^31
 ;;30^03^050^FT. BELKNAP AGENCY^40^44
 ;;41^05^120^VERNONIA^70^00
 ;;END
 ;

AUM9509M
AUM9509M ; IHS/ADC/GTH - BACKGROUND VALUES FOR STANDARD TABLE UPDATES, 11SEP95 BANYAN ; [ 09/11/95  3:33 PM ]
 ;;95.1;TABLE MAINTENANCE;**8**;NOV 1, 1994
 ;
AREA ; CODE^NAME^PREFIX/REGION^CAN PREFIX
15 ;;15^ABERDEEN TRIBE/638^C^J45
18 ;;18^BEMIDJI NON-IHS^D^J46
40 ;;40^BILLINGS^B^J47
66 ;;66^CALIFORNIA TRIBE/638^L^J41
70 ;;70^PORTLAND^P^J64
 ;
SU ; AREA^SU^NAME
1824 ;;18^24^FOND DU LAC
1831 ;;18^31^NETT LAKE
4044 ;;40^44^FT.BELKNAP
6615 ;;66^15^NORTH VALLEY
6620 ;;66^20^SONOMA CTY H
7000 ;;70^00^NON SERVICE UNIT
 ;
COUNTY ; STATE^COUNTY^NAME
0604 ;;06^04^BUTTE
2709 ;;27^09^CARLTON
2769 ;;27^69^ST LOUIS
3003 ;;30^03^BLAINE
4105 ;;41^05^COLUMBIA
 ;