12:56 PM  26-NOV-96
AUM v 96.1 Patch 11, SCB updates from 6Nov96 Banyan.  Restore 5 routines and DO ^AUM6111.
A9AUM11
A9AUM11 ; IHS/ADC/GTH - STANDARD TABLE UPDATES, 06NOV96 BANYAN, RPI ; [ 11/26/96  12:55 PM ]
 ;;96.1;TABLE MAINTENANCE;**11**;OCT 26,1995
 ;
 D START^AUM6111
INTERACT ;EP - Delete routines from interactive call.
 Q:'$L($G(^%ZOSF("DEL")))
 NEW AUM,X
 F AUM=1:1 S X=$P($T(DEL+AUM),";",3) Q:X=""  X ^%ZOSF("DEL") I '$D(ZTQUEUED) W !,X,$E("...........",1,11-$L(X)),"<poof'd>"
 Q
DEL ;     
 ;;A9AUM10
 ;;AUM6111
 ;;AUM61111
 ;;AUM6111A
 ;;AUM6111M

AUM6111
AUM6111 ; IHS/ADC/GTH - STANDARD TABLE UPDATES, 06NOV96 BANYAN ; [ 11/22/96  3:44 PM ]
 ;;96.1;TABLE MAINTENANCE;**11**;OCT 26,1995
 ;
 I '$G(DUZ) W !,"DUZ UNDEFINED OR ZERO.",! Q
 D HOME^%ZIS,DT^DICRW,HELP("INTRO")
 S (DIR(0),DIR("B"))="Y"
 S DIR("A")="Do you want to queue the update to TaskMan"
 S DIR("??")="^D HELP^AUM6111(""Q2"")"
 D ^DIR
 KILL DIR
 I $D(DIRUT) D HELP("Q2") Q
 G START:'Y
QUE ;
 S %DT="AERSX",%DT("A")="Requested Start Time: ",%DT("B")="T@2015",%DT(0)="NOW"
 D ^%DT
 I Y<1 W !,"QUEUE INFORMATION MISSING - NOT QUEUED" D Q2 G AUM6111
 S X=+Y
 D H^%DTC
 S ZTDTH=%H_","_%T
 S ZTRTN="START^AUM6111",ZTIO="",ZTDESC=$P($P($T(+1),";",2)," ",4,99)
 D ^%ZTLOAD,HOME^%ZIS
 I $D(ZTSK) W !!,"QUEUED TO TASK ",ZTSK,!!,"A mail message with the results will be sent to your MailMan 'IN' basket.",!
 E  W !!,*7,"QUEUE UNSUCCESSFUL.  RESTART UTILITY."
 Q
 ;
START ;EP - From Taskman
 ;
 NEW XMSUB,XMDUZ,XMTEXT,XMY
 KILL ^TMP("AUM6111",$J)
 D START^AUM61111
 S XMSUB=$P($P($T(+1),";",2)," ",4,99),XMDUZ=$S($G(DUZ):DUZ,1:.5),XMTEXT="^TMP(""AUM6111"",$J,",XMY(1)="",XMY(DUZ)=""
 D ^XMD
 KILL ^TMP("AUM6111",$J)
 I $D(ZTQUEUED) S ZTREQ="@" Q
 W !!,"The results are in your MailMan 'IN' basket.",!
 I $L($T(DIR^XBDIR)),$$DIR^XBDIR("Y","Want me to delete the routines in this patch","Y") G INTERACT^A9AUM11
 Q
 ;
INTRO ;
 ;;This updates standard tables according to the changes specified in
 ;;the Banyan message time stamped 06Nov96@09:49:18 MST. Please consult
 ;;that message, and the mail message produced by this update.
 ;;
 ;;###
 ;
Q2 ;
 ;;Answer "Y" if you want to queue this standard table update to TaskMan.
 ;;Answer "N" if you want to run this update interactively.
 ;;
 ;;If you run interactively, results will be displayed on your screen,
 ;;as well as in the mail message sent to you and user 1.  If you queue
 ;;to TaskMan, please read the mail message for results of this update.
 ;;###
 ;
HELP(L) ;EP - Display text at label L.
 W !
 F %=1:1 W !?4,$P($T(@L+%),";",3) Q:$P($T(@L+%+1),";",3)="###"
 Q
 ;

AUM61111
AUM61111 ; IHS/ADC/GTH - STANDARD TABLE UPDATES, 06NOV96 BANYAN ; [ 11/26/96  12:54 PM ]
 ;;96.1;TABLE MAINTENANCE;**11**;OCT 26,1995
 ;
 Q
 ;
