9:38 AM  6-MAR-96
AUM v 96.1, Patch 5, SCB update, 04Mar96 Banyan.  Restore 5 routines and DO ^AUM6105.
A9AUM5
A9AUM5 ; IHS/ADC/GTH - STANDARD TABLE UPDATES, 04MAR96 BANYAN, RPI ; [ 03/06/96  9:37 AM ]
 ;;96.1;TABLE MAINTENANCE;**5**;OCT 26,1995
 ;
 D START^AUM6105
INTERACT ;EP - Delete routines from interactive call.
 Q:'$L($G(^%ZOSF("DEL")))
 NEW AUM,X
 F AUM=1:1 S X=$P($T(DEL+AUM),";",3) Q:X=""  X ^%ZOSF("DEL") I '$D(ZTQUEUED) W !,X," (poof'd)"
 Q
DEL ;     
 ;;A9AUM4
 ;;AUM6105
 ;;AUM61051
 ;;AUM6105A
 ;;AUM6105M

AUM6105
AUM6105 ; IHS/ADC/GTH - STANDARD TABLE UPDATES, 04MAR96 BANYAN ; [ 03/04/96  11:30 AM ]
 ;;96.1;TABLE MAINTENANCE;**5**;OCT 26,1995
 ;
 I '$G(DUZ) W !,"DUZ UNDEFINED OR ZERO.",! Q
 D HOME^%ZIS,DT^DICRW,HELP("INTRO")
 S (DIR(0),DIR("B"))="Y"
 S DIR("A")="Do you want to queue the update to TaskMan"
 S DIR("??")="^D HELP^AUM6105(""Q2"")"
 D ^DIR
 K DIR
 I $D(DIRUT) D HELP("Q2") Q
 G START:'Y
QUE ;
 S %DT="AERSX",%DT("A")="Requested Start Time: ",%DT("B")="T@2015",%DT(0)="NOW"
 D ^%DT
 I Y<1 W !,"QUEUE INFORMATION MISSING - NOT QUEUED" D Q2 G AUM6105
 S X=+Y
 D H^%DTC
 S ZTDTH=%H_","_%T
 S ZTRTN="START^AUM6105",ZTIO="",ZTDESC=$P($P($T(+1),";",2)," ",4,99)
 D ^%ZTLOAD,HOME^%ZIS
 I $D(ZTSK) W !!,"QUEUED TO TASK ",ZTSK,!!,"A mail message with the results will be sent to your MailMan 'IN' basket.",!
 E  W !!,*7,"QUEUE UNSUCCESSFUL.  RESTART UTILITY."
 Q
 ;
START ;EP - From Taskman
 ;
 NEW XMSUB,XMDUZ,XMTEXT,XMY
 K ^TMP("AUM SCB",$J)
 D START^AUM61051
 S XMSUB=$P($P($T(+1),";",2)," ",4,99),XMDUZ=$S($G(DUZ):DUZ,1:.5),XMTEXT="^TMP(""AUM SCB"",$J,",XMY(1)="",XMY(DUZ)=""
 D ^XMD
 K ^TMP("AUM SCB",$J)
 I $D(ZTQUEUED) S ZTREQ="@" Q
 W !!,"The results are in your MailMan 'IN' basket.",!
 I $L($T(DIR^XBDIR)),$$DIR^XBDIR("Y","Want me to delete the routines in this patch","Y") G INTERACT^A9AUM5
 Q
 ;
INTRO ;
 ;;This updates standard tables according to the changes specified in
 ;;the Banyan message time stamped 04Mar96@10:02:50 MST. Please consult
 ;;that message, and the mail message produced by this update.
 ;;
 ;;###
 ;
Q2 ;
 ;;Answer "Y" if you want to queue this standard table update to TaskMan.
 ;;Answer "N" if you want to run this update interactively.
 ;;
 ;;If you run interactively, results will be displayed on your screen,
 ;;as well as in the mail message sent to you and user 1.  If you queue
 ;;to TaskMan, please read the mail message for results of this update.
 ;;###
 ;
