10:48 AM  27-JUL-2000
AUM v 99.1 Patch 15, SCB 21Jul00, Domain.  Restore 5 routines and DO ^AUM9115.
A9AUM15
A9AUM15 ; IHS/RPMSDBA/GTH - STANDARD TABLE UPDATES, 2000JUL21, RPI ; [ 07/27/2000  10:47 AM ]
 ;;99.1;TABLE MAINTENANCE;**15**;NOV 6,1998
 ;
 D START^AUM9115
DEL ;EP - Delete routines.
 Q:'$L($G(^%ZOSF("DEL")))
 NEW X
 I $$RSEL^ZIBRSEL("AUM9115*") D D
 I $$RSEL^ZIBRSEL("A9AUM*")
 KILL ^TMP("ZIBRSEL",$J,"A9AUM15") ; Don't delete the current routine.
 D D
 Q
 ;
D ;
 S X=""
 F  S X=$O(^TMP("ZIBRSEL",$J,X)) Q:X=""  X ^%ZOSF("DEL") I '$D(ZTQUEUED) W !,X,$E("...........",1,11-$L(X)),"<poof'd>"
 KILL ^TMP("ZIBRSEL",$J)
 Q
 ;

AUM9115
AUM9115 ; IHS/RPMSDBA/GTH - STANDARD TABLE UPDATES, 2000JUL21 ; [ 07/27/2000  10:47 AM ]
 ;;99.1;TABLE MAINTENANCE;**15**;NOV 6,1998
 ;
 I '$G(DUZ) W !,"DUZ UNDEFINED OR ZERO.",! Q
 D HOME^%ZIS,DT^DICRW,VP,HELP("INTRO")
 S (DIR(0),DIR("B"))="Y"
 S DIR("A")="Do you want to queue the update to TaskMan"
 S DIR("??")="^D HELP^AUM9115(""Q2"")"
 D ^DIR
 KILL DIR
 I $D(DIRUT) D HELP("Q2") Q
 G START:'Y
QUE ;
 S %DT="AERSX",%DT("A")="Requested Start Time: ",%DT("B")="T@2015",%DT(0)="NOW"
 D ^%DT
 I Y<1 W !,"QUEUE INFORMATION MISSING - NOT QUEUED" D HELP("Q2") G AUM9115
 S X=+Y
 D H^%DTC
 S ZTDTH=%H_","_%T
 S ZTRTN="START^AUM9115",ZTIO="",ZTDESC=$P($P($T(+1),";",2)," ",4,99)
 D ^%ZTLOAD,HOME^%ZIS
 I $D(ZTSK) W !!,"QUEUED TO TASK ",ZTSK,!!,"A mail message with the results will be sent to your MailMan 'IN' basket.",!
 E  W !!,*7,"QUEUE UNSUCCESSFUL.  RESTART UTILITY."
 Q
 ;
START ;EP - From Taskman
 ;
 NEW XMSUB,XMDUZ,XMTEXT,XMY
 KILL ^TMP("AUM9115",$J)
 D START^AUM91151
 S XMSUB=$P($P($T(+1),";",2)," ",4,99),XMDUZ=$G(DUZ,.5),XMTEXT="^TMP(""AUM9115"",$J,",XMY(DUZ)=""
 F %="XUPROGMODE","AG TM MENU","ABMDZ TABLE MAINTENANCE","APCCZMGR" D SINGLE(%)
 D ^XMD
 KILL ^TMP("AUM9115",$J)
 I $D(ZTQUEUED) S ZTREQ="@" G DEL^A9AUM15
 W !!,"The results are in your MailMan 'IN' basket.",!
 I $L($T(DIR^XBDIR)),$$DIR^XBDIR("Y","Want me to delete the routines in this patch","Y") G DEL^A9AUM15
 Q
 ;
INTRO ;EP - To write to mail message, too.
 ;;This updates standard tables according to the changes specified in
 ;;the message from Joe Herrera, with subject "Standard Code Book
 ;;modifications", released on Fri 7/21/00.  Please consult that
 ;;message, and the local RPMS mail message produced by this update.
 ;;  
 ;;Additionally, a domain name is added to the DOMAIN file.
 ;;  
 ;;###;NOTE:  This line indicates the end of the message.
 ;
