5:07 PM  12-NOV-98
AUM 98.1 Patch 7, SCB Changes 4Nov98 message.  Restore 5 routines and DO ^AUM8107.
A9AUM7
A9AUM7 ; IHS/ASDST/GTH - STANDARD TABLE UPDATES, 4NOV1998 MESSAGE, RPI ; [ 11/12/1998   5:06 PM ]
 ;;98.1;TABLE MAINTENANCE;**7**;NOV 17,1997
 ;
 D START^AUM8107
INTERACT ;EP - Delete routines from interactive call.
 Q:'$L($G(^%ZOSF("DEL")))
 NEW AUM,X
 F AUM=1:1 S X=$P($T(DEL+AUM),";",3) Q:X=""  X ^%ZOSF("DEL") I '$D(ZTQUEUED) W !,X,$E("...........",1,11-$L(X)),"<poof'd>"
 Q
 ;
DEL ;     
 ;;A9AUM6
 ;;AUM8107
 ;;AUM81071
 ;;AUM8107A
 ;;AUM8107M

AUM8107
AUM8107 ; IHS/ASDST/GTH - STANDARD TABLE UPDATES, 4NOV1998 MESSAGE ; [ 11/12/1998   5:06 PM ]
 ;;98.1;TABLE MAINTENANCE;**7**;NOV 17,1997
 ;
 I '$G(DUZ) W !,"DUZ UNDEFINED OR ZERO.",! Q
 D HOME^%ZIS,DT^DICRW,HELP("INTRO")
 S (DIR(0),DIR("B"))="Y"
 S DIR("A")="Do you want to queue the update to TaskMan"
 S DIR("??")="^D HELP^AUM8107(""Q2"")"
 D ^DIR
 KILL DIR
 I $D(DIRUT) D HELP("Q2") Q
 G START:'Y
QUE ;
 S %DT="AERSX",%DT("A")="Requested Start Time: ",%DT("B")="T@2015",%DT(0)="NOW"
 D ^%DT
 I Y<1 W !,"QUEUE INFORMATION MISSING - NOT QUEUED" D HELP("Q2") G AUM8107
 S X=+Y
 D H^%DTC
 S ZTDTH=%H_","_%T
 S ZTRTN="START^AUM8107",ZTIO="",ZTDESC=$P($P($T(+1),";",2)," ",4,99)
 D ^%ZTLOAD,HOME^%ZIS
 I $D(ZTSK) W !!,"QUEUED TO TASK ",ZTSK,!!,"A mail message with the results will be sent to your MailMan 'IN' basket.",!
 E  W !!,*7,"QUEUE UNSUCCESSFUL.  RESTART UTILITY."
 Q
 ;
START ;EP - From Taskman
 ;
 NEW XMSUB,XMDUZ,XMTEXT,XMY
 KILL ^TMP("AUM8107",$J)
 D START^AUM81071
 S XMSUB=$P($P($T(+1),";",2)," ",4,99),XMDUZ=$S($G(DUZ):DUZ,1:.5),XMTEXT="^TMP(""AUM8107"",$J,",XMY(1)="",XMY(DUZ)=""
 D ^XMD
 KILL ^TMP("AUM8107",$J)
 I $D(ZTQUEUED) S ZTREQ="@" Q
 W !!,"The results are in your MailMan 'IN' basket.",!
 I $L($T(DIR^XBDIR)),$$DIR^XBDIR("Y","Want me to delete the routines in this patch","Y") G INTERACT^A9AUM7
 Q
 ;
INTRO ;
 ;;This updates standard tables according to the changes specified in
 ;;the message time stamped 4Nov98 5:38PM.  Please consult that message,
 ;;and the mail message produced by this update.
 ;;
 ;;###
 ;
Q2 ;
 ;;Answer "Y" if you want to queue this standard table update to TaskMan.
 ;;Answer "N" if you want to run this update interactively.
 ;;
 ;;If you run interactively, results will be displayed on your screen,
 ;;as well as in the mail message sent to you and user 1.  If you queue
 ;;to TaskMan, please read the mail message for results of this update.
 ;;###
 ;