HELP(L) ;EP - Display text at label L.
 W !
 F %=1:1 W !?4,$P($T(@L+%),";",3) Q:$P($T(@L+%+1),";",3)="###"
 Q
 ;

AUM61051
AUM61051 ; IHS/ADC/GTH - STANDARD TABLE UPDATES, 04MAR96 BANYAN ; [ 03/04/96  4:02 PM ]
 ;;96.1;TABLE MAINTENANCE;**5**;OCT 26,1995
 ;
 Q
 ;
START ;EP
 ;
 NEW A,C,DIC,DIE,DLAYGO,DR,E,L,N,O,P,R,S,T
 ;
 S E(0)="ERROR : ",E(1)="NOT ADDED : "
 D RSLT($J("",15)_"IHS STANDARD CODE BOOK MODIFICATIONS - JAN 1996")
 D DASH,SUNEW,DASH,SUMOD,DASH,LOCNEW,DASH,LOCMOD,DASH,LOCINACT,DASH,COMMNEW,DASH,COMMMOD,DASH
 ;
 Q
 ;
 ; -----------------------------------------------------
 ;
ADDOK D RSLT($J("",5)_"Added : "_L) Q
ADDFAIL D RSLT($J("",5)_E(0)_"ADD FAILED => "_L) Q
DASH D RSLT(""),RSLT($$REPEAT^XLFSTR("-",$S($G(IOM):IOM-10,1:70))),RSLT("") Q
DIE NEW A,C,E,L,N,O,P,R,S,T
 LOCK +(@(DIE_DA_")")):10 E  D RSLT($J("",5)_E(0)_"Entry '"_DIE_DA_"' IS LOCKED.  NOTIFY PROGRAMMER.") S Y=1 Q
 D ^DIE LOCK -(@(DIE_DA_")")) K DA,DIE,DR Q
