5:52 PM  17-SEP-97
AUM v 97.1 Patch 9.  SCB Updates from 02Sep97 Banyan.  Restore 5 routines and DO ^AUM7109.
A9AUM9
A9AUM9 ; IHS/ADC/GTH - STANDARD TABLE UPDATES, 02SEP97 BANYAN, RPI ; [ 09/17/97   5:50 PM ]
 ;;97.1;TABLE MAINTENANCE;**9**;DEC 10,1996
 ;
 D START^AUM7109
INTERACT ;EP - Delete routines from interactive call.
 Q:'$L($G(^%ZOSF("DEL")))
 NEW AUM,X
 F AUM=1:1 S X=$P($T(DEL+AUM),";",3) Q:X=""  X ^%ZOSF("DEL") I '$D(ZTQUEUED) W !,X,$E("...........",1,11-$L(X)),"<poof'd>"
 Q
 ;
DEL ;     
 ;;A9AUM8
 ;;AUM7109
 ;;AUM71091
 ;;AUM7109A
 ;;AUM7109M

AUM7109
AUM7109 ; IHS/ADC/GTH - STANDARD TABLE UPDATES, 02SEP97 BANYAN ; [ 09/17/97   5:50 PM ]
 ;;97.1;TABLE MAINTENANCE;**9**;DEC 10,1996
 ;
 I '$G(DUZ) W !,"DUZ UNDEFINED OR ZERO.",! Q
 D HOME^%ZIS,DT^DICRW,HELP("INTRO")
 S (DIR(0),DIR("B"))="Y"
 S DIR("A")="Do you want to queue the update to TaskMan"
 S DIR("??")="^D HELP^AUM7109(""Q2"")"
 D ^DIR
 KILL DIR
 I $D(DIRUT) D HELP("Q2") Q
 G START:'Y
QUE ;
 S %DT="AERSX",%DT("A")="Requested Start Time: ",%DT("B")="T@2015",%DT(0)="NOW"
 D ^%DT
 I Y<1 W !,"QUEUE INFORMATION MISSING - NOT QUEUED" D HELP("Q2") G AUM7109
 S X=+Y
 D H^%DTC
 S ZTDTH=%H_","_%T
 S ZTRTN="START^AUM7109",ZTIO="",ZTDESC=$P($P($T(+1),";",2)," ",4,99)
 D ^%ZTLOAD,HOME^%ZIS
 I $D(ZTSK) W !!,"QUEUED TO TASK ",ZTSK,!!,"A mail message with the results will be sent to your MailMan 'IN' basket.",!
 E  W !!,*7,"QUEUE UNSUCCESSFUL.  RESTART UTILITY."
 Q
 ;
START ;EP - From Taskman
 ;
 NEW XMSUB,XMDUZ,XMTEXT,XMY
 KILL ^TMP("AUM7109",$J)
 D START^AUM71091
 S XMSUB=$P($P($T(+1),";",2)," ",4,99),XMDUZ=$S($G(DUZ):DUZ,1:.5),XMTEXT="^TMP(""AUM7109"",$J,",XMY(1)="",XMY(DUZ)=""
 D ^XMD
 KILL ^TMP("AUM7109",$J)
 I $D(ZTQUEUED) S ZTREQ="@" Q
 W !!,"The results are in your MailMan 'IN' basket.",!
 I $L($T(DIR^XBDIR)),$$DIR^XBDIR("Y","Want me to delete the routines in this patch","Y") G INTERACT^A9AUM9
 Q
 ;
INTRO ;
 ;;This updates standard tables according to the changes specified in
 ;;the Banyan message time stamped 02Sep97@11:53:49 MDT. Please consult
 ;;that message, and the mail message produced by this update.
 ;;
 ;;###
 ;
Q2 ;
 ;;Answer "Y" if you want to queue this standard table update to TaskMan.
 ;;Answer "N" if you want to run this update interactively.
 ;;
 ;;If you run interactively, results will be displayed on your screen,
 ;;as well as in the mail message sent to you and user 1.  If you queue
 ;;to TaskMan, please read the mail message for results of this update.
 ;;###
 ;
HELP(L) ;EP - Display text at label L.
 W !
 F %=1:1 W !?4,$P($T(@L+%),";",3) Q:$P($T(@L+%+1),";",3)="###"
 Q
 ;