START ;EP
 ;
 NEW A,C,DIC,DIE,DLAYGO,DR,E,L,M,N,O,P,R,S,T
 ;
 S E(0)="ERROR : ",E(1)="NOT ADDED : "
 D RSLT($J("",15)_$P($T(UPDATE^AUM6111A),";",3))
 D DASH,SUNEW,DASH,LOCNEW,DASH,LOCMOD,DASH,LOCINACT,DASH,COMMNEW,DASH,COMMMOD,DASH,COMMDEL
 ;
 Q
 ;
 ; -----------------------------------------------------
 ;
ADDOK D RSLT($J("",5)_"Added : "_L) Q
ADDFAIL D RSLT($J("",5)_E(0)_"ADD FAILED => "_L) Q
DASH D RSLT(""),RSLT($$REPEAT^XLFSTR("-",$S($G(IOM):IOM-10,1:70))),RSLT("") Q
DIE NEW A,C,E,L,M,N,O,P,R,S,T
 LOCK +(@(DIE_DA_")")):10 E  D RSLT($J("",5)_E(0)_"Entry '"_DIE_DA_"' IS LOCKED.  NOTIFY PROGRAMMER.") S Y=1 Q
 D ^DIE LOCK -(@(DIE_DA_")")) K DA,DIE,DR Q
