12:53 PM  21-AUG-98
AUM 98.1 Patch 5.  SCB updates 22May & 3Aug and Exam entry.  Restore 5 routines and DO ^AUM8105.
A9AUM5
A9AUM5 ; IHS/ADC/GTH - STANDARD TABLE UPDATES, 22MAY&03AUG1998 MESSAGES, RPI ; [ 08/21/1998  12:07 PM ]
 ;;98.1;TABLE MAINTENANCE;**5**;NOV 17,1997
 ;
 D START^AUM8105
INTERACT ;EP - Delete routines from interactive call.
 Q:'$L($G(^%ZOSF("DEL")))
 NEW AUM,X
 F AUM=1:1 S X=$P($T(DEL+AUM),";",3) Q:X=""  X ^%ZOSF("DEL") I '$D(ZTQUEUED) W !,X,$E("...........",1,11-$L(X)),"<poof'd>"
 Q
 ;
DEL ;     
 ;;A9AUM4
 ;;AUM8105
 ;;AUM81051
 ;;AUM8105A
 ;;AUM8105M

AUM8105
AUM8105 ; IHS/ADC/GTH - STANDARD TABLE UPDATES, 22MAY&03AUG1998 MESSAGES ; [ 08/21/1998  12:07 PM ]
 ;;98.1;TABLE MAINTENANCE;**5**;NOV 17,1997
 ;
 I '$G(DUZ) W !,"DUZ UNDEFINED OR ZERO.",! Q
 D HOME^%ZIS,DT^DICRW,HELP("INTRO")
 S (DIR(0),DIR("B"))="Y"
 S DIR("A")="Do you want to queue the update to TaskMan"
 S DIR("??")="^D HELP^AUM8105(""Q2"")"
 D ^DIR
 KILL DIR
 I $D(DIRUT) D HELP("Q2") Q
 G START:'Y
QUE ;
 S %DT="AERSX",%DT("A")="Requested Start Time: ",%DT("B")="T@2015",%DT(0)="NOW"
 D ^%DT
 I Y<1 W !,"QUEUE INFORMATION MISSING - NOT QUEUED" D HELP("Q2") G AUM8105
 S X=+Y
 D H^%DTC
 S ZTDTH=%H_","_%T
 S ZTRTN="START^AUM8105",ZTIO="",ZTDESC=$P($P($T(+1),";",2)," ",4,99)
 D ^%ZTLOAD,HOME^%ZIS
 I $D(ZTSK) W !!,"QUEUED TO TASK ",ZTSK,!!,"A mail message with the results will be sent to your MailMan 'IN' basket.",!
 E  W !!,*7,"QUEUE UNSUCCESSFUL.  RESTART UTILITY."
 Q
 ;
START ;EP - From Taskman
 ;
 NEW XMSUB,XMDUZ,XMTEXT,XMY
 KILL ^TMP("AUM8105",$J)
 D START^AUM81051
 S XMSUB=$P($P($T(+1),";",2)," ",4,99),XMDUZ=$S($G(DUZ):DUZ,1:.5),XMTEXT="^TMP(""AUM8105"",$J,",XMY(1)="",XMY(DUZ)=""
 D ^XMD
 KILL ^TMP("AUM8105",$J)
 I $D(ZTQUEUED) S ZTREQ="@" Q
 W !!,"The results are in your MailMan 'IN' basket.",!
 I $L($T(DIR^XBDIR)),$$DIR^XBDIR("Y","Want me to delete the routines in this patch","Y") G INTERACT^A9AUM5
 Q
 ;
INTRO ;
 ;;This updates standard tables according to the changes specified in
 ;;the messages time stamped 22May98@16:22 MDT, and 03Aug98@5:21PM
 ;;Please consult that message, and the mail message produced by this
 ;;update.
 ;;
 ;;###
 ;
Q2 ;
 ;;Answer "Y" if you want to queue this standard table update to TaskMan.
 ;;Answer "N" if you want to run this update interactively.
 ;;
 ;;If you run interactively, results will be displayed on your screen,
 ;;as well as in the mail message sent to you and user 1.  If you queue
 ;;to TaskMan, please read the mail message for results of this update.
 ;;###
 ;