IEN(X,%,Y) ;
 S Y=$O(@(X_"""C"",%,0)"))
 I 'Y S Y=$T(@%^AUM6105M) I Y NEW Z S Z=E D  S:Y<0 Y="" S E=Z
 . NEW A,C,L,N,O,P,R,S,V,%
 . S L=Y
 . I X["AREA" NEW X S E=E_" (Add Area) " D ADDAREA Q
 . I X["SU" NEW X S E=E_" (Add SU) " D ADDSU Q
 . I X["CTY" NEW X S E=E_" (Add County) " D ADDCNTY Q
 .Q
 D:'Y RSLT($J("",5)_E(0)_$P(@(X_"0)"),U)_" DOES NOT EXIST => "_%)
 Q +Y
DIK NEW A,C,E,L,N,O,P,R,S,T D ^DIK K DIK Q
FILE NEW A,C,E,L,N,O,P,R,S,T K DD,DO S DIC(0)="L" D FILE^DICN K DIC Q
MODOK D RSLT($J("",5)_"Changed : "_L) Q
RSLT(%) S ^(0)=$G(^TMP("AUM SCB",$J,0))+1,^(^(0))=% W:'$D(ZTQUEUED) !,% Q
ZEROTH(A,B,C,D,E,F,G,H,I,J,K) ; Return 0th node.  A is file #, rest fields.
 I '$G(A) Q -1
 I '$G(B) Q -1
 F %=67:1:75 Q:'$G(@($C(%)))  S A=+$P(^DD(A,B,0),U,2),B=@($C(%))
 I 'A!('B) Q -1
 I '$D(^DD(A,B,0)) Q -1
 Q U_$P(^DD(A,B,0),U,2)
 ;
 ; -----------------------------------------------------
 ;
AREANEW ;
 D RSLT("New Area Codes")
 F T=1:1 S L=$T(AREANEW+T^AUM6105A) Q:$P(L,";",3)="END"  D ADDAREA
 Q
 ;
ADDAREA ; PROGRAMMER NOTE:  This s/r is required for every patch.
 S L=$P(L,";;",2),A=$P(L,U),N=$P(L,U,2),R=$P(L,U,3),C=$P(L,U,4),L=A_" "_N_" "_R_" "_C
 I $D(^AUTTAREA("B",N)) D RSLT($J("",5)_E(1)_"NAME EXISTS => "_N) Q
 I $D(^AUTTAREA("C",A)) D RSLT($J("",5)_E(1)_"CODE EXISTS => "_A) Q
 S DLAYGO=9999999.21,DIC="^AUTTAREA(",X=N,DIC("DR")=".02///"_A_";.03///"_R_";.04///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
 ; -----------------------------------------------------
 ;
ADDCNTY ; PROGRAMMER NOTE:  This s/r is required for every patch.
 S L=$P(L,";;",2),S=$P(L,U),C=$P(L,U,2),N=$P(L,U,3),L=S_" "_C_" "_N
 I $D(^AUTTCTY("C",S_C)) D RSLT($J("",5)_E(1)_"CODE EXISTS => "_S_C) Q
 S P("S")=$$IEN("^DIC(5,",S)
 Q:'P("S")
 S DIC="^AUTTCTY(",X=N,DIC("DR")=".02////"_P("S")_";.03///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
 ; -----------------------------------------------------
 ;
SUNEW ;
 D RSLT("New Service Unit Codes, Section VIII-B")
 D RSLT($J("",13)_"AA SU NAME")
 D RSLT($J("",13)_"-- -- ----")
 F T=1:1 S L=$T(SUNEW+T^AUM6105A) Q:$P(L,";",3)="END"  D ADDSU
 Q
 ;
ADDSU ; PROGRAMMER NOTE:  This s/r is required for every patch.
 S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),N=$P(L,U,3),L=A_" "_S_" "_N
 I $D(^AUTTSU("C",A_S)) D RSLT($J("",5)_E(1)_"ASU EXISTS => "_A_S) Q
 S P=$$IEN("^AUTTAREA(",A)
 Q:'P
 S DLAYGO=9999999.22,DIC="^AUTTSU(",X=N,DIC("DR")=".02////"_P_";.03///"_S
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
SUMOD ;
 D RSLT("Service Unit Code Changes, Section VIII-B")
 D RSLT($J("",15)_"AA SU NAME")
 D RSLT($J("",15)_"-- -- ----")
 F T=1:2 S L=$T(SUMOD+T^AUM6105A) Q:$P(L,";",3)="END"  S L("TO")=$T(SUMOD+T+1^AUM6105A) D
 . S L=$P(L,U,2,99),A=$P(L,U),S=$P(L,U,2),N=$P(L,U,3)
 . S P=$O(^AUTTSU("C",A_S,0))
 . S L=$P(L("TO"),U,2,99),A=$P(L,U),S=$P(L,U,2),N=$P(L,U,3)
 . I 'P S P=$O(^AUTTSU("C",A_S,0)) I 'P S L=";;"_L D ADDSU Q
 . S L=A_" "_S_" "_N
 . S P("A")=$$IEN("^AUTTAREA(",A)
 . Q:'P("A")
 . S DIE="^AUTTSU(",DA=P,DR=".01///"_N_";.02////"_P("A")_";.03///"_S
 . D DIE
 . I $D(Y) D RSLT(E(0)_E_" : EDIT SERVICE UNIT FAILED => "_L) Q
 . D MODOK
 .Q
 ;
 Q
 ;
 ; -----------------------------------------------------
 ;
LOCNEW ;
 D RSLT("New Location Codes, Section VIII-C")
 D RSLT($J("",13)_"AA SU FA NAME"_$J("",28)_"PSEUDO")
 D RSLT($J("",13)_"-- -- -- ----"_$J("",28)_"------")
 F T=1:1 S L=$T(LOCNEW+T^AUM6105A) Q:$P(L,";",3)="END"  D ADDLOC
 Q
 ;
ADDLOC ;
 S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3),N=$P(L,U,4),P=$P(L,U,5)
 S L=A_" "_S_" "_F_" "_N_$J("",32-$L(N))_P
 S %=A_S_F,%=$O(^AUTTLOC("C",%,0))
 I % D RSLT($J("",5)_E(1)_"ASUFAC EXISTS => "_A_S_F) D  Q
 . I $P($G(^AUTTLOC(%,0)),U,21) S DIE="^AUTTLOC(",DA=%,DR=".27///@" D DIE D:$D(Y) RSLT($J("",5)_E(0)_"DELETE INACTIVE DATE FAILED => "_L) D:'$D(Y) RSLT($J("",5)_"INACTIVE DATE DELETED => "_L)
 . S %=$O(^AUTTLOC("C",A_S_F,0)),%=$P(^AUTTLOC(%,0),U)
 . I %,$D(^DIC(4,%,0)),N'=$P(^DIC(4,%,0),U) S DIE="^DIC(4,",DA=%,DR=".01///"_N D DIE D:$D(Y) RSLT($J("",5)_E(0)_"EDIT INSTITUTION FAILED => "_L) D:'$D(Y) RSLT($J("",5)_"INSTITUTION NAME UPDATED => "_L)
 . S %=$O(^AUTTLOC("C",A_S_F,0))
 . I P'=$P($G(^AUTTLOC(%,1)),U,2) S DIE="^AUTTLOC(",DA=%,DR=".31///"_P D DIE D:$D(Y) RSLT($J("",5)_E(0)_"EDIT PSEUDO PREFIX FAILED => "_L) D:'$D(Y) RSLT($J("",5)_"PSEUDO PREFIX UPDATED => "_L)
 .Q
 S P("A")=$$IEN("^AUTTAREA(",A)
 Q:'P("A")
 S P("S")=$$IEN("^AUTTSU(",A_S)
 Q:'P("S")
 F DINUM=+$P(^DIC(4,0),U,3):1 Q:'$D(^DIC(4,DINUM))&('$D(^AUTTLOC(DINUM)))  I DINUM>99999 D RSLT($J("",5)_E(0)_"DINUM FOR LOC/INSTITUTION TOO BIG. NOTIFY ISC.") Q
 Q:DINUM>99999
 S DLAYGO=4,DIC="^DIC(4,",X=N
 D FILE
 I Y<0 D RSLT($J("",5)_E(0)_"^DIC(4 ADD FAILED => "_L) Q
 S DINUM=+Y,DLAYGO=9999999.06,DIC="^AUTTLOC(",X=DINUM,DIC("DR")=".04////"_P("A")_";.05////"_P("S")_";.07///"_F_";.31///"_P
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
LOCMOD ;
 D RSLT("Location Code Changes, Section VIII-C")
 D RSLT($J("",15)_"AA SU FA NAME"_$J("",28)_"PSEUDO")
 D RSLT($J("",15)_"-- -- -- ----"_$J("",28)_"------")
 F T=1:2 S L=$T(LOCMOD+T^AUM6105A) Q:$P(L,";",3)="END"  S L("TO")=$T(LOCMOD+T+1^AUM6105A) D
 . S L=$P(L,U,2,99),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3)
 . S P=$O(^AUTTLOC("C",A_S_F,0))
 . S L=$P(L("TO"),U,2,99),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3),N=$P(L,U,4)
 . I 'P S P=$O(^AUTTLOC("C",A_S_F,0)) I 'P S L=";;"_L D ADDLOC Q
 . S L=A_" "_S_" "_F_" "_N_$J("",32-$L(N))_$P(L("TO"),U,6)
 . S P("A")=$$IEN("^AUTTAREA(",A)
 . Q:'P("A")
 . S P("S")=$$IEN("^AUTTSU(",A_S)
 . Q:'P("S")
 . S DIE="^AUTTLOC(",DA=P,DR=".04////"_P("A")_";.05////"_P("S")_";.07///"_F_";.31///"_$P(L("TO"),U,6)
 . D DIE
 . I $D(Y) D RSLT($J("",5)_E(0)_"EDIT LOCATION FAILED => "_L) Q
 . S DIE="^DIC(4,",DA=$P(^AUTTLOC(P,0),U),DR=".01///"_N
 . D DIE
 . I $D(Y) D RSLT($J("",5)_E(0)_"EDIT INSTITUTION FAILED => "_L) Q
 . D MODOK
 .Q
 D DASH,RSLT($$LOCMOD^AUMXPORT("AUM6105A")_" patients marked for export because of the Location Code changes.")
 ;
 Q
 ;
 ; -----------------------------------------------------
 ;
LOCINACT ;
 D RSLT("Inactivated Location Codes, Section VIII-C")
 D RSLT($J("",20)_"AA SU FA NAME")
 D RSLT($J("",20)_"-- -- -- ----")
 F T=1:1 S L=$T(LOCINACT+T^AUM6105A) Q:$P(L,";",3)="END"  D
 . S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3),N=$P(L,U,4),P=$P(L,U,5)
 . S L=A_" "_S_" "_F_" "_N_" "_P
 . S %=A_S_F,%=$O(^AUTTLOC("C",%,0))
 . I '% D RSLT($J("",5)_"ASUFAC "_A_S_F_" not found (OK).") Q
 . S DIE="^AUTTLOC(",DA=%,DR=".27////"_DT
 . D DIE
 . I $D(Y) D RSLT($J("",5)_E(0)_"EDIT INACTIVE DATE FAILED => "_L) I 1
 . E  D RSLT($J("",5)_"INACTIVATED => "_L)
 .Q
 Q
 ;
 ; -----------------------------------------------------
 ;
COMMNEW ;
 D RSLT("New Community Codes, Section V-C")
 D RSLT($J("",13)_"ST CT COM NAME"_$J("",28)_"AA SU")
 D RSLT($J("",13)_"-- -- --- ----"_$J("",28)_"-- --")
 F T=1:1 S L=$T(COMMNEW+T^AUM6105A) Q:$P(L,";",3)="END"  D ADDCOMM
 Q
 ;
ADDCOMM ;
 S L=$P(L,";;",2),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3),N=$P(L,U,4),A=$P(L,U,5),V=$P(L,U,6),L=S_" "_O_" "_C_" "_N_$J("",32-$L(N))_A_" "_V
 I $D(^AUTTCOM("C",S_O_C)) D RSLT($J("",5)_E(1)_"STCTYCOM CODE EXISTS => "_S_O_C) Q
 S P("O")=$$IEN^AUM61051("^AUTTCTY(",S_O)
 Q:'P("O")
 S P("A")=$$IEN^AUM61051("^AUTTAREA(",A)
 Q:'P("A")
 S P("V")=$$IEN^AUM61051("^AUTTSU(",A_V)
 Q:'P("V")
 S DLAYGO=9999999.05,DIC="^AUTTCOM(",X=N,DIC("DR")=".02////"_P("O")_";.05////"_P("V")_";.06////"_P("A")_";.07///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
COMMMOD ;
 D RSLT("Community Code Changes, Section V-C")
 D RSLT($J("",15)_"ST CT COM NAME"_$J("",28)_"AA SU")
 D RSLT($J("",15)_"-- -- --- ----"_$J("",28)_"-- --")
 F T=1:2 S L=$T(COMMMOD+T^AUM6105A) Q:$P(L,";",3)="END"  S L("TO")=$T(COMMMOD+T+1^AUM6105A) D
 . S L=$P(L,U,2,99),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3)
 . S P=$O(^AUTTCOM("C",S_O_C,0))
 . S L=$P(L("TO"),U,2,99),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3),N=$P(L,U,4),A=$P(L,U,5),V=$P(L,U,6)
 . I 'P S P=$O(^AUTTCOM("C",S_O_C,0)) I 'P S L=";;"_L D ADDCOMM Q
 . S L=S_" "_O_" "_C_" "_N_$J("",32-$L(N))_A_" "_V
 . S P("O")=$$IEN^AUM61051("^AUTTCTY(",S_O)
 . Q:'P("O")
 . S P("A")=$$IEN^AUM61051("^AUTTAREA(",A)
 . Q:'P("A")
 . S P("V")=$$IEN^AUM61051("^AUTTSU(",A_V)
 . Q:'P("V")
 . S DIE="^AUTTCOM(",DA=P,DR=".01///"_N_";.02////"_P("O")_";.05////"_P("V")_";.06////"_P("A")_";.07///"_C
 . D DIE
 . I $D(Y) D RSLT($J("",5)_E(0)_"CHANGE FAILED => "_L) Q
 . D MODOK
 .Q
 ;
 D DASH,RSLT($$COMMMOD^AUMXPORT("AUM6105A")_" patients marked for export because of the Community Code changes.")
 Q
 ;
 ; -----------------------------------------------------
 ;

AUM6105A
AUM6105A ; IHS/ADC/GTH - STANDARD TABLE UPDATES DATA A, 04MAR96 BANYAN ; [ 03/04/96  12:12 PM ]
 ;;96.1;TABLE MAINTENANCE;**5**;OCT 26,1995
 ;
 ;IHS STANDARD CODE BOOK MODIFICATIONS - FEB 1996  3/4/96
 ;
SUNEW ;;A.  NEW SERVICE UNIT CODE (SECTION VIII-B): AREA^S.U.^NAME
 ;;15^38^OMAHA
 ;;66^35^GREENVILLE
 ;;66^36^BERRY CREEK/MOORETOWN
 ;;END
 ;
SUMOD ;;B.  SERVICE UNIT CODE CHANGES (SECTION VIII-B): AREA^S.U.^NAME
 ;;FROM^10^20^OMAHA-WINNEBAGO
 ;;  TO^10^20^WINNEBAGO
 ;;FROM^15^20^OMAHA-WINNEBAGO
 ;;  TO^15^20^WINNEBAGO
 ;;END
 ;
LOCNEW ;;C.  NEW LOCATION CODES (SECTION VIII-C): AREA^S.U.^FAC.^NAME^PSEUDO
 ;;18^23^38^LITTLE TRAVERSE ODAWA^DYA
 ;;18^23^39^LITTLE RIVER OTTAWA^DYB
 ;;18^23^56^POKAGON POTAWATOMI^DYC
 ;;END
 ;
LOCMOD ;;D.  LOCATION CODE CHANGES (SECTION VIII-C): AREA^S.U.^FAC.^NAME^PSEUDO
 ;;FROM^15^20^10^CARL CURTIS^CLC
 ;;  TO^15^38^10^CARL CURTIS^CCB
 ;;FROM^60^67^01^HU-HU-KAM MEMORIAL HOSP^XBA
 ;;  TO^65^67^01^HU-HU-KAM MEMORIAL HOSP^XYG
 ;;FROM^60^67^30^AK CHIN^XBB
 ;;  TO^65^67^30^AK CHIN^XYA
 ;;FROM^60^67^53^BLACKWATER^XBF
 ;;  TO^65^67^53^BLACKWATER^XYB
 ;;FROM^60^67^55^CASA BLANCA^XBH
 ;;  TO^65^67^55^CASA BLANCA^XYC
 ;;FROM^60^67^57^SAN TAN^XBJ
 ;;  TO^65^67^57^SAN TAN^XYD
 ;;FROM^60^67^60^ELOY^XBM
 ;;  TO^65^67^60^ELOY^XYE
 ;;FROM^60^67^61^STOTONIC^XBN
 ;;  TO^65^67^61^STOTONIC^XYF
 ;;END
 ;
LOCINACT ;;E.  INACTIVATED LOCATION CODES (SECTION VIII-C): AREA^S.U.^FAC.^NAME
 ;;65^67^59^AK CHIN
 ;;65^67^60^BLACKWATER
 ;;65^67^61^CASA BLANCA
 ;;65^67^63^MARICOPA COLONY
 ;;65^67^64^SACATON
 ;;65^67^65^SAN TAN
 ;;65^67^66^STOTONIC
 ;;END
 ;
COMMNEW ;;F.  NEW COMMUNITY CODES (SECTION V-C): STATE^CNTY^COMM^NAME^AREA^S.U.
 ;;06^19^136^BELLFLOWER^64^80
 ;;19^67^355^ONAWA^15^38
 ;;19^67^356^BLENCOE^15^38
 ;;19^67^357^WHITING^15^38
 ;;31^90^352^WAYNE^10^20
 ;;31^90^353^WINSIDE^15^38
 ;;31^90^354^HOSKIN^15^38
 ;;END
 ;
COMMMOD ;;G.  COMMUNITY CODE CHANGES (SECTION V-C): STATE^CNTY^COMM^NAME^AREA^S.U.
 ;;FROM^31^11^286^DECATUR^10^20
 ;;  TO^31^11^286^DECATUR^15^38
 ;;FROM^31^11^287^OAKLAND^10^20
 ;;  TO^31^11^287^OAKLAND^15^38
 ;;FROM^31^11^288^TEKAMAH^10^20
 ;;  TO^31^11^288^TEKAMAH^15^38
 ;;FROM^31^20^296^BANCROFT^10^20
 ;;  TO^31^20^296^BANCROFT^15^38
 ;;FROM^31^87^346^MACY^10^20
 ;;  TO^31^87^346^MACY^15^38
 ;;FROM^31^87^347^PENDER^10^20
 ;;  TO^31^87^347^PENDER^15^38
 ;;FROM^31^87^348^ROSALIE^10^20
 ;;  TO^31^87^348^ROSALIE^15^38
 ;;FROM^31^87^350^WALTHILL^10^20
 ;;  TO^31^87^350^WALTHILL^15^38
 ;;FROM^35^16^865^DEMING^20^00
 ;;  TO^35^16^878^DEMING^20^00
 ;;FROM^41^08^043^CAPE SEBASTAIN^70^86
 ;;  TO^41^08^043^CAPE SEBASTIAN^70^86
 ;;END
 ;

AUM6105M
AUM6105M ; IHS/ADC/GTH - BACKGROUND VALUES FOR STANDARD TABLE UPDATES, 04MAR96 BANYAN ; [ 03/04/96  2:29 PM ]
 ;;96.1;TABLE MAINTENANCE;**5**;OCT 26,1995
 ;
AREA ; CODE^NAME^PREFIX/REGION^CAN PREFIX
10 ;;10^ABERDEEN^C^J45
15 ;;15^ABERDEEN TRIBE/638^C^J45
18 ;;18^BEMIDJI NON-IHS^D^J46
20 ;;20^ALBUQUERQUE^Q^J53
60 ;;60^PHOENIX^X^J40
64 ;;64^CALIFORNIA URBAN^L^J41
65 ;;65^PHOENIX TRIBE/638^X^J40
66 ;;66^CALIFORNIA TRIBE/638^L^J41
70 ;;70^PORTLAND^P^J64
 ;
SU ; AREA^SU^NAME
1020 ;;10^20^OMAHA-WINNEB
1520 ;;15^20^OMAHA-WINNEB
1823 ;;18^23^EASTERN MICHIGAN
2000 ;;20^00^NON SERVICE UNIT
6067 ;;60^67^SACATON
6480 ;;64^80^AMERICAN IND FREE CLINIC
6567 ;;65^67^SACATON
7086 ;;70^86^SOUTHERN OREGON
 ;
COUNTY ; STATE^COUNTY^NAME
0619 ;;06^19^LOS ANGELES
1967 ;;19^67^MONONA
3111 ;;31^11^BURT
3120 ;;31^20^CUMING
3187 ;;31^87^THURSTON
3190 ;;31^90^WAYNE
3516 ;;35^16^LUNA
4108 ;;41^08^CURRY
 ;