IEN(X,%,Y) ;
 S Y=$O(@(X_"""C"",%,0)"))
 I 'Y S Y=$T(@%^AUM6111M) I Y NEW Z S Z=E D  S:Y<0 Y="" S E=Z
 . NEW A,C,L,M,N,O,P,R,S,V,%
 . S L=Y
 . I X["AREA" NEW X S E=E_" (Add Area) " D ADDAREA Q
 . I X["SU" NEW X S E=E_" (Add SU) " D ADDSU Q
 . I X["CTY" NEW X S E=E_" (Add County) " D ADDCNTY Q
 .Q
 D:'Y RSLT($J("",5)_E(0)_$P(@(X_"0)"),U)_" DOES NOT EXIST => "_%)
 Q +Y
DIK NEW A,C,E,L,M,N,O,P,R,S,T D ^DIK K DIK Q
FILE NEW A,C,E,L,M,N,O,P,R,S,T K DD,DO S DIC(0)="L" D FILE^DICN K DIC Q
MODOK D RSLT($J("",5)_"Changed : "_L) Q
RSLT(%) S ^(0)=$G(^TMP("AUM6111",$J,0))+1,^(^(0))=% W:'$D(ZTQUEUED) !,% Q
ZEROTH(A,B,C,D,E,F,G,H,I,J,K) ; Return 0th node.  A is file #, rest fields.
 I '$G(A) Q -1
 I '$G(B) Q -1
 F %=67:1:75 Q:'$G(@($C(%)))  S A=+$P(^DD(A,B,0),U,2),B=@($C(%))
 I 'A!('B) Q -1
 I '$D(^DD(A,B,0)) Q -1
 Q U_$P(^DD(A,B,0),U,2)
 ;
 ; -----------------------------------------------------
 ;
ADDAREA ; PROGRAMMER NOTE:  This s/r is required for every patch.
 S L=$P(L,";;",2),A=$P(L,U),N=$P(L,U,2),R=$P(L,U,3),C=$P(L,U,4),L=A_" "_N_" "_R_" "_C
 I $D(^AUTTAREA("B",N)) D RSLT($J("",5)_E(1)_"NAME EXISTS => "_N) Q
 I $D(^AUTTAREA("C",A)) D RSLT($J("",5)_E(1)_"CODE EXISTS => "_A) Q
 S DLAYGO=9999999.21,DIC="^AUTTAREA(",X=N,DIC("DR")=".02///"_A_";.03///"_R_";.04///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DLAYGO
 Q
 ;
 ; -----------------------------------------------------
 ;
ADDCNTY ; PROGRAMMER NOTE:  This s/r is required for every patch.
 S L=$P(L,";;",2),S=$P(L,U),C=$P(L,U,2),N=$P(L,U,3),L=S_" "_C_" "_N
 I $D(^AUTTCTY("C",S_C)) D RSLT($J("",5)_E(1)_"CODE EXISTS => "_S_C) Q
 S P("S")=$$IEN("^DIC(5,",S)
 Q:'P("S")
 S DIC="^AUTTCTY(",X=N,DIC("DR")=".02////"_P("S")_";.03///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
 ; -----------------------------------------------------
 ;
SUNEW ;
 S E="New Service Unit Codes, Section VIII-B"
 D RSLT(E)
 D RSLT($J("",13)_"AA SU NAME")
 D RSLT($J("",13)_"-- -- ----")
 F T=1:1 S L=$T(SUNEW+T^AUM6111A) Q:$P(L,";",3)="END"  D ADDSU
 Q
 ;
ADDSU ; PROGRAMMER NOTE:  This s/r is required for every patch.
 S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),N=$P(L,U,3),L=A_" "_S_" "_N
 I $D(^AUTTSU("C",A_S)) D RSLT($J("",5)_E(1)_"ASU EXISTS => "_A_S) Q
 S P=$$IEN("^AUTTAREA(",A)
 Q:'P
 S DLAYGO=9999999.22,DIC="^AUTTSU(",X=N,DIC("DR")=".02////"_P_";.03///"_S
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DLAYGO
 Q
 ;
 ; -----------------------------------------------------
 ;
LOCNEW ;
 S E="New Location Codes, Section VIII-C"
 D RSLT(E)
 D RSLT($J("",13)_"AA SU FA NAME"_$J("",28)_"PSEUDO")
 D RSLT($J("",13)_"-- -- -- ----"_$J("",28)_"------")
 F T=1:1 S L=$T(LOCNEW+T^AUM6111A) Q:$P(L,";",3)="END"  D ADDLOC
 Q
 ;
ADDLOC ;
 S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3),N=$P(L,U,4),P=$P(L,U,5)
 S L=A_" "_S_" "_F_" "_N_$J("",32-$L(N))_P
 S %=A_S_F,%=$O(^AUTTLOC("C",%,0))
 I % D RSLT($J("",5)_E(1)_"ASUFAC EXISTS => "_A_S_F) D  Q
 . I $P($G(^AUTTLOC(%,0)),U,21) S DIE="^AUTTLOC(",DA=%,DR=".27///@" D DIE D:$D(Y) RSLT($J("",5)_E(0)_"DELETE INACTIVE DATE FAILED => "_L) D:'$D(Y) RSLT($J("",5)_"INACTIVE DATE DELETED => "_L)
 . S %=$O(^AUTTLOC("C",A_S_F,0)),%=$P(^AUTTLOC(%,0),U)
 . I %,$D(^DIC(4,%,0)),N'=$P(^DIC(4,%,0),U) S DIE="^DIC(4,",DA=%,DR=".01///"_N D DIE D:$D(Y) RSLT($J("",5)_E(0)_"EDIT INSTITUTION FAILED => "_L) D:'$D(Y) RSLT($J("",5)_"INSTITUTION NAME UPDATED => "_L)
 . S %=$O(^AUTTLOC("C",A_S_F,0))
 . I P'=$P($G(^AUTTLOC(%,1)),U,2) S DIE="^AUTTLOC(",DA=%,DR=".31///"_P D DIE D:$D(Y) RSLT($J("",5)_E(0)_"EDIT PSEUDO PREFIX FAILED => "_L) D:'$D(Y) RSLT($J("",5)_"PSEUDO PREFIX UPDATED => "_L)
 .Q
 S P("A")=$$IEN("^AUTTAREA(",A)
 Q:'P("A")
 S P("S")=$$IEN("^AUTTSU(",A_S)
 Q:'P("S")
 F DINUM=+$P(^DIC(4,0),U,3):1 Q:'$D(^DIC(4,DINUM))&('$D(^AUTTLOC(DINUM)))  I DINUM>99999 D RSLT($J("",5)_E(0)_"DINUM FOR LOC/INSTITUTION TOO BIG. NOTIFY ISC.") Q
 Q:DINUM>99999
 S DLAYGO=4,DIC="^DIC(4,",X=N
 D FILE
 KILL DINUM,DLAYGO
 I Y<0 D RSLT($J("",5)_E(0)_"^DIC(4 ADD FAILED => "_L) Q
 S DINUM=+Y,DLAYGO=9999999.06,DIC="^AUTTLOC(",X=DINUM,DIC("DR")=".04////"_P("A")_";.05////"_P("S")_";.07///"_F_";.31///"_P
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DINUM,DLAYGO
 Q
 ;
LOCMOD ;
 S E="Location Code Changes, Section VIII-C"
 D RSLT(E)
 D RSLT($J("",15)_"AA SU FA NAME"_$J("",28)_"PSEUDO")
 D RSLT($J("",15)_"-- -- -- ----"_$J("",28)_"------")
 F T=1:2 S L=$T(LOCMOD+T^AUM6111A) Q:$P(L,";",3)="END"  S L("TO")=$T(LOCMOD+T+1^AUM6111A) D
 . S L=$P(L,U,2,99),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3)
 . S P=$O(^AUTTLOC("C",A_S_F,0))
 . S L=$P(L("TO"),U,2,99),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3),N=$P(L,U,4)
 . I 'P S P=$O(^AUTTLOC("C",A_S_F,0)) I 'P S L=";;"_L D ADDLOC Q
 . S L=A_" "_S_" "_F_" "_N_$J("",32-$L(N))_$P(L("TO"),U,6)
 . S P("A")=$$IEN("^AUTTAREA(",A)
 . Q:'P("A")
 . S P("S")=$$IEN("^AUTTSU(",A_S)
 . Q:'P("S")
 . S DIE="^AUTTLOC(",DA=P,DR=".04////"_P("A")_";.05////"_P("S")_";.07///"_F_";.31///"_$P(L("TO"),U,6)
 . D DIE
 . I $D(Y) D RSLT($J("",5)_E(0)_"EDIT LOCATION FAILED => "_L) Q
 . S DIE="^DIC(4,",DA=$P(^AUTTLOC(P,0),U),DR=".01///"_N
 . D DIE
 . I $D(Y) D RSLT($J("",5)_E(0)_"EDIT INSTITUTION FAILED => "_L) Q
 . D MODOK
 .Q
 D DASH,RSLT($$LOCMOD^AUMXPORT("AUM6111A")_" patients marked for export because of the Location Code changes.")
 ;
 Q
 ;
 ; -----------------------------------------------------
 ;
LOCINACT ;
 S E="Inactivated Location Codes, Section VIII-C"
 D RSLT(E)
 D RSLT($J("",20)_"AA SU FA NAME")
 D RSLT($J("",20)_"-- -- -- ----")
 F T=1:1 S L=$T(LOCINACT+T^AUM6111A) Q:$P(L,";",3)="END"  D
 . S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3),N=$P(L,U,4),P=$P(L,U,5)
 . S L=A_" "_S_" "_F_" "_N_" "_P
 . S %=A_S_F,%=$O(^AUTTLOC("C",%,0))
 . I '% D RSLT($J("",5)_"ASUFAC "_A_S_F_" not found (OK).") Q
 . S DIE="^AUTTLOC(",DA=%,DR=".27////"_DT
 . D DIE
 . I $D(Y) D RSLT($J("",5)_E(0)_"EDIT INACTIVE DATE FAILED => "_L) I 1
 . E  D RSLT($J("",5)_"INACTIVATED => "_L)
 .Q
 Q
 ;
 ; -----------------------------------------------------
 ;
COMMNEW ;
 S E="New Community Codes, Section V-C"
 D RSLT(E)
 D RSLT($J("",13)_"ST CT COM NAME"_$J("",28)_"AA SU")
 D RSLT($J("",13)_"-- -- --- ----"_$J("",28)_"-- --")
 F T=1:1 S L=$T(COMMNEW+T^AUM6111A) Q:$P(L,";",3)="END"  D ADDCOMM
 Q
 ;
ADDCOMM ;
 S L=$P(L,";;",2),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3),N=$P(L,U,4),A=$P(L,U,5),V=$P(L,U,6),L=S_" "_O_" "_C_" "_N_$J("",32-$L(N))_A_" "_V
 I $D(^AUTTCOM("C",S_O_C)) D RSLT($J("",5)_E(1)_"STCTYCOM CODE EXISTS => "_S_O_C) Q
 S P("O")=$$IEN^AUM61111("^AUTTCTY(",S_O)
 Q:'P("O")
 S P("A")=$$IEN^AUM61111("^AUTTAREA(",A)
 Q:'P("A")
 S P("V")=$$IEN^AUM61111("^AUTTSU(",A_V)
 Q:'P("V")
 S DLAYGO=9999999.05,DIC="^AUTTCOM(",X=N,DIC("DR")=".02////"_P("O")_";.05////"_P("V")_";.06////"_P("A")_";.07///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DLAYGO
 Q
 ;
 ; -----------------------------------------------------
 ;
COMMMOD ;
 S E="Community Code Changes, Section V-C"
 D RSLT(E)
 D RSLT($J("",15)_"ST CT COM NAME"_$J("",28)_"AA SU")
 D RSLT($J("",15)_"-- -- --- ----"_$J("",28)_"-- --")
 F T=1:2 S L=$T(COMMMOD+T^AUM6111A) Q:$P(L,";",3)="END"  S L("TO")=$T(COMMMOD+T+1^AUM6111A) D
 . S L=$P(L,U,2,99),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3)
 . S P=$O(^AUTTCOM("C",S_O_C,0))
 . S L=$P(L("TO"),U,2,99),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3),N=$P(L,U,4),A=$P(L,U,5),V=$P(L,U,6)
 . I 'P S P=$O(^AUTTCOM("C",S_O_C,0)) I 'P S L=";;"_L D ADDCOMM Q
 . S L=S_" "_O_" "_C_" "_N_$J("",32-$L(N))_A_" "_V
 . S P("O")=$$IEN^AUM61111("^AUTTCTY(",S_O)
 . Q:'P("O")
 . S P("A")=$$IEN^AUM61111("^AUTTAREA(",A)
 . Q:'P("A")
 . S P("V")=$$IEN^AUM61111("^AUTTSU(",A_V)
 . Q:'P("V")
 . S DIE="^AUTTCOM(",DA=P,DR=".01///"_N_";.02////"_P("O")_";.05////"_P("V")_";.06////"_P("A")_";.07///"_C
 . D DIE
 . I $D(Y) D RSLT($J("",5)_E(0)_"CHANGE FAILED => "_L) Q
 . D MODOK
 .Q
 ;
 D DASH,RSLT($$COMMMOD^AUMXPORT("AUM6111A")_" patients marked for export because of the Community Code changes.")
 Q
 ;
 ; -----------------------------------------------------
 ;
COMMDEL ;
 S E="Community Inactivation"
 D RSLT(E)
 D RSLT($J("",15)_"ST CT COM NAME"_$J("",28)_"AA SU")
 D RSLT($J("",15)_"-- -- --- ----"_$J("",28)_"-- --")
 F T=1:1 S L=$T(COMMDEL+T^AUM6111A) Q:$P(L,";",3)="END"  D
 . S L=$P(L,";;",2),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3),N=$P(L,U,4),A=$P(L,U,5),V=$P(L,U,6),L=S_" "_O_" "_C_" "_N_" "_A_" "_V
 . S P=$O(^AUTTCOM("C",S_O_C,0))
 . I 'P D RSLT("COMMUNITY NOT FOUND (That's OK) => "_L) Q
 . S DIE="^AUTTCOM(",DA=P,DR=".14///<INACTIVE>"
 . D DIE
 . I $D(Y) D RSLT(E(0)_" : EDIT FAILED => "_L) Q
 . D RSLT("SHORT NAME Marked '<INACTIVE>' :")
 . D RSLT($J("",15)_S_" "_O_" "_C_" "_N_$J("",32-$L(N))_A_" "_V)
 .Q
 Q
 ;
 ; -----------------------------------------------------
 ;

AUM6111A
AUM6111A ; IHS/ADC/GTH - STANDARD TABLE UPDATES DATA A, 06NOV96 BANYAN ; [ 11/22/96  5:44 PM ]
 ;;96.1;TABLE MAINTENANCE;**11**;OCT 26,1995
 ;
UPDATE ;;IHS STANDARD CODE BOOK MODIFICATIONS - SEPT/OCT 1996^11/5/96
 ;
SUNEW ;;A. NEW SERVICE UNIT CODES (SECTION VIII-B): AREA^S.U.^NAME
 ;;85^87^TUBA CITY
 ;;END
 ;
LOCNEW ;;B. NEW FACILITY CODES (SECTION VIII-C): AREA^S.U.^FAC.^NAME^PSEUDO
 ;;25^25^20^PINE HILL TEEN HLTH CTR^QAZ
 ;;80^87^51^WELLNESS CENTER^NIU
 ;;85^87^52^JUVENILE SERV CENTER^NIV
 ;;END
 ;
LOCMOD ;;C. FACILITY CODE CHANGES (SECTION VIII-C): AREA^S.U.^FAC.^NAME^PSEUDO
 ;;FROM^20^24^10^DULCE HEALTH CENTER^QDB
 ;;  TO^20^28^10^DULCE HEALTH CENTER^QEU
 ;;FROM^60^63^60^ELKO IHS A/C^XSB
 ;;  TO^60^63^60^ELKO IHS AD/AP^XSB
 ;;FROM^60^69^65^FALLON IHS A/C^XSF
 ;;  TO^60^69^65^FALLON IHS AD/AP^XSF
 ;;FROM^65^61^61^PITU TRIBE^XSK
 ;;  TO^65^61^61^PITU TRIBE AD/AP^XSK
 ;;FROM^65^61^62^UTE TRIBE^XSL
 ;;  TO^65^61^62^UTE TRIBE AD/AP^XSL
 ;;FROM^65^62^64^HOPI TRIBE^XSM
 ;;  TO^65^62^64^HOPI TRIBE AD/AP^XSM
 ;;FROM^65^62^65^KAIBAB PAIUTE TRIBE ALC PROG^XSN
 ;;  TO^65^62^65^KAIBAB PAIUTE TRIBE AD/AP^XSN
 ;;FROM^65^63^60^ELKO TRIBE ALC PROG^XSR
 ;;  TO^65^63^60^ELKO TRIBE AD/AP^XSR
 ;;FROM^65^63^61^BATTLE MOUNTAIN TRIBE^XSO
 ;;  TO^65^63^61^BATTLE MOUNTAIN TRIBE AD/AP^XSO
 ;;FROM^65^63^62^DUCK VALLEY TRIBE^XSP
 ;;  TO^65^63^62^DUCK VALLEY TRIBE AD/AP^XSP
 ;;FROM^65^63^63^DUCKWATER TRIBE^XSQ
 ;;  TO^65^63^63^DUCKWATER TRIBE AD/AP^XSQ
 ;;FROM^65^63^64^ELY TRIBE^XSS
 ;;  TO^65^63^64^ELY TRIBE AD/AP^XSS
 ;;FROM^65^63^65^GOSHUTE TRIBE^XST
 ;;  TO^65^63^65^GOSHUTE TRIBE AD/AP^XST
 ;;FROM^65^63^66^TE-MOAK TRIBE^XSU
 ;;  TO^65^63^66^TE-MOAK TRIBE AD/AP^XSU
 ;;FROM^65^64^61^CHEMEHUEVI TRIBE^XSV
 ;;  TO^65^64^61^CHEMEHUEVI TRIBE AD/AP^XSV
 ;;FROM^65^64^62^CRIT TRIBE^XSW
 ;;  TO^65^64^62^CRIT TRIBE AD/AP^XSW
 ;;FROM^65^64^63^FORT MOJAVE TRIBE^XSX
 ;;  TO^65^64^63^FORT MOJAVE TRIBE^XSX
 ;;FROM^65^64^64^HUALAPAI TRIBE^XSY
 ;;  TO^65^64^64^HUALAPAI TRIBE AD/AP^XSY
 ;;FROM^65^66^31^SALT RIVER TRIBE^XTB
 ;;  TO^65^66^31^SALT RIVER TRIBE AD/AP^XTB
 ;;FROM^65^66^63^FORT MCDOWELL TRIBE^XSZ
 ;;  TO^65^66^63^FORT MCDOWELL TRIBE AD/AP^XSZ
 ;;FROM^65^66^84^YAVAPAI APACHE TRIBE^XTF
 ;;  TO^65^66^84^YAVAPAI APACHE TRIBE AD/AP^XTF
 ;;FROM^65^66^87^TOHONO O'ODHAM - SAN LUCY^XTC
 ;;  TO^65^66^87^TOHONO O'ODHAM SAN LUCY AD/AP^XTC
 ;;FROM^65^66^90^TONTO APACHE TRIBE^XTD
 ;;  TO^65^66^90^TONTO APACHE TRIBE AD/AP^XTD
 ;;FROM^65^67^67^GILA CROSSING TRIB ALCOL PRG^XEZ
 ;;  TO^65^67^67^GILA CROSSING TRIBE AD/AP^XEZ
 ;;FROM^65^67^78^GRIC TRIBE^XTZ
 ;;  TO^65^67^78^GRIC TRIBE AD/AP^XTZ
 ;;FROM^65^68^80^SAN CARLOS TRIBE^XTG
 ;;  TO^65^68^80^SAN CARLOS TRIBE AD/AP^XTG
 ;;FROM^65^69^19^RENO/SPARKS^XQC
 ;;  TO^65^69^19^RENO/SPARKS AD/AP^XQC
 ;;FROM^65^69^65^FALLON TRIBE ALC PROG^XTH
 ;;  TO^65^69^65^FALLON TRIBE AD/AP^XTH
 ;;FROM^65^69^66^LAS VEGAS TRIBE ALC PROG^XTI
 ;;  TO^65^69^66^LAS VEGAS TRIBE AD/AP^XTI
 ;;FROM^65^69^67^LOVELOCK TRIBE^XTJ
 ;;  TO^65^69^67^LOVELOCK TRIBE AD/AP^XTJ
 ;;FROM^65^69^68^PYRAMID LAKE TRIBE ALC PROG^XTK
 ;;  TO^65^69^68^PYRAMID LAKE TRIBE AD/AP^XTK
 ;;FROM^65^69^69^WALKER RIVER TRIBE ALC PROG^XTQ
 ;;  TO^65^69^69^WALKER RIVER TRIBE AD/AP^XTQ
 ;;FROM^65^69^70^WASHOE TRIBE ALC PROG^XTR
 ;;  TO^65^69^70^WASHOE TRIBE AD/AP^XTR
 ;;FROM^65^69^71^YERINGTON TRIBE ALC PROG^XTS
 ;;  TO^65^69^71^YERINGTON TRIBE AD/AP^XTS
 ;;FROM^65^69^72^YOMBA TRIBE^XTT
 ;;  TO^65^69^72^YOMBA TRIBE AD/AP^XTT
 ;;FROM^65^71^79^WHITERIVER TRIBAL GUIDANCE CT^XFU
 ;;  TO^65^71^79^WHITERIVER TRIBAL AD/AP^XFU
 ;;FROM^65^72^62^COCOPAH TRIBE^XTM
 ;;  TO^65^72^62^COCOPAH TRIBE AD/AP^XTM
 ;;FROM^65^72^63^QUECHAN TRIBE^XTN
 ;;  TO^65^72^63^QUECHAN TRIBE AD/AP^XTN
 ;;FROM^67^61^63^IAC & RHP URBAN (SALT LAKE)^XTO
 ;;  TO^67^61^63^IAC & RHP URB SALT LAKE AD/AP^XTO
 ;;FROM^67^66^86^INDIAN COMM HEALTH SERV INC^XTY
 ;;  TO^67^66^86^INDIAN COMM HLTH SRV INC AD/AP^XTY
 ;;FROM^69^66^60^INDIAN REHABILITATION, INC.^XTV
 ;;  TO^69^66^60^INDIAN REHAB, INC. - AD/AP^XTV
 ;;END
 ;
LOCINACT ;;D. INACTIVATED FACILITY CODES (SECTION VIII-C): AREA^S.U.^FAC.^NAME
 ;;60^61^60^U & O IHS A/C
 ;;60^72^61^YUMA IHS A/C
 ;;END
 ;
COMMNEW ;;E.  NEW COMMUNITY CODES (SECTION V-C): STATE^CNTY^COMM^NAME^AREA^S.U.
 ;;18^20^500^ELKHART^18^23
 ;;18^50^501^BREMAN^18^23
 ;;18^50^502^CULVER^18^23
 ;;18^50^503^PLYMOUTH^18^23
 ;;18^71^504^GRANGER^18^23
 ;;18^71^505^HOWE^18^23
 ;;18^71^506^MISHAWAKA^18^23
 ;;18^71^507^NORTH LIBERTY^18^23
 ;;18^71^508^NOTRE DAME^18^23
 ;;18^71^509^OSCEOLA^18^23
 ;;18^71^510^SOUTH BEND^18^23
 ;;18^71^511^WALKERTON^18^23
 ;;26^03^401^HOLLAND SOUTH^18^23
 ;;26^03^512^DORR^18^23
 ;;26^03^513^MARTIN^18^23
 ;;26^11^514^BARODA^18^23
 ;;26^11^515^BERRIEN CENTER^18^23
 ;;26^11^516^BERRIEN SPRINGS^18^23
 ;;26^11^517^BRIDGMAN^18^23
 ;;26^11^518^EAU CLAIRE^18^23
 ;;26^11^519^HAGAR SHORES^18^23
 ;;26^11^520^ST. JOSEPH^18^23
 ;;26^11^521^SAWYER^18^23
 ;;26^11^522^STEVENSVILLE^18^23
 ;;26^11^523^THREE OAKS^18^23
 ;;26^14^524^CASSOPOLIS^18^23
 ;;26^14^525^EDWARDSBURG^18^23
 ;;26^14^526^MARCELLUS^18^23
 ;;26^14^527^VANDALIA^18^23
 ;;26^70^528^HOLLAND^11^00
 ;;26^80^529^BANGOR^18^23
 ;;26^80^530^BLOOMINGDALE^18^23
 ;;26^80^531^COVERT^18^23
 ;;26^80^532^DECATUR^18^23
 ;;26^80^533^GOBLES^18^23
 ;;26^80^534^GRAND JUNCTION^18^23
 ;;26^80^535^HARTFORD^18^23
 ;;26^80^536^LAWRENCE^18^23
 ;;26^80^537^PAW PAW^18^23
 ;;26^80^538^SOUTH HAVEN^18^23
 ;;35^21^100^CANJILON^20^28
 ;;35^21^101^CEBOLLA^20^28
 ;;35^21^102^EL VADO LAKE^20^28
 ;;35^21^103^ENSENADA^20^28
 ;;35^21^104^HERON LAKE^20^28
 ;;35^21^105^LA PUENTE^20^28
 ;;35^21^106^LLAVES^20^28
 ;;35^21^107^MONERO^20^28
 ;;35^21^108^EASTERN NAVAJO DAM^20^28
 ;;35^21^109^NUTRIAS^20^28
 ;;35^21^110^RUTHERTON^20^28
 ;;35^21^111^CAPULIN^20^28
 ;;35^21^112^WOODYARD^20^28
 ;;55^16^400^FOXBORO^11^00
 ;;55^16^401^LAKE NEBAGAMON^11^00
 ;;55^16^402^POPLAR^11^00
 ;;55^16^403^SOUTH RANGE^11^00
 ;;END
 ;
COMMMOD ;;F.  COMMUNITY CODE CHANGES (SECTION V-C): STATE^CNTY^COMM^NAME^AREA^S.U.
 ;;FROM^08^04^001^CHROMO^20^26
 ;;  TO^08^04^001^CHROMO^20^28
 ;;FROM^08^04^002^EDITH^20^26
 ;;  TO^08^04^005^EDITH^20^28
 ;;FROM^35^21^002^LOS OJOS^20^24
 ;;  TO^35^21^002^LOS OJOS (PARKVIEW)^20^28
 ;;FROM^35^21^203^BUCKMAN^20^24
 ;;  TO^35^21^203^BUCKMAN^20^28
 ;;FROM^35^21^207^GAVILAN^20^24
 ;;  TO^35^21^207^GAVILAN^20^28
 ;;FROM^35^21^208^DULCE^20^24
 ;;  TO^35^21^208^DULCE^20^28
 ;;FROM^35^21^209^OTERO^20^24
 ;;  TO^35^21^209^OTERO^20^28
 ;;FROM^35^21^210^POUNDS MILL^20^24
 ;;  TO^35^21^210^POUNDS MILL^20^28
 ;;FROM^35^21^211^JICARILLA RES OTHER^20^24
 ;;  TO^35^21^211^JICARILLA RES OTHER^20^28
 ;;FROM^35^21^212^LINDRITH^20^24
 ;;  TO^35^21^212^LINDRITH^20^28
 ;;FROM^35^21^213^LUMBERTON^20^24
 ;;  TO^35^21^213^LUMBERTON^20^28
 ;;FROM^35^21^216^TAPICITOES^20^24
 ;;  TO^35^21^216^TAPICITOES^20^28
 ;;FROM^35^21^552^GALLINA^20^24
 ;;  TO^35^21^552^GALLINA^20^28
 ;;FROM^35^21^700^CHAMA^20^24
 ;;  TO^35^21^700^CHAMA^20^28
 ;;FROM^35^21^702^GOBERNADOR^20^24
 ;;  TO^35^21^702^GOBERNADOR^20^28
 ;;FROM^35^21^703^TIERRA AMARI^20^24
 ;;  TO^35^21^703^TIERRA AMARILLA^20^28
 ;;FROM^35^21^704^BRAZOS^20^24
 ;;  TO^35^21^704^BRAZOS^20^28
 ;;FROM^35^23^276^LA JARA^20^21
 ;;  TO^35^23^276^LA JARA^20^28
 ;;FROM^35^23^575^REGINA^20^21
 ;;  TO^35^23^575^REGINA^20^28
 ;;FROM^41^27^203^DALLES^70^82
 ;;  TO^41^27^203^DALLAS^70^82
 ;;END
 ;
COMMDEL ;;G. INACTIVATED COMMUNITY CODES (SECTION V-C): STATE^CNTY^COMM^NAME^AREA^S.U.
 ;;35^21^701^PARKVIEW^20^24
 ;;END
 ;

AUM6111M
AUM6111M ; IHS/ADC/GTH - BACKGROUND VALUES FOR STANDARD TABLE UPDATES, 06NOV96 BANYAN ; [ 11/22/96  4:40 PM ]
 ;;96.1;TABLE MAINTENANCE;**11**;OCT 26,1995
 ;
AREA ; CODE^NAME^PREFIX/REGION^CAN PREFIX
11 ;;11^BEMIDJI^D^J46
18 ;;18^BEMIDJI NON-IHS^D^J46
20 ;;20^ALBUQUERQUE^Q^J53
25 ;;25^ALBUQUERQUE TRIBE/638^Q^J53
60 ;;60^PHOENIX^X^J40
65 ;;65^PHOENIX TRIBE/638^X^J40
67 ;;67^PHOENIX URBAN^X^J40
69 ;;69^PHOENIX NON-IHS^X^J40
80 ;;80^NAVAJO^N^J54
85 ;;85^NAVAJO TRIBE/638^N^J54
 ;
SU ; AREA^SU^NAME
1100 ;;11^00^NON SERVICE UNIT
1823 ;;18^23^EASTERN MICHIGAN
2021 ;;20^21^ALBUQUERQUE
2024 ;;20^24^SANTA FE
2026 ;;20^26^SOUTHERN COL
2028 ;;20^28^JICARILLA
2525 ;;25^25^ZUNI-RAMAH
6063 ;;60^63^OWYHEE
6069 ;;60^69^SCHURZ
6561 ;;65^61^UINTAH-OURAY
6562 ;;65^62^KEAMS CANYON
6563 ;;65^63^OWYHEE
6564 ;;65^64^COLORADO RIVER
6566 ;;65^66^PHOENIX
6567 ;;65^67^SACATON
6568 ;;65^68^SAN CARLOS
6569 ;;65^69^SCHURZ
6571 ;;65^71^WHITERIVER
6572 ;;65^72^FT. YUMA
6761 ;;67^61^UINTAH-OURAY
6766 ;;67^66^PHOENIX
6966 ;;69^66^PHOENIX
7082 ;;70^82^WESTERN OREGON
8087 ;;80^87^TUBA CITY
 ;
COUNTY ; STATE^COUNTY^NAME
0804 ;;08^04^ARCHULETA
1820 ;;18^20^ELKHART
1850 ;;18^50^MARSHALL
1871 ;;18^71^ST JOSEPH
2603 ;;26^03^ALLEGAN
2611 ;;26^11^BERRIEN
2614 ;;26^14^CASS
2670 ;;26^70^OTTAWA
2680 ;;26^80^VAN BUREN
3521 ;;35^21^RIO ARRIBA
3523 ;;35^23^SANDOVAL
4127 ;;41^27^POLK
5516 ;;55^16^DOUGLAS
 ;