Q2 ;
 ;;Answer "Y" if you want to queue this standard table update to TaskMan.
 ;;Answer "N" if you want to run this update interactively.
 ;;
 ;;If you run interactively, results will be displayed on your screen,
 ;;as well as in the mail message sent to you and user 1.  If you queue
 ;;to TaskMan, please read the mail message for results of this update.
 ;;###;NOTE:  This line indicates the end of the message.
 ;
HELP(L) ;EP - Display text at label L.
 W !
 F %=1:1 W !?4,$P($T(@L+%),";",3) Q:$P($T(@L+%+1),";",3)="###"
 Q
 ;
SINGLE(K) ; Get holders of a single key K.
 NEW Y
 S Y=0
 Q:'$D(^XUSEC(K))
 F  S Y=$O(^XUSEC(K,Y)) Q:'Y  S XMY(Y)=""
 Q
 ;
VP ;
 W !?4,"****    AUM Version ",$P($T(+2),";",3)," Patch ",$P($P($T(+2),";",5),"*",3),?65,"****"
 W !?4,"****   ",$P($P($T(+1),";",2),"-",2),?65,"****"
 Q
 ;
GREET ;;EP - To add to mail message.
 ;;  
 ;;Greetings.
 ;;  
 ;;Standard tables on your RPMS system have been updated.
 ;;  
 ;;You are receiving this message because of the particular RPMS
 ;;security keys that you hold.  This is for your information, only.
 ;;You need do nothing in response to this message.
 ;;  
 ;;Requests for modifications or additions to RPMS standard tables,
 ;;whether they are or are not reflected in the IHS Standard Code
 ;;Book (SCB), can be submitted to your Area Information System
 ;;Coordinator (ISC).
 ;;  
 ;;Questions about this patch, which is a product of the RPMS/DBA
 ;;Team, can be directed to the DIR/RPMS Support Center, at
 ;;505-248-4371, or via e-mail to "hqwhd@mail.ihs.gov".  Please
 ;;refer to patch "AUM*99.1*15".
 ;;  
 ;;###;NOTE: This line indicates the end of text in this message.
 ;

AUM91151
AUM91151 ; IHS/RPMSDBA/GTH - STANDARD TABLE UPDATES, 2000JUL21 ; [ 07/27/2000  10:47 AM ]
 ;;99.1;TABLE MAINTENANCE;**15**;NOV 6,1998
 ;
 Q
 ;
START ;EP
 ;
 NEW A,C,DIC,DIE,DINUM,DLAYGO,DR,E,L,M,N,O,P,R,S,T
 ;
 S E(0)="ERROR : ",E(1)="NOT ADDED : "
 D RSLT($J("",5)_$P($T(UPDATE^AUM9115A),";",3))
 F %=1:1 D RSLT($P($T(GREET+%^AUM9115),";",3)) Q:$P($T(GREET+%+1^AUM9115),";",3)="###"
 F %=1:1 D RSLT($P($T(INTRO+%^AUM9115),";",3)) Q:$P($T(INTRO+%+1^AUM9115),";",3)="###"
 D DASH,LOCNEW,DASH,LOCMOD,DASH,COMMNEW,DASH,COMMMOD,DASH,TRIBNEW,DASH,TRIBMOD,DASH,DOMNEW,DASH
 Q
 ;
 ; -----------------------------------------------------
 ;
ADDOK D RSLT($J("",5)_"Added : "_L) Q
ADDFAIL D RSLT($J("",5)_E(0)_"ADD FAILED => "_L) Q
DASH D RSLT(""),RSLT($$REPEAT^XLFSTR("-",$S($G(IOM):IOM-10,1:70))),RSLT("") Q
DIE NEW A,C,E,L,M,N,O,P,R,S,T
 LOCK +(@(DIE_DA_")")):10 E  D RSLT($J("",5)_E(0)_"Entry '"_DIE_DA_"' IS LOCKED.  NOTIFY PROGRAMMER.") S Y=1 Q
 D ^DIE LOCK -(@(DIE_DA_")")) KILL DA,DIE,DR Q