HELP(L) ;EP - Display text at label L.
 W !
 F %=1:1 W !?4,$P($T(@L+%),";",3) Q:$P($T(@L+%+1),";",3)="###"
 Q
 ;

AUM81071
AUM81071 ; IHS/ASDST/GTH - STANDARD TABLE UPDATES, 4NOV1998 MESSAGE ; [ 11/12/1998   5:06 PM ]
 ;;98.1;TABLE MAINTENANCE;**7**;NOV 17,1997
 ;
 Q
 ;
START ;EP
 ;
 NEW A,C,DIC,DIE,DLAYGO,DR,E,L,M,N,O,P,R,S,T
 ;
 S E(0)="ERROR : ",E(1)="NOT ADDED : "
 D RSLT($J("",5)_$P($T(UPDATE^AUM8107A),";",3))
 D DASH,LOCNEW,DASH,LOCINACT,DASH,COMMNEW,DASH,COMMMOD,DASH,TRIBMOD,DASH
 Q
 ;
 ; -----------------------------------------------------
 ;
ADDOK D RSLT($J("",5)_"Added : "_L) Q
ADDFAIL D RSLT($J("",5)_E(0)_"ADD FAILED => "_L) Q
DASH D RSLT(""),RSLT($$REPEAT^XLFSTR("-",$S($G(IOM):IOM-10,1:70))),RSLT("") Q
DIE NEW A,C,E,L,M,N,O,P,R,S,T
 LOCK +(@(DIE_DA_")")):10 E  D RSLT($J("",5)_E(0)_"Entry '"_DIE_DA_"' IS LOCKED.  NOTIFY PROGRAMMER.") S Y=1 Q
 D ^DIE LOCK -(@(DIE_DA_")")) KILL DA,DIE,DR Q