AUM71091
AUM71091 ; IHS/ADC/GTH - STANDARD TABLE UPDATES, 02SEP97 BANYAN ; [ 09/17/97   5:50 PM ]
 ;;97.1;TABLE MAINTENANCE;**9**;DEC 10,1996
 ;
 Q
 ;
START ;EP
 ;
 NEW A,C,DIC,DIE,DLAYGO,DR,E,L,M,N,O,P,R,S,T
 ;
 S E(0)="ERROR : ",E(1)="NOT ADDED : "
 D RSLT($J("",5)_$P($T(UPDATE^AUM7109A),";",3))
 D DASH,LOCNEW,DASH,COMMNEW,DASH,COMMMOD,DASH,COMMDEL,DASH,CSCNEW,DASH
 Q
 ;
 ; -----------------------------------------------------
 ;
ADDOK D RSLT($J("",5)_"Added : "_L) Q
ADDFAIL D RSLT($J("",5)_E(0)_"ADD FAILED => "_L) Q
DASH D RSLT(""),RSLT($$REPEAT^XLFSTR("-",$S($G(IOM):IOM-10,1:70))),RSLT("") Q
DIE NEW A,C,E,L,M,N,O,P,R,S,T
 LOCK +(@(DIE_DA_")")):10 E  D RSLT($J("",5)_E(0)_"Entry '"_DIE_DA_"' IS LOCKED.  NOTIFY PROGRAMMER.") S Y=1 Q
 D ^DIE LOCK -(@(DIE_DA_")")) KILL DA,DIE,DR Q