E(L) Q $P($P($T(@L^AUM9115A),";",3),":",1)
IEN(X,%,Y) ;
 S Y=$O(@(X_"""C"",%,0)"))
 I 'Y S Y=$$VAL^AUM9115M(X,%) I Y NEW Z S Z=E D  S:Y<0 Y="" S E=Z
 . NEW A,C,L,M,N,O,P,R,S,V,%
 . S L=Y
 . I X["AREA" NEW X D RSLT("(Add Missing Area)") D ADDAREA D RSLT("(END Add Missing Area)") Q
 . I X["SU" NEW X D RSLT("(Add Missing SU)") D ADDSU D RSLT("(END Add Missing SU)") Q
 . I X["CTY" NEW X D RSLT("(Add Missing County)") D ADDCNTY D RSLT("(END Add Missing County)") Q
 .Q
 D:'Y RSLT($J("",5)_E(0)_$P(@(X_"0)"),U)_" DOES NOT EXIST => "_%)
 Q +Y
DIK NEW A,C,E,L,M,N,O,P,R,S,T D ^DIK KILL DIK Q
FILE NEW A,C,E,L,M,N,O,P,R,S,T K DD,DO S DIC(0)="L" D FILE^DICN KILL DIC Q
MODOK D RSLT($J("",5)_"Changed : "_L) Q
RSLT(%) S ^(0)=$G(^TMP("AUM9115",$J,0))+1,^(^(0))=% W:'$D(ZTQUEUED) !,% Q
ZEROTH(A,B,C,D,E,F,G,H,I,J,K) ; Return 0th node.  A is file #, rest fields.
 I '$G(A) Q -1
 I '$G(B) Q -1
 F %=67:1:75 Q:'$G(@($C(%)))  S A=+$P(^DD(A,B,0),U,2),B=@($C(%))
 I 'A!('B) Q -1
 I '$D(^DD(A,B,0)) Q -1
 Q U_$P(^DD(A,B,0),U,2)
 ;
 ; -----------------------------------------------------
 ;
ADDAREA ; PROGRAMMER NOTE:  This s/r is required for every patch.
 S L=$P(L,";;",2),A=$P(L,U),N=$P(L,U,2),R=$P(L,U,3),C=$P(L,U,4),L=A_" "_N_" "_R_" "_C
 I $D(^AUTTAREA("B",N)) D RSLT($J("",5)_E(1)_"NAME EXISTS => "_N) Q
 I $D(^AUTTAREA("C",A)) D RSLT($J("",5)_E(1)_"CODE EXISTS => "_A) Q
 S DLAYGO=9999999.21,DIC="^AUTTAREA(",X=N,DIC("DR")=".02///"_A_";.03///"_R_";.04///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DLAYGO
 Q
 ;
 ; -----------------------------------------------------
 ;
ADDCNTY ; PROGRAMMER NOTE:  This s/r is required for every patch.
 S L=$P(L,";;",2),S=$P(L,U),C=$P(L,U,2),N=$P(L,U,3),L=S_" "_C_" "_N
 I $D(^AUTTCTY("C",S_C)) D RSLT($J("",5)_E(1)_"CODE EXISTS => "_S_C) Q
 S P("S")=$$IEN("^DIC(5,",S)
 Q:'P("S")
 S DIC="^AUTTCTY(",X=N,DIC("DR")=".02////"_P("S")_";.03///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 Q
 ;
 ; -----------------------------------------------------
 ;
ADDSU ; PROGRAMMER NOTE:  This s/r is required for every patch.
 S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),N=$P(L,U,3),L=A_" "_S_" "_N
 I $D(^AUTTSU("C",A_S)) D RSLT($J("",5)_E(1)_"ASU EXISTS => "_A_S) Q
 S P=$$IEN("^AUTTAREA(",A)
 Q:'P
 S DLAYGO=9999999.22,DIC="^AUTTSU(",X=N,DIC("DR")=".02////"_P_";.03///"_S
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DLAYGO
 Q
 ;
 ; -----------------------------------------------------
LOCNEW ;
 D RSLT($$E("LOCNEW"))
 D RSLT($J("",13)_"AA SU FA NAME"_$J("",28)_"PSEUDO")
 D RSLT($J("",13)_"-- -- -- ----"_$J("",28)_"------")
 F T=1:1 S L=$T(LOCNEW+T^AUM9115A) Q:$P(L,";",3)="END"  D ADDLOC
 Q
 ;
ADDLOC ;
 S L=$P(L,";;",2),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3),N=$P(L,U,4),P=$P(L,U,5)
 S L=A_" "_S_" "_F_" "_N_$J("",32-$L(N))_P
 S %=A_S_F,%=$O(^AUTTLOC("C",%,0))
 I % D RSLT($J("",5)_E(1)_"ASUFAC EXISTS => "_A_S_F) D  Q
 . I $P($G(^AUTTLOC(%,0)),U,21) S DIE="^AUTTLOC(",DA=%,DR=".27///@;.28////"_DT D DIE D:$D(Y) RSLT($J("",5)_E(0)_"DELETE INACTIVE DATE FAILED => "_L) D:'$D(Y) RSLT($J("",5)_"INACTIVE DATE DELETED => "_L)
 . S %=$O(^AUTTLOC("C",A_S_F,0)),%=$P(^AUTTLOC(%,0),U)
 . I %,$D(^DIC(4,%,0)),N'=$P(^DIC(4,%,0),U) S DIE="^DIC(4,",DA=%,DR=".01///"_N D DIE D:$D(Y) RSLT($J("",5)_E(0)_"EDIT INSTITUTION FAILED => "_L) D:'$D(Y) RSLT($J("",5)_"INSTITUTION NAME UPDATED => "_L)
 . S %=$O(^AUTTLOC("C",A_S_F,0))
 . I P'=$P($G(^AUTTLOC(%,1)),U,2) S DIE="^AUTTLOC(",DA=%,DR=".28////"_DT_";.31///"_P D DIE D:$D(Y) RSLT($J("",5)_E(0)_"EDIT PSEUDO PREFIX FAILED => "_L) D:'$D(Y) RSLT($J("",5)_"PSEUDO PREFIX UPDATED => "_L)
 .Q
 S P("A")=$$IEN("^AUTTAREA(",A)
 Q:'P("A")
 S P("S")=$$IEN("^AUTTSU(",A_S)
 Q:'P("S")
 F DINUM=+$P(^DIC(4,0),U,3):1 Q:'$D(^DIC(4,DINUM))&('$D(^AUTTLOC(DINUM)))  I DINUM>99999 D RSLT($J("",5)_E(0)_"DINUM FOR LOC/INSTITUTION TOO BIG. NOTIFY ISC.") Q
 Q:DINUM>99999
 S DLAYGO=4,DIC="^DIC(4,",X=N
 D FILE
 KILL DINUM,DLAYGO
 I Y<0 D RSLT($J("",5)_E(0)_"^DIC(4 ADD FAILED => "_L) Q
 S DINUM=+Y,DLAYGO=9999999.06,DIC="^AUTTLOC(",X=DINUM,DIC("DR")=".04////"_P("A")_";.05////"_P("S")_";.07///"_F_";.28////"_DT_";.31///"_P
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DINUM,DLAYGO
 Q
 ;
 ; -----------------------------------------------------
 ;
LOCMOD ;
 D RSLT($$E("LOCMOD"))
 D RSLT($J("",15)_"AA SU FA NAME"_$J("",28)_"PSEUDO")
 D RSLT($J("",15)_"-- -- -- ----"_$J("",28)_"------")
 F T=1:2 S L=$T(LOCMOD+T^AUM9115A) Q:$P(L,";",3)="END"  S L("TO")=$T(LOCMOD+T+1^AUM9115A) D
 . S L=$P(L,U,2,99),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3)
 . S P=$O(^AUTTLOC("C",A_S_F,0))
 . S L=$P(L("TO"),U,2,99),A=$P(L,U),S=$P(L,U,2),F=$P(L,U,3),N=$P(L,U,4)
 . I 'P S P=$O(^AUTTLOC("C",A_S_F,0)) I 'P S L=";;"_L D ADDLOC Q
 . S L=A_" "_S_" "_F_" "_N_$J("",32-$L(N))_$P(L("TO"),U,6)
 . S P("A")=$$IEN("^AUTTAREA(",A)
 . Q:'P("A")
 . S P("S")=$$IEN("^AUTTSU(",A_S)
 . Q:'P("S")
 . S DIE="^AUTTLOC(",DA=P,DR=".04////"_P("A")_";.05////"_P("S")_";.07///"_F_";.28////"_DT_";.31///"_$P(L("TO"),U,6)
 . D DIE
 . I $D(Y) D RSLT($J("",5)_E(0)_"EDIT LOCATION FAILED => "_L) Q
 . S DIE="^DIC(4,",DA=$P(^AUTTLOC(P,0),U),DR=".01///"_N
 . D DIE
 . I $D(Y) D RSLT($J("",5)_E(0)_"EDIT INSTITUTION FAILED => "_L) Q
 . D MODOK
 .Q
 ;
 D DASH
 D RSLT("Checking Location Code changes to determine export status.")
 D RSLT("Patient data is not exported if the only change is to the Location NAME.")
 D RSLT("Location Code changes must be rolled up into the national data repository...")
 D DASH,RSLT($$LOCMOD^AUMXPORT("AUM9115A")_" patients marked for export because of the Location Code changes.")
 Q
 ;
 ; -----------------------------------------------------
 ;
COMMNEW ;
 D RSLT($$E("COMMNEW"))
 D RSLT($J("",13)_"ST CT COM NAME"_$J("",28)_"AA SU")
 D RSLT($J("",13)_"-- -- --- ----"_$J("",28)_"-- --")
 F T=1:1 S L=$T(COMMNEW+T^AUM9115A) Q:$P(L,";",3)="END"  D ADDCOMM
 Q
 ;
ADDCOMM ;
 S L=$P(L,";;",2),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3),N=$P(L,U,4),A=$P(L,U,5),V=$P(L,U,6),L=S_" "_O_" "_C_" "_N_$J("",32-$L(N))_A_" "_V
 I $D(^AUTTCOM("C",S_O_C)) D RSLT($J("",5)_E(1)_"STCTYCOM CODE EXISTS => "_S_O_C) Q
 S P("O")=$$IEN("^AUTTCTY(",S_O)
 Q:'P("O")
 S P("A")=$$IEN("^AUTTAREA(",A)
 Q:'P("A")
 S P("V")=$$IEN("^AUTTSU(",A_V)
 Q:'P("V")
 S DLAYGO=9999999.05,DIC="^AUTTCOM(",X=N,DIC("DR")=".02////"_P("O")_";.05////"_P("V")_";.06////"_P("A")_";.07///"_C
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DLAYGO
 Q
 ;
 ; -----------------------------------------------------
 ;
COMMMOD ;
 D RSLT($$E("COMMMOD"))
 D RSLT($J("",15)_"ST CT COM NAME"_$J("",28)_"AA SU")
 D RSLT($J("",15)_"-- -- --- ----"_$J("",28)_"-- --")
 F T=1:2 S L=$T(COMMMOD+T^AUM9115A) Q:$P(L,";",3)="END"  S L("TO")=$T(COMMMOD+T+1^AUM9115A) D
 . S L=$P(L,U,2,99),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3)
 . S P=$O(^AUTTCOM("C",S_O_C,0))
 . S L=$P(L("TO"),U,2,99),S=$P(L,U),O=$P(L,U,2),C=$P(L,U,3),N=$P(L,U,4),A=$P(L,U,5),V=$P(L,U,6)
 . I 'P S P=$O(^AUTTCOM("C",S_O_C,0)) I 'P S L=";;"_L D ADDCOMM Q
 . S L=S_" "_O_" "_C_" "_N_$J("",32-$L(N))_A_" "_V
 . S P("O")=$$IEN("^AUTTCTY(",S_O)
 . Q:'P("O")
 . S P("A")=$$IEN("^AUTTAREA(",A)
 . Q:'P("A")
 . S P("V")=$$IEN("^AUTTSU(",A_V)
 . Q:'P("V")
 . S DIE="^AUTTCOM(",DA=P,DR=".01///"_N_";.02////"_P("O")_";.05////"_P("V")_";.06////"_P("A")_";.07///"_C
 . D DIE
 . I $D(Y) D RSLT($J("",5)_E(0)_"CHANGE FAILED => "_L) Q
 . D MODOK
 .Q
 ;
 D DASH
 D RSLT("Checking Community Code changes to determine export status.")
 D RSLT("Patient data is not exported if the only change is to the Commnuity NAME.")
 D RSLT("Commnity Code changes must be rolled up into the national data repository...")
 D DASH,RSLT($$COMMMOD^AUMXPORT("AUM9115A")_" patients marked for export because of the Community Code changes.")
 Q
 ;
 ; -----------------------------------------------------
 ;
TRIBNEW ;
 D RSLT($$E("TRIBNEW"))
 D RSLT($J("",13)_"CCC NAME")
 D RSLT($J("",13)_"--- ----")
 F T=1:1 S L=$T(TRIBNEW+T^AUM9115A) Q:$P(L,";",3)="END"  D ADDTRIB
 Q
 ;
ADDTRIB ;
 S L=$P(L,";;",2),C=$P(L,U),N=$P(L,U,2),A=$P(L,U,3),L=C_" "_A
 I $D(^AUTTTRI("C",C)) D RSLT($J("",5)_E(1)_"TRIBE CODE EXISTS => "_C) Q
 S DLAYGO=9999999.03,DIC="^AUTTTRI(",X=N,DIC("DR")=".02///"_C_";.03///"_A_";.04///N"
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DLAYGO
 Q
 ;
 ; -----------------------------------------------------
 ;
TRIBMOD ;
 D RSLT($$E("TRIBMOD"))
 D RSLT($J("",14)_"CODE  NAME"_$J("",29)_"INACTIVE")
 D RSLT($J("",14)_"----  ----"_$J("",29)_"--------")
 F T=1:2 S L=$T(TRIBMOD+T^AUM9115A) Q:$P(L,";",3)="END"  S L("TO")=$T(TRIBMOD+T+1^AUM9115A) D
 . S L=$P(L,U,2,99),C=$P(L,U)
 . S P=$O(^AUTTTRI("C",C,0))
 . S L=$P(L("TO"),U,2,99),C=$P(L,U),N=$P(L,U,2),S=$P(L,U,3)
 . I 'P S L=";;"_L D ADDTRIB Q
 . S L=C_"  "_N_$J("",40-$L(N))_S
 . S DIE="^AUTTTRI(",DA=P,DR=".01///"_N_";.04///"_S
 . D DIE
 . I $D(Y) D RSLT(E(0)_E_" : EDIT TRIBE FAILED => "_L) Q
 . D MODOK
 .Q
 Q
 ;
 ; -----------------------------------------------------
 ;
DOMNEW ;
 D RSLT($$E("DOMNEW"))
 D RSLT($J("",13)_"NAME")
 D RSLT($J("",13)_"----")
 F T=1:1 S L=$T(DOMNEW+T^AUM9115A) Q:$P(L,";",3)="END"  D ADDDOM
 Q
 ;
ADDDOM ;
 S L=$P(L,";;",2),N=$P(L,U),L=N
 I $D(^DIC(4.2,"B",N)) D RSLT($J("",5)_E(1)_"DOMAIN NAME EXISTS => "_N) Q
 S DLAYGO=4.2,DIC="^DIC(4.2,",X=N
 D FILE,ADDFAIL:Y<0,ADDOK:Y>0
 KILL DLAYGO
 Q
 ;
 ; -----------------------------------------------------
 ;

AUM9115A
AUM9115A ; IHS/RPMSDBA/GTH - STANDARD TABLE UPDATES, 2000JUL21 ; [ 07/27/2000  10:47 AM ]
 ;;99.1;TABLE MAINTENANCE;**15**;NOV 6,1998
 ;
UPDATE ;;IHS STANDARD CODE BOOK MODIFICATIONS - JUNE/JULY 2000 07/21/2000
 ;
LOCNEW ;;A.  NEW FACILITY CODES (SECTION VIII-C): AREA^S.U.^FAC.^NAME^PSEUDO
 ;;10^15^34^PORCUPINE CLINIC^CBZ
 ;;15^20^80^WINNEBAGO DENTAL PROGRAM^CCD
 ;;65^63^98^OTHER^XEB
 ;;END
 ;
LOCMOD ;;B.  FACILITY CODE CHANGES (SECTION VIII-C): AREA^S.U.^FAC.^NAME^PSEUDO
 ;;FROM^15^33^80^MESQUAKIE HC^CXG
 ;;  TO^15^33^80^MESKWAKI HC^CXG
 ;;FROM^60^62^01^KEAMS CANYON HOSPITAL^XCA
 ;;  TO^60^62^01^HOPI HEALTH CARE CENTER^XCA
 ;;FROM^60^66^01^PHOENIX HOSP^XAA
 ;;  TO^60^66^01^PHOENIX INDIAN MEDICAL CENTER^XAA
 ;;FROM^65^66^63^FORT MCDOWELL HS^XSZ
 ;;  TO^65^66^63^WASSAJA HEALTH CENTER^XSZ
 ;;END
 ;
COMMNEW ;;C.  NEW COMMUNITY CODES (SECTION V-C); STATE^CNTY^COMM^NAME^AREA^S.U.
 ;;19^07^155^WATERLOO^10^00
 ;;19^07^156^CEDAR FALLS^10^00
 ;;19^08^157^AMES^10^00
 ;;19^25^158^PERRY^10^00
 ;;19^31^159^DUBUQUE^10^00
 ;;19^50^160^NEWTON^10^00
 ;;19^57^161^CEDAR RAPIDS^10^00
 ;;19^62^162^OSKALOOSA^10^00
 ;;19^64^163^MARSHALLTOWN^10^00
 ;;19^64^164^LE GRANDE^10^00
 ;;19^77^165^DES MOINES^10^00
 ;;19^79^166^GRINNELL^10^00
 ;;19^82^167^DAVENPORT^10^00
 ;;19^86^005^BUCKINGHAM^15^33
 ;;19^86^006^CHELSEA^15^33
 ;;19^86^007^CLUTIER^15^33
 ;;19^86^008^DINSDALE^15^33
 ;;19^86^009^DYSART^15^33
 ;;19^86^010^ELBERON^15^33
 ;;19^86^011^GARWIN^15^33
 ;;19^86^012^GLADBROOK^15^33
 ;;19^86^013^HAVEN^15^33
 ;;19^86^014^LINCOLN^15^33
 ;;19^86^015^MONTOUR^15^33
 ;;19^86^016^TOLEDO^15^33
 ;;19^86^017^VINING^15^33
 ;;19^90^168^OTTUMWA^10^00
 ;;26^70^028^HUDSONVILLE^11^00
 ;;27^03^005^WOLF LAKE^18^31
 ;;27^31^005^BEAR RIVER^18^31
 ;;27^31^013^CALUMET^18^31
 ;;27^31^015^GREENWAY^18^31
 ;;27^31^016^NASHWAUK^18^31
 ;;27^31^017^TOGO^18^31
 ;;27^36^018^ERICSBURG^18^31
 ;;27^36^019^RAUCH^18^31
 ;;27^36^020^RAY^18^31
 ;;27^36^021^SILVERDALE^18^31
 ;;27^36^022^SOUTH I'NTL FALLS^18^31
 ;;27^69^023^BUYCK^18^31
 ;;27^69^024^CUSSON^18^31
 ;;27^69^025^GREANEY^18^31
 ;;27^69^026^KABETOGAMA^18^31
 ;;27^69^027^MARKHAM^18^31
 ;;27^69^028^PALO^18^31
 ;;27^69^029^SIDE LAKE^18^31
 ;;27^69^030^SOUDAN^18^31
 ;;96^99^886^CORNWALL ISLAND^58^00
 ;;96^99^887^SYNE^58^00
 ;;96^99^888^ST. REGIS^58^00
 ;;END
 ;
COMMMOD ;;D.  COMMUNITY CODES CHANGES (SECTION V-C): STATE^CNTY^COMM^NAME^AREA^S.U.
 ;;FROM^35^33^384^ADELINO^20^22
 ;;  TO^35^32^384^ADELINO^20^21
 ;;END
 ;
TRIBNEW ;;E.  NEW TRIBE CODES (SECTION XVIII): CODE^NAME^LONG NAME
 ;;461^MATCH-E-BE-NASH-SHE-WISH POTTAWATOMI^MATCH-E-BE-NASH-SHE-WISH BAND OF POTTAWATOMI INDIANS OF MICHIGAN
 ;;END
 ;
TRIBMOD ;;F.  TRIBE CODE CHANGES (SECTION XVIII): CODE^NAME^INACTIVE
 ;;FROM^235^ASSINIBOINE AND SIOUX TRIBES, MT^N
 ;;  TO^235^ASSINIBOINE/SIOUX TRBS,FT PECK, MT-ASSIN^N
 ;;FROM^272^DEVILS LAKE SIOUX TRIBE, ND^N
 ;;  TO^272^SPIRIT LAKE SIOUX TRIBE, ND^N
 ;;FROM^276^ASSINIBOINE AND SIOUX TRIBES, MT^N
 ;;  TO^276^ASSINIBOINE/SIOUX TRBS,FT PECK, MT-SIOUX^N
 ;;END
 ;
DOMNEW ;;FIELD REQUEST - ADDITION(S) TO DOMAIN FILE: NAME
 ;;SAMISH.PRT.IHS.GOV
 ;;END
 ;

AUM9115M
AUM9115M ; IHS/RPMSDBA/GTH -  BACKGROUND VALUES FOR STANDARD TABLE UPDATES, 2000JUL21 ; [ 07/27/2000  10:47 AM ]
 ;;99.1;TABLE MAINTENANCE;**15**;NOV 6,1998
 ;
VAL(X,%,Y) ;EP - return background info.
 I X["AREA" Q $T(@%)
 S Y=0
 I X["SU" D  Q Y
 . NEW C,T
 . F C=1:1 S T=$P($T(SU+C),";",3) Q:T="END"  I $P(T,U,1,2)=($E(%,1,2)_U_$E(%,3,4)) S Y=1_";;"_T Q
 .Q
 I '(X["CTY") Q 0
 NEW C,T
 F C=1:1 S T=$P($T(COUNTY+C),";",3) Q:T="END"  I $P(T,U,1,2)=($E(%,1,2)_U_$E(%,3,4)) S Y=1_";;"_T Q
 Q Y
 ;
AREA ; CODE^NAME^PREFIX/REGION^CAN PREFIX
10 ;;10^ABERDEEN^C^J45
11 ;;11^BEMIDJI^D^J46
15 ;;15^ABERDEEN TRIBE/638^C^J45
18 ;;18^BEMIDJI NON-IHS^D^J46
20 ;;20^ALBUQUERQUE^Q^J53
58 ;;58^NASHVILLE NON-IHS^U^J51
60 ;;60^PHOENIX^X^J40
65 ;;65^PHOENIX TRIBE/638^X^J40
 ;;END
 ;
SU ; AREA^SU^NAME
1000 ;;10^00^NON SERVICE UNIT
1015 ;;10^15^PINE RIDGE
1100 ;;11^00^NON SERVICE UNIT
1520 ;;15^20^WINNEBAGO
1533 ;;15^33^SAC AND FOX
1831 ;;18^31^NETT LAKE
2021 ;;20^21^ALBUQUERQUE
5800 ;;58^00^NON SERVICE UNIT
6062 ;;60^62^KEAMS CANYON
6066 ;;60^66^PHOENIX
6563 ;;65^63^OWYHEE
6566 ;;65^66^PHOENIX
 ;;END
 ;
COUNTY ; STATE^COUNTY^NAME
1907 ;;19^07^BLACK HAWK
1908 ;;19^08^BOONE
1925 ;;19^25^DALLAS
1931 ;;19^31^DUBUQUE
1950 ;;19^50^JASPER
1957 ;;19^57^LINN
1962 ;;19^62^MAHASKA
1964 ;;19^64^MARSHALL
1977 ;;19^77^POLK
1979 ;;19^79^POWESHIEK
1982 ;;19^82^SCOTT
1986 ;;19^86^TAMA
1990 ;;19^90^WAPELLO
2670 ;;26^70^OTTAWA
2703 ;;27^03^BECKER
2731 ;;27^31^ITASCA
2736 ;;27^36^KOOCHICHING
2769 ;;27^69^ST LOUIS
3532 ;;35^32^VALENCIA
9699 ;;96^99^CANADA UNK
 ;;END
 ;