E(L) Q $P($P($T(@L^AUM8107A),";",3),":",1)
IEN(X,%,Y) ;
 S Y=$O(@(X_"""C"",%,0)"))
 I 'Y S Y=$$VAL^AUM8107M(X,%) I Y NEW Z S Z=E D  S:Y<0 Y="" S E=Z
 . NEW A,C,L,M,N,O,P,R,S,V,%
 . S L=Y
 . I X["AREA" NEW X D RSLT("(Add Missing Area)") D ADDAREA D RSLT("(END Add Missing Area)") Q
 . I X["SU" NEW X D RSLT("(Add Missing SU)") D ADDSU D RSLT("(END Add Missing SU)") Q
 . I X["CTY" NEW X D RSLT("(Add Missing County)") D ADDCNTY D RSLT("(END Add Missing County)") Q
 .Q
 D:'Y RSLT($J("",5)_E(0)_$P(@(X_"0)"),U)_" DOES NOT EXIST => "_%)
 Q +Y
DIK NEW A,C,E,L,M,N,O,P,R,S,T D ^DIK KILL DIK Q
FILE NEW A,C,E,L,M,N,O,P,R,S,T K DD,DO S DIC(0)="L" D FILE^DICN KILL DIC Q
MODOK D RSLT($J("",5)_"Changed : "_L) Q
RSLT(%) S ^(0)=$G(^TMP("AUM8107",$J,0))+1,^(^(0))=% W:'$D(ZTQUEUED) !,% Q
ZEROTH(A,B,C,D,E,F,G,H,I,J,K) ; Return 0th node.  A is file #, rest fields.
 I '$G(A) Q -1
 I '$G(B) Q -1
 F %=67:1:75 Q:'$G(@($C(%)))  S A=+$P(^DD(A,B,0),U,2),B=@($C(%))
 I 'A!('B) Q -1
 I '$D(^DD(A,B,0)) Q -1
 Q U_$P(^DD(A,B,0),U,2)
 ;
 ; -----------------------------------------------------
 ;
ADDAREA ; PROGRAMMER NOTE:  This s/r is required for every patch.
 S L=$P(L,";;",2),A=$P(L,U),N=$P(L,U,2),R=$P(L,U,3),C=$P(L,U,4),L=A_" "_N_" "_R_" "_C
 I $D(^AUTTAREA("B",N)) D RSLT($J("",5)_E(1)_"NAME EXISTS => "_N) Q
 I $D(^AUTTAREA("C",A)) D RSLT($J("",5)_E(1)_"CODE EXISTS => "_A) Q
 S DLAYGO=9999999.21,DIC="^AUTTAREA(",X=N,DIC("DR")=".02///"_A_";.03///"_R_";.04///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DLAYGO
 Q
 ;
 ; -----------------------------------------------------
 ;
ADDCNTY ; PROGRAMMER NOTE:  This s/r is required for every patch.
 S L=$P(L,";;",2),S=$P(L,U),C=$P(L,U,2),N=$P(L,U,3),L=S_" "_C_" "_N
 I $D(^AUTTCTY("C",S_C)) D RSLT($J("",5)_E(1)_"CODE EXISTS => "_S_C) Q
 S P("S")=$$IEN("^DIC(5,",S)
 Q:'P("S")
 S DIC="^AUTTCTY(",X=N,DIC("DR")=".02////"_P("S")_";.03///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
 ; -----------------------------------------------------
 ;
ADDSU ; PROGRAMMER NOTE:  This s/r is required for every patch.
 S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),N=$P(L,U,3),L=A_" "_S_" "_N
 I $D(^AUTTSU("C",A_S)) D RSLT($J("",5)_E(1)_"ASU EXISTS => "_A_S) Q
 S P=$$IEN("^AUTTAREA(",A)
 Q:'P
 S DLAYGO=9999999.22,DIC="^AUTTSU(",X=N,DIC("DR")=".02////"_P_";.03///"_S
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DLAYGO
 Q
 ;
 ; -----------------------------------------------------
 ;
COMMNEW ;
 S E=$$E("COMMNEW")
 D RSLT(E)
 D RSLT($J("",13)_"ST CT COM NAME"_$J("",28)_"AA SU")
 D RSLT($J("",13)_"-- -- --- ----"_$J("",28)_"-- --")
 F T=1:1 S L=$T(COMMNEW+T^AUM8107A) Q:$P(L,";",3)="END"  D ADDCOMM
 Q
 ;
ADDCOMM ;
 S L=$P(L,";;",2),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3),N=$P(L,U,4),A=$P(L,U,5),V=$P(L,U,6),L=S_" "_O_" "_C_" "_N_$J("",32-$L(N))_A_" "_V
 I $D(^AUTTCOM("C",S_O_C)) D RSLT($J("",5)_E(1)_"STCTYCOM CODE EXISTS => "_S_O_C) Q
 S P("O")=$$IEN^AUM81071("^AUTTCTY(",S_O)
 Q:'P("O")
 S P("A")=$$IEN^AUM81071("^AUTTAREA(",A)
 Q:'P("A")
 S P("V")=$$IEN^AUM81071("^AUTTSU(",A_V)
 Q:'P("V")
 S DLAYGO=9999999.05,DIC="^AUTTCOM(",X=N,DIC("DR")=".02////"_P("O")_";.05////"_P("V")_";.06////"_P("A")_";.07///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DLAYGO
 Q
 ;
 ; -----------------------------------------------------
COMMMOD ;
 S E=$$E("COMMMOD")
 D RSLT(E)
 D RSLT($J("",15)_"ST CT COM NAME"_$J("",28)_"AA SU")
 D RSLT($J("",15)_"-- -- --- ----"_$J("",28)_"-- --")
 F T=1:2 S L=$T(COMMMOD+T^AUM8107A) Q:$P(L,";",3)="END"  S L("TO")=$T(COMMMOD+T+1^AUM8107A) D
 . S L=$P(L,U,2,99),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3)
 . S P=$O(^AUTTCOM("C",S_O_C,0))
 . S L=$P(L("TO"),U,2,99),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3),N=$P(L,U,4),A=$P(L,U,5),V=$P(L,U,6)
 . I 'P S P=$O(^AUTTCOM("C",S_O_C,0)) I 'P S L=";;"_L D ADDCOMM Q
 . S L=S_" "_O_" "_C_" "_N_$J("",32-$L(N))_A_" "_V
 . S P("O")=$$IEN^AUM81071("^AUTTCTY(",S_O)
 . Q:'P("O")
 . S P("A")=$$IEN^AUM81071("^AUTTAREA(",A)
 . Q:'P("A")
 . S P("V")=$$IEN^AUM81071("^AUTTSU(",A_V)
 . Q:'P("V")
 . S DIE="^AUTTCOM(",DA=P,DR=".01///"_N_";.02////"_P("O")_";.05////"_P("V")_";.06////"_P("A")_";.07///"_C
 . D DIE
 . I $D(Y) D RSLT($J("",5)_E(0)_"CHANGE FAILED => "_L) Q
 . D MODOK
 .Q
 ;
 ; Line below is comment'd if the only change is to the name of the community.
 ; D DASH,RSLT($$COMMMOD^AUMXPORT("AUM8107A")_" patients marked for export because of the Community Code changes.")
 Q
 ;
 ; -----------------------------------------------------
 ;
LOCNEW ;
 S E=$$E("LOCNEW")
 D RSLT(E)
 D RSLT($J("",13)_"AA SU FA NAME"_$J("",28)_"PSEUDO")
 D RSLT($J("",13)_"-- -- -- ----"_$J("",28)_"------")
 F T=1:1 S L=$T(LOCNEW+T^AUM8107A) Q:$P(L,";",3)="END"  D ADDLOC
 Q
 ;
ADDLOC ;
 S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3),N=$P(L,U,4),P=$P(L,U,5)
 S L=A_" "_S_" "_F_" "_N_$J("",32-$L(N))_P
 S %=A_S_F,%=$O(^AUTTLOC("C",%,0))
 I % D RSLT($J("",5)_E(1)_"ASUFAC EXISTS => "_A_S_F) D  Q
 . I $P($G(^AUTTLOC(%,0)),U,21) S DIE="^AUTTLOC(",DA=%,DR=".27///@" D DIE D:$D(Y) RSLT($J("",5)_E(0)_"DELETE INACTIVE DATE FAILED => "_L) D:'$D(Y) RSLT($J("",5)_"INACTIVE DATE DELETED => "_L)
 . S %=$O(^AUTTLOC("C",A_S_F,0)),%=$P(^AUTTLOC(%,0),U)
 . I %,$D(^DIC(4,%,0)),N'=$P(^DIC(4,%,0),U) S DIE="^DIC(4,",DA=%,DR=".01///"_N D DIE D:$D(Y) RSLT($J("",5)_E(0)_"EDIT INSTITUTION FAILED => "_L) D:'$D(Y) RSLT($J("",5)_"INSTITUTION NAME UPDATED => "_L)
 . S %=$O(^AUTTLOC("C",A_S_F,0))
 . I P'=$P($G(^AUTTLOC(%,1)),U,2) S DIE="^AUTTLOC(",DA=%,DR=".31///"_P D DIE D:$D(Y) RSLT($J("",5)_E(0)_"EDIT PSEUDO PREFIX FAILED => "_L) D:'$D(Y) RSLT($J("",5)_"PSEUDO PREFIX UPDATED => "_L)
 .Q
 S P("A")=$$IEN("^AUTTAREA(",A)
 Q:'P("A")
 S P("S")=$$IEN("^AUTTSU(",A_S)
 Q:'P("S")
 F DINUM=+$P(^DIC(4,0),U,3):1 Q:'$D(^DIC(4,DINUM))&('$D(^AUTTLOC(DINUM)))  I DINUM>99999 D RSLT($J("",5)_E(0)_"DINUM FOR LOC/INSTITUTION TOO BIG. NOTIFY ISC.") Q
 Q:DINUM>99999
 S DLAYGO=4,DIC="^DIC(4,",X=N
 D FILE
 KILL DINUM,DLAYGO
 I Y<0 D RSLT($J("",5)_E(0)_"^DIC(4 ADD FAILED => "_L) Q
 S DINUM=+Y,DLAYGO=9999999.06,DIC="^AUTTLOC(",X=DINUM,DIC("DR")=".04////"_P("A")_";.05////"_P("S")_";.07///"_F_";.31///"_P
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DINUM,DLAYGO
 Q
 ;
 ; -----------------------------------------------------
 ;
LOCINACT ;
 S E=$$E("LOCINACT")
 D RSLT(E)
 D RSLT($J("",20)_"AA SU FA NAME")
 D RSLT($J("",20)_"-- -- -- ----")
 F T=1:1 S L=$T(LOCINACT+T^AUM8107A) Q:$P(L,";",3)="END"  D
 . S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3),N=$P(L,U,4),P=$P(L,U,5)
 . S L=A_" "_S_" "_F_" "_N_" "_P
 . S %=A_S_F,%=$O(^AUTTLOC("C",%,0))
 . I '% D RSLT($J("",5)_"ASUFAC "_A_S_F_" not found (OK).") Q
 . S DIE="^AUTTLOC(",DA=%,DR=".27////"_DT
 . D DIE
 . I $D(Y) D RSLT($J("",5)_E(0)_"EDIT INACTIVE DATE FAILED => "_L) I 1
 . E  D RSLT($J("",5)_"INACTIVATED => "_L)
 .Q
 Q
 ;
 ; -----------------------------------------------------
 ;
ADDTRIB ;
 S L=$P(L,";;",2),C=$P(L,U),N=$P(L,U,2),L=C_" "_N
 I $D(^AUTTTRI("C",C)) D RSLT($J("",5)_E(1)_"TRIBE CODE EXISTS => "_C) Q
 S DLAYGO=9999999.03,DIC="^AUTTTRI(",X=N,DIC("DR")=".02///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
TRIBMOD ;
 S E=$$E("TRIBMOD")
 D RSLT(E)
 D RSLT($J("",14)_"CODE  NAME")
 D RSLT($J("",14)_"----  ----")
 F T=1:2 S L=$T(TRIBMOD+T^AUM8107A) Q:$P(L,";",3)="END"  S L("TO")=$T(TRIBMOD+T+1^AUM8107A) D
 . S L=$P(L,U,2,99),C=$P(L,U)
 . S P=$O(^AUTTTRI("C",C,0))
 . S L=$P(L("TO"),U,2,99),C=$P(L,U),N=$P(L,U,2)
 . I 'P S L=";;"_L D ADDTRIB Q
 . S L=C_"  "_N
 . S DIE="^AUTTTRI(",DA=P,DR=".01///"_N
 . D DIE
 . I $D(Y) D RSLT(E(0)_E_" : EDIT TRIBE FAILED => "_L) Q
 . D MODOK
 .Q
 Q
 ;
 ;
 ; -----------------------------------------------------
 ;

AUM8107A
AUM8107A ; IHS/ASDST/GTH - STANDARD TABLE UPDATES, 4NOV1998 MESSAGE ; [ 11/12/1998   5:06 PM ]
 ;;98.1;TABLE MAINTENANCE;**7**;NOV 17,1997
 ;
UPDATE ;;IHS STANDARD CODE BOOK MODIFICATIONS - OCT 1998   11/4/98
 ;
LOCNEW ;;A.  NEW FACILITY CODE (SECTION VIII-C): AREA^S.U.^FAC.^NAME^PSEUDO
 ;;20^22^30^LAGUNA-ACOMA TEEN CENTER^QBP
 ;;20^22^31^TOHAJIILEE TEEN CENTER^QBQ
 ;;55^52^33^MOBILE CLINIC NORTH^OCW
 ;;END
 ;
LOCINACT ;;B.  INACTIVATED FACILITY CODES (SECTION VIII-C): AREA^S.U.^FAC.^NAME
 ;;67^61^63^IAC & RHP URBAN (SALT LAKE)
 ;;END
 ;
COMMNEW ;;C.  NEW COMMUNITY CODES (SECTION V-C): STATE^CNTY^COMM^NAME^AREA^S.U.
 ;;06^33^160^BANNING^66^18
 ;;06^56^021^SIMI VALLEY^66^00
 ;;08^30^011^LAKEWOOD^60^00
 ;;09^02^100^WEST HARTFORD^51^00
 ;;12^16^101^JACKSONVILLE^51^00
 ;;12^54^102^SAN MATEO^51^00
 ;;12^54^103^SATSUMA^51^00
 ;;12^58^104^VENICE^51^00
 ;;18^20^139^BRISTOL^18^23
 ;;18^20^140^GOSHEN^18^23
 ;;18^44^574^SHIPSHEWANA^11^00
 ;;18^46^141^HUDSON^18^23
 ;;18^50^142^TYNER^18^23
 ;;22^26^105^KENNER^51^00
 ;;26^03^144^HOLLAND^18^23
 ;;26^03^145^PULLMAN^18^23
 ;;26^19^575^ELSIE^11^00
 ;;26^25^576^BURTON^11^00
 ;;26^30^577^PITTSFORD^11^00
 ;;26^41^578^BELMONT^11^00
 ;;26^41^579^BYRON CENTER^11^00
 ;;26^41^580^COMSTOCK PARK^11^00
 ;;26^41^581^ROCKFORD^11^00
 ;;26^41^582^SAND LAKE^11^00
 ;;26^41^583^SPARTA^11^00
 ;;26^50^584^ST CLAIR SHORES^11^00
 ;;26^50^585^WARREN^11^00
 ;;26^58^586^PETERSBURG^11^00
 ;;26^59^587^STANTON^11^00
 ;;26^61^588^FRUITPORT^11^00
 ;;26^61^589^MONTAGUE^11^00
 ;;26^61^590^MUSKEGON HEIGHTS^11^00
 ;;26^61^591^NORTH MUSKEGON^11^00
 ;;26^61^592^WHITEHALL^11^00
 ;;26^62^593^GRANT^11^00
 ;;26^63^594^AUBURN HILLS^11^00
 ;;26^63^595^FERNDALE^11^00
 ;;26^63^596^ROYAL OAK^11^00
 ;;26^63^597^SOUTH LYON^11^00
 ;;26^63^598^WATERFORD^11^00
 ;;26^64^599^PENTWATER^11^00
 ;;26^64^600^ROTHBURY^11^00
 ;;26^64^601^SHELBY^11^00
 ;;26^65^146^LUPTON^18^23
 ;;26^65^147^PRESCOTT^18^23
 ;;26^67^602^MARION^11^00
 ;;26^70^603^ALLENDALE^11^00
 ;;26^70^604^CONKLIN^11^00
 ;;26^70^605^FERRYSBURG^11^00
 ;;26^70^606^MARNE^11^00
 ;;26^70^607^NUNICA^11^00
 ;;26^70^608^ZEELAND^11^00
 ;;26^73^609^ST CHARLES^11^00
 ;;26^73^610^ZILWAUKEE^11^00
 ;;26^74^611^ALGONAC^11^00
 ;;26^74^612^PEARL BEACH^11^00
 ;;26^78^613^BYRON^11^00
 ;;26^78^614^HENDERSON^11^00
 ;;26^78^615^LAINGSBURG^11^00
 ;;26^79^616^DEFORD^11^00
 ;;26^80^148^LACOTA^18^23
 ;;37^26^106^FAYETTEVILLE^51^00
 ;;45^39^100^EASLEY^51^00
 ;;48^05^100^PLANO^55^00
 ;;55^54^617^BELOIT^11^00
 ;;END
 ;
COMMMOD ;;D.  COMMUNITY CODE CHANGES (SECTION V-C): STATE^CNTY^COMM^NAME^AREA^S.U.
 ;;FROM^26^53^286^LUDDINGTON^18^23
 ;;  TO^26^53^286^LUDINGTON^18^23
 ;;END
 ;
TRIBMOD ;;E.  CHANGES (SECTION XVIII): CODE^NAME
 ;;FROM^228^SAMISH TRIBAL ORGANIZATION
 ;;  TO^228^SAMISH INDIAN TRIBE, WASHINGTON
 ;;END
 ;

AUM8107M
AUM8107M ; IHS/ASDST/GTH -  BACKGROUND VALUES FOR STANDARD TABLE UPDATES, 4NOV1998 MESSAGE ; [ 11/12/1998   5:06 PM ]
 ;;98.1;TABLE MAINTENANCE;**7**;NOV 17,1997
 ;
VAL(X,%,Y) ;EP - return background info.
 I X["AREA" Q $T(@%)
 S Y=0
 I X["SU" D  Q Y
 . NEW C,T
 . F C=1:1 S T=$P($T(SU+C),";",3) Q:T="END"  I $P(T,U,1,2)=($E(%,1,2)_U_$E(%,3,4)) S Y=1_";;"_T Q
 .Q
 I '(X["CTY") Q 0
 NEW C,T
 F C=1:1 S T=$P($T(COUNTY+C),";",3) Q:T="END"  I $P(T,U,1,2)=($E(%,1,2)_U_$E(%,3,4)) S Y=1_";;"_T Q
 Q Y
 ;
AREA ; CODE^NAME^PREFIX/REGION^CAN PREFIX
11 ;;11^BEMIDJI^D^J46
18 ;;18^BEMIDJI NON-IHS^D^J46
20 ;;20^ALBUQUERQUE^Q^J53
51 ;;51^NASHVILLE^U^J51
55 ;;55^OKLAHOMA TRIBE/638^O^J50
60 ;;60^PHOENIX^X^J40
66 ;;66^CALIFORNIA TRIBE/638^L^J41
 ;;END
 ;
SU ; AREA^SU^NAME
1100 ;;11^00^NON SERVICE UNIT
1823 ;;18^23^EASTERN MICHIGAN
2022 ;;20^22^ACOM CAN LAG
5100 ;;51^00^NON SERVICE UNIT
5500 ;;55^00^NON SERVICE UNIT
5552 ;;55^52^CLAREMORE
6000 ;;60^00^NON SERVICE UNIT
6600 ;;66^00^NON SERVICE UNIT
6618 ;;66^18^RIVERSIDE SB
 ;;END
 ;
COUNTY ; STATE^COUNTY^NAME
0633 ;;06^33^RIVERSIDE
0656 ;;06^56^VENTURA
0830 ;;08^30^JEFFERSON
0902 ;;09^02^HARTFORD
1216 ;;12^16^DUVAL
1254 ;;12^54^PUTNAM
1258 ;;12^58^SARASOTA
1820 ;;18^20^ELKHART
1844 ;;18^44^LAGRANGE
1850 ;;18^50^MARSHALL
2226 ;;22^26^JEFFERSON
2603 ;;26^03^ALLEGAN
2619 ;;26^19^CLINTON
2625 ;;26^25^GENESEE
2630 ;;26^30^HILLSDALE
2650 ;;26^50^MACOMB
2653 ;;26^53^MASON
2658 ;;26^58^MONROE
2659 ;;26^59^MONTCALM
2661 ;;26^61^MUSKEGON
2662 ;;26^62^NEWAYGO
2663 ;;26^63^OAKLAND
2664 ;;26^64^OCEANA
2665 ;;26^65^OGENAW
2667 ;;26^67^OSCEOLA
2670 ;;26^70^OTTAWA
2673 ;;26^73^SAGINAW
2674 ;;26^74^ST CLAIR
2678 ;;26^78^SHIAWASSEE
2679 ;;26^79^TUSCOLA
2680 ;;26^80^VAN BUREN
3726 ;;37^26^CUMBERLAND
4539 ;;45^39^PICKENS
4805 ;;48^05^COLLIN
5554 ;;55^54^ROCK
 ;;END
 ;