HELP(L) ;EP - Display text at label L.
 W !
 F %=1:1 W !?4,$P($T(@L+%),";",3) Q:$P($T(@L+%+1),";",3)="###"
 Q
 ;

AUM81051
AUM81051 ; IHS/ADC/GTH - STANDARD TABLE UPDATES, 22MAY&03AUG1998 MESSAGES ; [ 08/21/1998  12:07 PM ]
 ;;98.1;TABLE MAINTENANCE;**5**;NOV 17,1997
 ;
 Q
 ;
START ;EP
 ;
 NEW A,C,DIC,DIE,DLAYGO,DR,E,L,M,N,O,P,R,S,T
 ;
 S E(0)="ERROR : ",E(1)="NOT ADDED : "
 D RSLT($J("",5)_$P($T(UPDATE^AUM8105A),";",3))
 D DASH,SUNEW,DASH,LOCNEW,DASH,LOCMOD,DASH,STATENEW,DASH,COMMNEW,DASH,SUMOD,DASH,COMMMOD,DASH,TRIBNEW,DASH,EXAMNEW,DASH
 Q
 ;
 ; -----------------------------------------------------
 ;
ADDOK D RSLT($J("",5)_"Added : "_L) Q
ADDFAIL D RSLT($J("",5)_E(0)_"ADD FAILED => "_L) Q
DASH D RSLT(""),RSLT($$REPEAT^XLFSTR("-",$S($G(IOM):IOM-10,1:70))),RSLT("") Q
DIE NEW A,C,E,L,M,N,O,P,R,S,T
 LOCK +(@(DIE_DA_")")):10 E  D RSLT($J("",5)_E(0)_"Entry '"_DIE_DA_"' IS LOCKED.  NOTIFY PROGRAMMER.") S Y=1 Q
 D ^DIE LOCK -(@(DIE_DA_")")) KILL DA,DIE,DR Q