E(L) Q $P($P($T(@L^AUM7109A),";",3),":",1)
IEN(X,%,Y) ;
 S Y=$O(@(X_"""C"",%,0)"))
 I 'Y S Y=$$VAL^AUM7109M(X,%) I Y NEW Z S Z=E D  S:Y<0 Y="" S E=Z
 . NEW A,C,L,M,N,O,P,R,S,V,%
 . S L=Y
 . I X["AREA" NEW X D RSLT("(Add Missing Area)") D ADDAREA D RSLT("(END Add Missing Area)") Q
 . I X["SU" NEW X D RSLT("(Add Missing SU)") D ADDSU D RSLT("(END Add Missing SU)") Q
 . I X["CTY" NEW X D RSLT("(Add Missing County)") D ADDCNTY D RSLT("(END Add Missing County)") Q
 .Q
 D:'Y RSLT($J("",5)_E(0)_$P(@(X_"0)"),U)_" DOES NOT EXIST => "_%)
 Q +Y
DIK NEW A,C,E,L,M,N,O,P,R,S,T D ^DIK KILL DIK Q
FILE NEW A,C,E,L,M,N,O,P,R,S,T K DD,DO S DIC(0)="L" D FILE^DICN KILL DIC Q
MODOK D RSLT($J("",5)_"Changed : "_L) Q
RSLT(%) S ^(0)=$G(^TMP("AUM7109",$J,0))+1,^(^(0))=% W:'$D(ZTQUEUED) !,% Q
ZEROTH(A,B,C,D,E,F,G,H,I,J,K) ; Return 0th node.  A is file #, rest fields.
 I '$G(A) Q -1
 I '$G(B) Q -1
 F %=67:1:75 Q:'$G(@($C(%)))  S A=+$P(^DD(A,B,0),U,2),B=@($C(%))
 I 'A!('B) Q -1
 I '$D(^DD(A,B,0)) Q -1
 Q U_$P(^DD(A,B,0),U,2)
 ;
 ; -----------------------------------------------------
 ;
ADDAREA ; PROGRAMMER NOTE:  This s/r is required for every patch.
 S L=$P(L,";;",2),A=$P(L,U),N=$P(L,U,2),R=$P(L,U,3),C=$P(L,U,4),L=A_" "_N_" "_R_" "_C
 I $D(^AUTTAREA("B",N)) D RSLT($J("",5)_E(1)_"NAME EXISTS => "_N) Q
 I $D(^AUTTAREA("C",A)) D RSLT($J("",5)_E(1)_"CODE EXISTS => "_A) Q
 S DLAYGO=9999999.21,DIC="^AUTTAREA(",X=N,DIC("DR")=".02///"_A_";.03///"_R_";.04///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DLAYGO
 Q
 ;
 ; -----------------------------------------------------
 ;
ADDCNTY ; PROGRAMMER NOTE:  This s/r is required for every patch.
 S L=$P(L,";;",2),S=$P(L,U),C=$P(L,U,2),N=$P(L,U,3),L=S_" "_C_" "_N
 I $D(^AUTTCTY("C",S_C)) D RSLT($J("",5)_E(1)_"CODE EXISTS => "_S_C) Q
 S P("S")=$$IEN("^DIC(5,",S)
 Q:'P("S")
 S DIC="^AUTTCTY(",X=N,DIC("DR")=".02////"_P("S")_";.03///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
 ; -----------------------------------------------------
 ;
ADDSU ; PROGRAMMER NOTE:  This s/r is required for every patch.
 S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),N=$P(L,U,3),L=A_" "_S_" "_N
 I $D(^AUTTSU("C",A_S)) D RSLT($J("",5)_E(1)_"ASU EXISTS => "_A_S) Q
 S P=$$IEN("^AUTTAREA(",A)
 Q:'P
 S DLAYGO=9999999.22,DIC="^AUTTSU(",X=N,DIC("DR")=".02////"_P_";.03///"_S
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DLAYGO
 Q
 ;
 ; -----------------------------------------------------
 ;
LOCNEW ;
 S E=$$E("LOCNEW")
 D RSLT(E)
 D RSLT($J("",13)_"AA SU FA NAME"_$J("",28)_"PSEUDO")
 D RSLT($J("",13)_"-- -- -- ----"_$J("",28)_"------")
 F T=1:1 S L=$T(LOCNEW+T^AUM7109A) Q:$P(L,";",3)="END"  D ADDLOC
 Q
 ;
ADDLOC ;
 S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3),N=$P(L,U,4),P=$P(L,U,5)
 S L=A_" "_S_" "_F_" "_N_$J("",32-$L(N))_P
 S %=A_S_F,%=$O(^AUTTLOC("C",%,0))
 I % D RSLT($J("",5)_E(1)_"ASUFAC EXISTS => "_A_S_F) D  Q
 . I $P($G(^AUTTLOC(%,0)),U,21) S DIE="^AUTTLOC(",DA=%,DR=".27///@" D DIE D:$D(Y) RSLT($J("",5)_E(0)_"DELETE INACTIVE DATE FAILED => "_L) D:'$D(Y) RSLT($J("",5)_"INACTIVE DATE DELETED => "_L)
 . S %=$O(^AUTTLOC("C",A_S_F,0)),%=$P(^AUTTLOC(%,0),U)
 . I %,$D(^DIC(4,%,0)),N'=$P(^DIC(4,%,0),U) S DIE="^DIC(4,",DA=%,DR=".01///"_N D DIE D:$D(Y) RSLT($J("",5)_E(0)_"EDIT INSTITUTION FAILED => "_L) D:'$D(Y) RSLT($J("",5)_"INSTITUTION NAME UPDATED => "_L)
 . S %=$O(^AUTTLOC("C",A_S_F,0))
 . I P'=$P($G(^AUTTLOC(%,1)),U,2) S DIE="^AUTTLOC(",DA=%,DR=".31///"_P D DIE D:$D(Y) RSLT($J("",5)_E(0)_"EDIT PSEUDO PREFIX FAILED => "_L) D:'$D(Y) RSLT($J("",5)_"PSEUDO PREFIX UPDATED => "_L)
 .Q
 S P("A")=$$IEN("^AUTTAREA(",A)
 Q:'P("A")
 S P("S")=$$IEN("^AUTTSU(",A_S)
 Q:'P("S")
 F DINUM=+$P(^DIC(4,0),U,3):1 Q:'$D(^DIC(4,DINUM))&('$D(^AUTTLOC(DINUM)))  I DINUM>99999 D RSLT($J("",5)_E(0)_"DINUM FOR LOC/INSTITUTION TOO BIG. NOTIFY ISC.") Q
 Q:DINUM>99999
 S DLAYGO=4,DIC="^DIC(4,",X=N
 D FILE
 KILL DINUM,DLAYGO
 I Y<0 D RSLT($J("",5)_E(0)_"^DIC(4 ADD FAILED => "_L) Q
 S DINUM=+Y,DLAYGO=9999999.06,DIC="^AUTTLOC(",X=DINUM,DIC("DR")=".04////"_P("A")_";.05////"_P("S")_";.07///"_F_";.31///"_P
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DINUM,DLAYGO
 Q
 ;
LOCMOD ;
 S E=$$E("LOCMOD")
 D RSLT(E)
 D RSLT($J("",15)_"AA SU FA NAME"_$J("",28)_"PSEUDO")
 D RSLT($J("",15)_"-- -- -- ----"_$J("",28)_"------")
 F T=1:2 S L=$T(LOCMOD+T^AUM7109A) Q:$P(L,";",3)="END"  S L("TO")=$T(LOCMOD+T+1^AUM7109A) D
 . S L=$P(L,U,2,99),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3)
 . S P=$O(^AUTTLOC("C",A_S_F,0))
 . S L=$P(L("TO"),U,2,99),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3),N=$P(L,U,4)
 . I 'P S P=$O(^AUTTLOC("C",A_S_F,0)) I 'P S L=";;"_L D ADDLOC Q
 . S L=A_" "_S_" "_F_" "_N_$J("",32-$L(N))_$P(L("TO"),U,6)
 . S P("A")=$$IEN("^AUTTAREA(",A)
 . Q:'P("A")
 . S P("S")=$$IEN("^AUTTSU(",A_S)
 . Q:'P("S")
 . S DIE="^AUTTLOC(",DA=P,DR=".04////"_P("A")_";.05////"_P("S")_";.07///"_F_";.31///"_$P(L("TO"),U,6)
 . D DIE
 . I $D(Y) D RSLT($J("",5)_E(0)_"EDIT LOCATION FAILED => "_L) Q
 . S DIE="^DIC(4,",DA=$P(^AUTTLOC(P,0),U),DR=".01///"_N
 . D DIE
 . I $D(Y) D RSLT($J("",5)_E(0)_"EDIT INSTITUTION FAILED => "_L) Q
 . D MODOK
 .Q
 ; Locations were name changes, only.  Following line commented.
 ; D DASH,RSLT($$LOCMOD^AUMXPORT("AUM7109A")_" patients marked for export because of the Location Code changes.")
 ;
 Q
 ;
 ; -----------------------------------------------------
 ;
COMMNEW ;
 S E=$$E("COMMNEW")
 D RSLT(E)
 D RSLT($J("",13)_"ST CT COM NAME"_$J("",28)_"AA SU")
 D RSLT($J("",13)_"-- -- --- ----"_$J("",28)_"-- --")
 F T=1:1 S L=$T(COMMNEW+T^AUM7109A) Q:$P(L,";",3)="END"  D ADDCOMM
 Q
 ;
ADDCOMM ;
 S L=$P(L,";;",2),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3),N=$P(L,U,4),A=$P(L,U,5),V=$P(L,U,6),L=S_" "_O_" "_C_" "_N_$J("",32-$L(N))_A_" "_V
 I $D(^AUTTCOM("C",S_O_C)) D RSLT($J("",5)_E(1)_"STCTYCOM CODE EXISTS => "_S_O_C) Q
 S P("O")=$$IEN^AUM71091("^AUTTCTY(",S_O)
 Q:'P("O")
 S P("A")=$$IEN^AUM71091("^AUTTAREA(",A)
 Q:'P("A")
 S P("V")=$$IEN^AUM71091("^AUTTSU(",A_V)
 Q:'P("V")
 S DLAYGO=9999999.05,DIC="^AUTTCOM(",X=N,DIC("DR")=".02////"_P("O")_";.05////"_P("V")_";.06////"_P("A")_";.07///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DLAYGO
 Q
 ;
 ; -----------------------------------------------------
 ;
COMMMOD ;
 S E=$$E("COMMMOD")
 D RSLT(E)
 D RSLT($J("",15)_"ST CT COM NAME"_$J("",28)_"AA SU")
 D RSLT($J("",15)_"-- -- --- ----"_$J("",28)_"-- --")
 F T=1:2 S L=$T(COMMMOD+T^AUM7109A) Q:$P(L,";",3)="END"  S L("TO")=$T(COMMMOD+T+1^AUM7109A) D
 . S L=$P(L,U,2,99),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3)
 . S P=$O(^AUTTCOM("C",S_O_C,0))
 . S L=$P(L("TO"),U,2,99),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3),N=$P(L,U,4),A=$P(L,U,5),V=$P(L,U,6)
 . I 'P S P=$O(^AUTTCOM("C",S_O_C,0)) I 'P S L=";;"_L D ADDCOMM Q
 . S L=S_" "_O_" "_C_" "_N_$J("",32-$L(N))_A_" "_V
 . S P("O")=$$IEN^AUM71091("^AUTTCTY(",S_O)
 . Q:'P("O")
 . S P("A")=$$IEN^AUM71091("^AUTTAREA(",A)
 . Q:'P("A")
 . S P("V")=$$IEN^AUM71091("^AUTTSU(",A_V)
 . Q:'P("V")
 . S DIE="^AUTTCOM(",DA=P,DR=".01///"_N_";.02////"_P("O")_";.05////"_P("V")_";.06////"_P("A")_";.07///"_C
 . D DIE
 . I $D(Y) D RSLT($J("",5)_E(0)_"CHANGE FAILED => "_L) Q
 . D MODOK
 .Q
 ;
 ; Line below comment'd because the only change is to the name of the community.
 ; D DASH,RSLT($$COMMMOD^AUMXPORT("AUM7109A")_" patients marked for export because of the Community Code changes.")
 Q
 ;
 ; -----------------------------------------------------
 ;
COMMDEL ;
 S E=$$E("COMMDEL")
 D RSLT(E)
 D RSLT($J("",15)_"ST CT COM NAME"_$J("",28)_"AA SU")
 D RSLT($J("",15)_"-- -- --- ----"_$J("",28)_"-- --")
 F T=1:1 S L=$T(COMMDEL+T^AUM7109A) Q:$P(L,";",3)="END"  D
 . S L=$P(L,";;",2),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3),N=$P(L,U,4),A=$P(L,U,5),V=$P(L,U,6),L=S_" "_O_" "_C_" "_N_" "_A_" "_V
 . S P=$O(^AUTTCOM("C",S_O_C,0))
 . I 'P D RSLT("COMMUNITY NOT FOUND (That's OK) => "_L) Q
 . S DIE="^AUTTCOM(",DA=P,DR=".14///<INACTIVE>"
 . D DIE
 . I $D(Y) D RSLT(E(0)_" : EDIT FAILED => "_L) Q
 . D RSLT("SHORT NAME Marked '<INACTIVE>' :")
 . D RSLT($J("",15)_S_" "_O_" "_C_" "_N_$J("",32-$L(N))_A_" "_V)
 .Q
 Q
 ;
 ; -----------------------------------------------------
 ;
CSCNEW ;
 S E=$$E("CSCNEW")
 D RSLT(E)
 D RSLT($J("",11)_"CODE NAME")
 D RSLT($J("",11)_"---- ----")
 F T=1:1 S L=$T(CSCNEW+T^AUM7109A) Q:$P(L,";",3)="END"  D ADDCSC
 Q
 ;
ADDCSC ;
 S L=$P(L,";;",2),C=$P(L,U),N=$P(L,U,2),L=C_" "_N
 I $D(^DIC(45.7,"B",N)) D RSLT($J("",5)_E(1)_"NAME EXISTS => "_N) Q
 I $D(^DIC(45.7,"CIHS",C)) D RSLT($J("",5)_E(1)_"IHS CODE EXISTS => "_C) Q
 S DLAYGO=45.7,DIC="^DIC(45.7,",X=N,DIC("DR")="9999999.01///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DLAYGO
 Q
 ;
 ; -----------------------------------------------------
 ;

AUM7109A
AUM7109A ; IHS/ADC/GTH - STANDARD TABLE UPDATES, 02SEP97 BANYAN ; [ 09/17/97   5:50 PM ]
 ;;97.1;TABLE MAINTENANCE;**9**;DEC 10,1996
 ;
UPDATE ;;IHS STANDARD CODE BOOK MODIFICATIONS - AUGUST 1997   9/2/97    
 ;
LOCNEW ;;A. NEW FACILITY CODES (SECTION VIII-C): AREA^SU^FAC^NAME^PSEUDO
 ;;35^36^13^KIC TRIBAL HEALTH CLINIC^ARR
 ;;45^43^57^HOT SPRINGS^BJL
 ;;55^52^80^CREEK NATION BEHAV HLTH ADMIN^OPV
 ;;75^83^10^CHILOQUIN TRIBAL CLINICS^PYB
 ;;END
 ;
COMMNEW ;;B. NEW COMMUNITY CODES (SECTION V-C): STATE^CNTY^COMM^NAME^AREA^SU
 ;;55^03^017^DALLAS^18^27
 ;;55^58^018^BACON STRIP^18^27
 ;;55^58^019^BARBER TOWN^18^27
 ;;55^58^020^BILLYBOY DAM^18^27
 ;;55^58^021^BLUEBERRY^18^27
 ;;55^58^022^EXELAND^18^27
 ;;55^58^023^FROGG ROAD^18^27
 ;;55^58^024^GIIWEDIN^18^27
 ;;55^58^025^INDIAN LAKE^18^27
 ;;55^58^026^NORTHWOODS BEACH^18^27
 ;;55^58^027^OJIBWA^18^27
 ;;55^58^028^POPPLE TOWN^18^27
 ;;55^58^029^SCOTT LAKE^18^27
 ;;55^58^030^SIX MILE^18^27
 ;;55^58^031^SKUNAWONG^18^27
 ;;55^58^032^TAINTER HILLS^18^27
 ;;55^58^033^TALL PINES^18^27
 ;;55^58^034^TREPANIA ROAD^18^27
 ;;55^58^035^WINTER^18^27
 ;;55^66^993^BIRCHWOOD^18^27
 ;;55^66^994^MINONG^18^27
 ;;55^66^995^SPRINGBROOK^18^27
 ;;END
 ;
COMMMOD ;;C.  COMMUNITY CODE CHANGES  (SECTION V-C): STATE^CNTY^COMM^NAME^AREA^SU
 ;;FROM^55^58^845^EAST SCHOOL HOUSE^18^27
 ;;  TO^55^58^845^SCHOOL HOUSE^18^27
 ;;FROM^55^58^846^INDIAN TRAILS^18^27
 ;;  TO^55^58^846^INDIAN TRAIL^18^27
 ;;FROM^55^58^847^CHIEF LAKE ROAD^18^27
 ;;  TO^55^58^847^CHIEF LAKE^18^27
 ;;FROM^55^58^969^STONELAKE^18^27
 ;;  TO^55^58^969^STONE LAKE^18^27
 ;;FROM^55^58^970^WHITE FISH^18^27
 ;;  TO^55^58^970^WHITEFISH^18^27
 ;;END
 ;
COMMDEL ;;D.  COMMUNITY CODES TO DELETE (SECTION V-C): STATE^CNTY^COMM^NAME^AREA^SU
 ;;55^58^844^SCHOOL HOUSE ROAD^18^27
 ;;END
 ;
CSCNEW ;;E.  CLINICAL SERVICE (SECTION X): CODE^NAME
 ;;21^SWING BED
 ;;END
 ;

AUM7109M
AUM7109M ; IHS/ADC/GTH -  BACKGROUND VALUES FOR STANDARD TABLE UPDATES, 02SEP97 BANYAN ; [ 09/17/97   5:50 PM ]
 ;;97.1;TABLE MAINTENANCE;**9**;DEC 10,1996
 ;
VAL(X,%,Y) ;EP - return background info.
 I X["AREA" Q $T(@%)
 S Y=0
 I X["SU" D  Q Y
 . NEW C,T
 . F C=1:1 S T=$P($T(SU+C),";",3) Q:T="END"  I $P(T,U,1,2)=($E(%,1,2)_U_$E(%,3,4)) S Y=1_";;"_T Q
 .Q
 I '(X["CTY") Q 0
 NEW C,T
 F C=1:1 S T=$P($T(COUNTY+C),";",3) Q:T="END"  I $P(T,U,1,2)=($E(%,1,2)_U_$E(%,3,4)) S Y=1_";;"_T Q
 Q Y
 ;
AREA ; CODE^NAME^PREFIX/REGION^CAN PREFIX
18 ;;18^BEMIDJI NON-IHS^D^J46
35 ;;35^ALASKA TRIBE/638^A^J59
45 ;;45^BILLINGS TRIBE/638^B^J47
55 ;;55^OKLAHOMA TRIBE/638^O^J50
75 ;;75^PORTLAND TRIBE/638^P^J64
 ;;END
 ;
SU ; AREA^SU^NAME
 ;;18^27^NORTHWESTERN WISCONSIN
 ;;35^36^MT.EDGECUMBE
 ;;45^43^FLATHEAD
 ;;55^52^CLAREMORE
 ;;75^83^KLAMATH
 ;;END
 ;
COUNTY ; STATE^COUNTY^NAME
 ;;55^03^BARRON
 ;;55^58^SAWYER
 ;;55^66^WASHBURN
 ;;END
 ;