E(L) Q $P($P($T(@L^AUM8105A),";",3),":",1)
IEN(X,%,Y) ;
 S Y=$O(@(X_"""C"",%,0)"))
 I 'Y S Y=$$VAL^AUM8105M(X,%) I Y NEW Z S Z=E D  S:Y<0 Y="" S E=Z
 . NEW A,C,L,M,N,O,P,R,S,V,%
 . S L=Y
 . I X["AREA" NEW X D RSLT("(Add Missing Area)") D ADDAREA D RSLT("(END Add Missing Area)") Q
 . I X["SU" NEW X D RSLT("(Add Missing SU)") D ADDSU D RSLT("(END Add Missing SU)") Q
 . I X["CTY" NEW X D RSLT("(Add Missing County)") D ADDCNTY D RSLT("(END Add Missing County)") Q
 .Q
 D:'Y RSLT($J("",5)_E(0)_$P(@(X_"0)"),U)_" DOES NOT EXIST => "_%)
 Q +Y
DIK NEW A,C,E,L,M,N,O,P,R,S,T D ^DIK KILL DIK Q
FILE NEW A,C,E,L,M,N,O,P,R,S,T K DD,DO S DIC(0)="L" D FILE^DICN KILL DIC Q
MODOK D RSLT($J("",5)_"Changed : "_L) Q
RSLT(%) S ^(0)=$G(^TMP("AUM8105",$J,0))+1,^(^(0))=% W:'$D(ZTQUEUED) !,% Q
ZEROTH(A,B,C,D,E,F,G,H,I,J,K) ; Return 0th node.  A is file #, rest fields.
 I '$G(A) Q -1
 I '$G(B) Q -1
 F %=67:1:75 Q:'$G(@($C(%)))  S A=+$P(^DD(A,B,0),U,2),B=@($C(%))
 I 'A!('B) Q -1
 I '$D(^DD(A,B,0)) Q -1
 Q U_$P(^DD(A,B,0),U,2)
 ;
 ; -----------------------------------------------------
 ;
ADDAREA ; PROGRAMMER NOTE:  This s/r is required for every patch.
 S L=$P(L,";;",2),A=$P(L,U),N=$P(L,U,2),R=$P(L,U,3),C=$P(L,U,4),L=A_" "_N_" "_R_" "_C
 I $D(^AUTTAREA("B",N)) D RSLT($J("",5)_E(1)_"NAME EXISTS => "_N) Q
 I $D(^AUTTAREA("C",A)) D RSLT($J("",5)_E(1)_"CODE EXISTS => "_A) Q
 S DLAYGO=9999999.21,DIC="^AUTTAREA(",X=N,DIC("DR")=".02///"_A_";.03///"_R_";.04///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DLAYGO
 Q
 ;
 ; -----------------------------------------------------
 ;
ADDCNTY ; PROGRAMMER NOTE:  This s/r is required for every patch.
 S L=$P(L,";;",2),S=$P(L,U),C=$P(L,U,2),N=$P(L,U,3),L=S_" "_C_" "_N
 I $D(^AUTTCTY("C",S_C)) D RSLT($J("",5)_E(1)_"CODE EXISTS => "_S_C) Q
 S P("S")=$$IEN("^DIC(5,",S)
 Q:'P("S")
 S DIC="^AUTTCTY(",X=N,DIC("DR")=".02////"_P("S")_";.03///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
 ; -----------------------------------------------------
 ;
SUNEW ;
 S E=$$E("SUNEW")
 D RSLT(E)
 D RSLT($J("",13)_"AA SU NAME")
 D RSLT($J("",13)_"-- -- ----")
 F T=1:1 S L=$T(SUNEW+T^AUM8105A) Q:$P(L,";",3)="END"  D ADDSU
 Q
 ;
 ; -----------------------------------------------------
 ;
ADDSU ; PROGRAMMER NOTE:  This s/r is required for every patch.
 S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),N=$P(L,U,3),L=A_" "_S_" "_N
 I $D(^AUTTSU("C",A_S)) D RSLT($J("",5)_E(1)_"ASU EXISTS => "_A_S) Q
 S P=$$IEN("^AUTTAREA(",A)
 Q:'P
 S DLAYGO=9999999.22,DIC="^AUTTSU(",X=N,DIC("DR")=".02////"_P_";.03///"_S
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DLAYGO
 Q
 ;
 ; -----------------------------------------------------
SUMOD ;
 S E=$$E("SUMOD")
 D RSLT(E)
 D RSLT($J("",15)_"AA SU NAME")
 D RSLT($J("",15)_"-- -- ----")
 F T=1:2 S L=$T(SUMOD+T^AUM8105A) Q:$P(L,";",3)="END"  S L("TO")=$T(SUMOD+T+1^AUM8105A) D
 . S L=$P(L,U,2,99),A=$P(L,U),S=$P(L,U,2),N=$P(L,U,3)
 . S P=$O(^AUTTSU("C",A_S,0))
 . S L=$P(L("TO"),U,2,99),A=$P(L,U),S=$P(L,U,2),N=$P(L,U,3)
 . I 'P S P=$O(^AUTTSU("C",A_S,0)) I 'P S L=";;"_L D ADDSU Q
 . S L=A_" "_S_" "_N
 . S P("A")=$$IEN("^AUTTAREA(",A)
 . Q:'P("A")
 . S DIE="^AUTTSU(",DA=P,DR=".01///"_N_";.02////"_P("A")_";.03///"_S
 . D DIE
 . I $D(Y) D RSLT($J("",5)_E(0)_" : EDIT SERVICE UNIT FAILED => "_L) Q
 . D MODOK
 .Q
 ;
 Q
 ;
 ; -----------------------------------------------------
 ;
COMMNEW ;
 S E=$$E("COMMNEW")
 D RSLT(E)
 D RSLT($J("",13)_"ST CT COM NAME"_$J("",28)_"AA SU")
 D RSLT($J("",13)_"-- -- --- ----"_$J("",28)_"-- --")
 F T=1:1 S L=$T(COMMNEW+T^AUM8105A) Q:$P(L,";",3)="END"  D ADDCOMM
 Q
 ;
ADDCOMM ;
 S L=$P(L,";;",2),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3),N=$P(L,U,4),A=$P(L,U,5),V=$P(L,U,6),L=S_" "_O_" "_C_" "_N_$J("",32-$L(N))_A_" "_V
 I $D(^AUTTCOM("C",S_O_C)) D RSLT($J("",5)_E(1)_"STCTYCOM CODE EXISTS => "_S_O_C) Q
 S P("O")=$$IEN^AUM81051("^AUTTCTY(",S_O)
 Q:'P("O")
 S P("A")=$$IEN^AUM81051("^AUTTAREA(",A)
 Q:'P("A")
 S P("V")=$$IEN^AUM81051("^AUTTSU(",A_V)
 Q:'P("V")
 S DLAYGO=9999999.05,DIC="^AUTTCOM(",X=N,DIC("DR")=".02////"_P("O")_";.05////"_P("V")_";.06////"_P("A")_";.07///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DLAYGO
 Q
 ;
 ; -----------------------------------------------------
COMMMOD ;
 S E=$$E("COMMMOD")
 D RSLT(E)
 D RSLT($J("",15)_"ST CT COM NAME"_$J("",28)_"AA SU")
 D RSLT($J("",15)_"-- -- --- ----"_$J("",28)_"-- --")
 F T=1:2 S L=$T(COMMMOD+T^AUM8105A) Q:$P(L,";",3)="END"  S L("TO")=$T(COMMMOD+T+1^AUM8105A) D
 . S L=$P(L,U,2,99),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3)
 . S P=$O(^AUTTCOM("C",S_O_C,0))
 . S L=$P(L("TO"),U,2,99),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3),N=$P(L,U,4),A=$P(L,U,5),V=$P(L,U,6)
 . I 'P S P=$O(^AUTTCOM("C",S_O_C,0)) I 'P S L=";;"_L D ADDCOMM Q
 . S L=S_" "_O_" "_C_" "_N_$J("",32-$L(N))_A_" "_V
 . S P("O")=$$IEN^AUM81051("^AUTTCTY(",S_O)
 . Q:'P("O")
 . S P("A")=$$IEN^AUM81051("^AUTTAREA(",A)
 . Q:'P("A")
 . S P("V")=$$IEN^AUM81051("^AUTTSU(",A_V)
 . Q:'P("V")
 . S DIE="^AUTTCOM(",DA=P,DR=".01///"_N_";.02////"_P("O")_";.05////"_P("V")_";.06////"_P("A")_";.07///"_C
 . D DIE
 . I $D(Y) D RSLT($J("",5)_E(0)_"CHANGE FAILED => "_L) Q
 . D MODOK
 .Q
 ;
 ; Line below is comment'd if the only change is to the name of the community.
 D DASH,RSLT($$COMMMOD^AUMXPORT("AUM8105A")_" patients marked for export because of the Community Code changes.")
 Q
 ;
 ; -----------------------------------------------------
 ;
LOCNEW ;
 S E=$$E("LOCNEW")
 D RSLT(E)
 D RSLT($J("",13)_"AA SU FA NAME"_$J("",28)_"PSEUDO")
 D RSLT($J("",13)_"-- -- -- ----"_$J("",28)_"------")
 F T=1:1 S L=$T(LOCNEW+T^AUM8105A) Q:$P(L,";",3)="END"  D ADDLOC
 Q
 ;
ADDLOC ;
 S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3),N=$P(L,U,4),P=$P(L,U,5)
 S L=A_" "_S_" "_F_" "_N_$J("",32-$L(N))_P
 S %=A_S_F,%=$O(^AUTTLOC("C",%,0))
 I % D RSLT($J("",5)_E(1)_"ASUFAC EXISTS => "_A_S_F) D  Q
 . I $P($G(^AUTTLOC(%,0)),U,21) S DIE="^AUTTLOC(",DA=%,DR=".27///@" D DIE D:$D(Y) RSLT($J("",5)_E(0)_"DELETE INACTIVE DATE FAILED => "_L) D:'$D(Y) RSLT($J("",5)_"INACTIVE DATE DELETED => "_L)
 . S %=$O(^AUTTLOC("C",A_S_F,0)),%=$P(^AUTTLOC(%,0),U)
 . I %,$D(^DIC(4,%,0)),N'=$P(^DIC(4,%,0),U) S DIE="^DIC(4,",DA=%,DR=".01///"_N D DIE D:$D(Y) RSLT($J("",5)_E(0)_"EDIT INSTITUTION FAILED => "_L) D:'$D(Y) RSLT($J("",5)_"INSTITUTION NAME UPDATED => "_L)
 . S %=$O(^AUTTLOC("C",A_S_F,0))
 . I P'=$P($G(^AUTTLOC(%,1)),U,2) S DIE="^AUTTLOC(",DA=%,DR=".31///"_P D DIE D:$D(Y) RSLT($J("",5)_E(0)_"EDIT PSEUDO PREFIX FAILED => "_L) D:'$D(Y) RSLT($J("",5)_"PSEUDO PREFIX UPDATED => "_L)
 .Q
 S P("A")=$$IEN("^AUTTAREA(",A)
 Q:'P("A")
 S P("S")=$$IEN("^AUTTSU(",A_S)
 Q:'P("S")
 F DINUM=+$P(^DIC(4,0),U,3):1 Q:'$D(^DIC(4,DINUM))&('$D(^AUTTLOC(DINUM)))  I DINUM>99999 D RSLT($J("",5)_E(0)_"DINUM FOR LOC/INSTITUTION TOO BIG. NOTIFY ISC.") Q
 Q:DINUM>99999
 S DLAYGO=4,DIC="^DIC(4,",X=N
 D FILE
 KILL DINUM,DLAYGO
 I Y<0 D RSLT($J("",5)_E(0)_"^DIC(4 ADD FAILED => "_L) Q
 S DINUM=+Y,DLAYGO=9999999.06,DIC="^AUTTLOC(",X=DINUM,DIC("DR")=".04////"_P("A")_";.05////"_P("S")_";.07///"_F_";.31///"_P
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DINUM,DLAYGO
 Q
 ;
 ; -----------------------------------------------------
 ;
LOCMOD ;
 S E=$$E("LOCMOD")
 D RSLT(E)
 D RSLT($J("",15)_"AA SU FA NAME"_$J("",28)_"PSEUDO")
 D RSLT($J("",15)_"-- -- -- ----"_$J("",28)_"------")
 F T=1:2 S L=$T(LOCMOD+T^AUM8105A) Q:$P(L,";",3)="END"  S L("TO")=$T(LOCMOD+T+1^AUM8105A) D
 . S L=$P(L,U,2,99),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3)
 . S P=$O(^AUTTLOC("C",A_S_F,0))
 . S L=$P(L("TO"),U,2,99),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3),N=$P(L,U,4)
 . I 'P S P=$O(^AUTTLOC("C",A_S_F,0)) I 'P S L=";;"_L D ADDLOC Q
 . S L=A_" "_S_" "_F_" "_N_$J("",32-$L(N))_$P(L("TO"),U,6)
 . S P("A")=$$IEN("^AUTTAREA(",A)
 . Q:'P("A")
 . S P("S")=$$IEN("^AUTTSU(",A_S)
 . Q:'P("S")
 . S DIE="^AUTTLOC(",DA=P,DR=".04////"_P("A")_";.05////"_P("S")_";.07///"_F_";.31///"_$P(L("TO"),U,6)
 . D DIE
 . I $D(Y) D RSLT($J("",5)_E(0)_"EDIT LOCATION FAILED => "_L) Q
 . S DIE="^DIC(4,",DA=$P(^AUTTLOC(P,0),U),DR=".01///"_N
 . D DIE
 . I $D(Y) D RSLT($J("",5)_E(0)_"EDIT INSTITUTION FAILED => "_L) Q
 . D MODOK
 .Q
 ; If Locations were name changes, only, following line commented.
 D DASH,RSLT($$LOCMOD^AUMXPORT("AUM8105A")_" patients marked for export because of the Location Code changes.")
 ;
 Q
 ;
 ; -----------------------------------------------------
 ;
STATENEW ;
 S E=$$E("STATENEW")
 D RSLT(E)
 D RSLT($J("",13)_"CC NAME ABBREV")
 D RSLT($J("",13)_"-- ---- ------")
 F T=1:1 S L=$T(STATENEW+T^AUM8105A) Q:$P(L,";",3)="END"  D ADDSTATE
 Q
 ;
ADDSTATE ;
 S L=$P(L,";;",2),C=$P(L,U),N=$P(L,U,2),A=$P(L,U,3),L=C_" "_N_" "_A
 I $D(^DIC(5,"C",A)) D RSLT($J("",5)_E(1)_"STATE ABBREVIATION EXISTS => "_A) Q
 S DLAYGO=5,DIC="^DIC(5,",X=N,DIC("DR")="1///"_A_";2///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DLAYGO
 Q
 ;
 ; -----------------------------------------------------
 ;
TRIBNEW ;
 S E=$$E("TRIBNEW")
 D RSLT(E)
 D RSLT($J("",13)_"CCC NAME")
 D RSLT($J("",13)_"--- ----")
 F T=1:1 S L=$T(TRIBNEW+T^AUM8105A) Q:$P(L,";",3)="END"  D ADDTRIB
 Q
 ;
ADDTRIB ;
 S L=$P(L,";;",2),C=$P(L,U),N=$P(L,U,2),L=C_" "_N
 I $D(^AUTTTRI("C",C)) D RSLT($J("",5)_E(1)_"TRIBE CODE EXISTS => "_C) Q
 S DLAYGO=9999999.03,DIC="^AUTTTRI(",X=N,DIC("DR")=".02///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
 ; -----------------------------------------------------
 ;
EXAMNEW ;
 S E=$$E("EXAMNEW")
 D RSLT(E)
 D RSLT($J("",13)_"CC NAME")
 D RSLT($J("",13)_"-- ----")
 F T=1:1 S L=$T(EXAMNEW+T^AUM8105A) Q:$P(L,";",3)="END"  D ADDEXAM
 Q
 ;
ADDEXAM ;
 S L=$P(L,";;",2),C=$P(L,U),N=$P(L,U,2),L=C_" "_N
 I $D(^AUTTEXAM("C",C)) D RSLT($J("",5)_E(1)_"EXAM CODE EXISTS => "_C) Q
 S DLAYGO=9999999.15,DIC="^AUTTEXAM(",X=N,DIC("DR")=".02///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;

AUM8105A
AUM8105A ; IHS/ADC/GTH - STANDARD TABLE UPDATES, 22MAY&03AUG1998 MESSAGES ; [ 08/21/1998  12:07 PM ]
 ;;98.1;TABLE MAINTENANCE;**5**;NOV 17,1997
 ;
UPDATE ;;IHS STANDARD CODE BOOK MODIFICATIONS - 1998 5/22/98 & 8/3/98 
 ;
SUNEW ;;A.  NEW SERVICE UNIT CODES (SECTION VIII-B): AREA^S.U.^NAME
 ;;55^53^CLINTON
 ;;55^56^PAWNEE
 ;;55^64^WEWOKA
 ;;END
 ;
LOCNEW ;;B/B.  NEW FACILITY CODE (SECTION VIII-C): AREA^S.U.^FAC.^NAME^PSEUDO
 ;;30^31^95^HOME^AYZ
 ;;50^65^61^HASKELL HLTH CTR SUB ABUSE^OUK
 ;;55^00^60^AMERICAN INDIAN CTR HLFWY HSE^OUL
 ;;55^00^61^MORNING STAR OUTREACH PROG^OUM
 ;;55^52^60^CREEK NATION SUB ABUSE PROG^OUN
 ;;55^52^61^INTER-TRIBAL SUB ABUSE PROG^OUO
 ;;55^52^62^COMMUNITY HOUSE^OUP
 ;;55^53^60^CHEYENNE & ARAPAHO TX CTR^OUQ
 ;;55^54^60^SAC & FOX MO SUB ABUSE PROG^OUR
 ;;55^54^61^FOUR WINDS HALFWAY HOUSE^OUS
 ;;55^54^62^PRAIRIE BAND POTAWATOMI S/A^OUT
 ;;55^55^60^KIOWA TRIBE SUB ABUSE PROG^OUU
 ;;55^55^61^COMANCHE TRIBE NEW PATHWAYS^OUV
 ;;55^55^62^COMANCHE TRIBE PREV PROG^OUW
 ;;55^55^63^CONSORTIUM AGAINST SUB ABUSE^OUX
 ;;55^55^64^CADDO TRIBE A/D PROG^OUY
 ;;55^56^61^NATIVE AMERICAN WOMEN'S REHAB^OUZ
 ;;55^56^62^OSAGE NATION SUB ABUSE PROG^OXC
 ;;55^56^63^OTOE-MISSOURI SUB ABUSE PROG^OXD
 ;;55^56^64^PAWNEE HUMAN DEV SERVICES^OXE
 ;;55^56^65^SOCIAL DEVELOPMENT CENTER^OXF
 ;;55^56^67^TONKAWA TRIBAL SUB ABUSE PROG^OXG
 ;;55^58^60^NATIVE AMERICAN CTR RECOVERY^OXI
 ;;55^58^61^KICKAPOO OK SUB ABUSE PROG^OXJ
 ;;55^58^65^IOWA TRIBE SUB ABUSE PROG^OXK
 ;;55^58^66^CITIZEN BAND POTAWATOMI S/A^OXL
 ;;55^59^61^JACK BROWN YOUTH TX CTR^OXM
 ;;55^64^60^SEMINOLE NATION SUB ABUSE PRG^OXO
 ;;57^10^11^DALLAS INTER-TRIBAL CENTER^OXP
 ;;66^10^11^GRASS VALLEY CLINIC^LLY
 ;;66^21^52^SIHC YOUTH TREATMENT CENTER^LLX
 ;;END
 ;
LOCMOD ;;C.  FACILITY CODE CHANGE (SECTION VIII-C): AREA^S.U.^FAC.^NAME^PSEUDO
 ;;FROM^65^63^56^ELY^XEW
 ;;  TO^60^63^56^ELY HEALTH STATION^XEG
 ;;FROM^75^78^83^HOH RIVER CHS OFFICE^PAZ
 ;;  TO^70^78^83^HOH RIVER CHS OFFICE^PGZ
 ;;END
 ;
STATENEW ;;D.  NEW STATE CODE (SECTION V-A): CODE^NAME^ABBREVIATION
 ;;73^GUAM^GU
 ;;END
 ;
COMMNEW ;;E/C.  NEW COMMUNITY CODES (SECTION V-C): STATE^CNTY^COMM^NAME^AREA^S.U.
 ;;18^43^030^WARSAW^18^23
 ;;26^03^031^HOPKINS^18^23
 ;;26^03^032^PLAINWELL^18^23
 ;;26^11^033^GALIEN^18^23
 ;;26^80^034^BREEDSVILLE^18^23
 ;;28^40^110^RED WATER^58^57
 ;;28^40^111^STANDING PINE^58^57
 ;;28^50^112^PEARL RIVER^58^57
 ;;28^50^113^TUCKER^58^57
 ;;28^80^114^CRYSTAL RIDGE^58^57
 ;;06^06^140^COLUSA WEST^66^15
 ;;06^06^141^COLLEGE CITY^66^15
 ;;06^52^142^RANCHO TEHAMA^66^15
 ;;06^52^143^DAIRYVILLE^66^15
 ;;06^52^144^DALES^66^15
 ;;06^52^145^PAYNES CREEK^66^15
 ;;06^52^146^MINERAL^66^15
 ;;06^52^147^TOWN OF TEHAMA^66^15
 ;;06^52^148^TEHAMA COUNTY WEST^66^15
 ;;06^52^149^TEHAMA COUNTY EAST^66^35
 ;;32^12^636^CURRANT^60^63
 ;;END
 ;
SUMOD ;;A.  SERVICE UNIT CHANGE (SECTION VIII-B): AREA^S.U.^NAME
 ;;FROM^64^85^CENTRAL VAL URB IND PROG
 ;;  TO^64^85^FRESNO INDIAN HEALTH ASSN
 ;;END
 ;
COMMMOD ;;D.  COMMUNITY CODE CHANGES (SECTION V-C): STATE^CNTY^COMM^NAME^AREA^S.U.
 ;;FROM^06^37^116^POTRERO^66^32
 ;;  TO^06^37^116^POTRERO^66^21
 ;;FROM^06^37^117^TECATE^66^32
 ;;  TO^06^37^117^TECATE^66^21
 ;;FROM^06^37^207^LEMON GROVE^66^21
 ;;  TO^06^37^207^LEMON GROVE^64^81
 ;;FROM^06^37^625^SPRING VALLEY^64^81
 ;;  TO^06^37^625^SPRING VALLEY^66^21
 ;;FROM^06^37^626^SPRING VALLEY BEACH AREA^64^81
 ;;  TO^06^37^626^SPRING VALLEY BEACH AREA^66^21
 ;;FROM^06^52^126^LOS MOLINOS^66^15
 ;;  TO^06^52^126^LOS MOLINOS^66^35
 ;;FROM^06^52^128^VINA^66^15
 ;;  TO^06^52^128^VINA^66^35
 ;;END
 ;
TRIBNEW ;;E.  NEW TRIBE CODES (SECTION XVIII): CODE^NAME
 ;;980^FILIPINO
 ;;985^NATIVE HAWAIIAN/OTH PAC ISLANDER
 ;;990^WHITE (CAUCASIAN)
 ;;991^HISPANIC/LATINO
 ;;992^BLACK/AFRICAN AMERICAN
 ;;993^ASIAN
 ;;END
 ;
EXAMNEW ;;ETC.  EXAM FILE (FIELD REQUEST): CODE^NAME
 ;;30^DENTAL EXAM
 ;;END
 ;

AUM8105M
AUM8105M ; IHS/ADC/GTH -  BACKGROUND VALUES FOR STANDARD TABLE UPDATES, 22MAY&03AUG1998 MESSAGES ; [ 08/21/1998  12:07 PM ]
 ;;98.1;TABLE MAINTENANCE;**5**;NOV 17,1997
 ;
VAL(X,%,Y) ;EP - return background info.
 I X["AREA" Q $T(@%)
 S Y=0
 I X["SU" D  Q Y
 . NEW C,T
 . F C=1:1 S T=$P($T(SU+C),";",3) Q:T="END"  I $P(T,U,1,2)=($E(%,1,2)_U_$E(%,3,4)) S Y=1_";;"_T Q
 .Q
 I '(X["CTY") Q 0
 NEW C,T
 F C=1:1 S T=$P($T(COUNTY+C),";",3) Q:T="END"  I $P(T,U,1,2)=($E(%,1,2)_U_$E(%,3,4)) S Y=1_";;"_T Q
 Q Y
 ;
AREA ; CODE^NAME^PREFIX/REGION^CAN PREFIX
18 ;;18^BEMIDJI NON-IHS^D^J46
30 ;;30^ALASKA^A^J59
50 ;;50^OKLAHOMA^O^J50
55 ;;55^OKLAHOMA TRIBE/638^O^J50
57 ;;57^OKLAHOMA URBAN^O^J50
58 ;;58^NASHVILLE NON-IHS^U^J51
60 ;;60^PHOENIX^X^J40
64 ;;64^CALIFORNIA URBAN^L^J41
66 ;;66^CALIFORNIA TRIBE/638^L^J41
70 ;;70^PORTLAND^P^J64
 ;;END
 ;
SU ; AREA^SU^NAME
1823 ;;18^23^EASTERN MICHIGAN
3031 ;;30^31^ANCHORAGE
5065 ;;50^65^HASKELL
5500 ;;55^00^NON SERVICE UNIT
5552 ;;55^52^CLAREMORE
5554 ;;55^54^KANSAS
5555 ;;55^55^LAWTON
5558 ;;55^58^SHAWNEE
5559 ;;55^59^TAHLEQUAH
5710 ;;57^10^DALLAS
5857 ;;58^57^CHOCTAW
6063 ;;60^63^OWYHEE
6481 ;;64^81^SAN DIEGO A.I.H.C.
6485 ;;64^85^CENTRAL VAL URB IND PROG
6610 ;;66^10^CHAPA-DE INDIAN HEALTH PROJECT
6615 ;;66^15^NORTH VALLEY
6621 ;;66^21^SOUTHERN IHC
6635 ;;66^35^GREENVILLE
7078 ;;70^78^TAHOLAH
 ;;END
 ;
COUNTY ; STATE^COUNTY^NAME
0606 ;;06^06^COLUSA
0637 ;;06^37^SAN DIEGO
0652 ;;06^52^TEHAMA
1843 ;;18^43^KOSCIUSKO
2603 ;;26^03^ALLEGAN
2611 ;;26^11^BERRIEN
2680 ;;26^80^VAN BUREN
2840 ;;28^40^LEAKE
2850 ;;28^50^NESHOBA
2880 ;;28^80^WINSTON
3212 ;;32^12^NYE
 ;;END
 ;